2011网中一条鱼 发表于 2014-6-1 07:21:13

就是说系统进不了,可是想知道本地IP及网关、DNS

就是说系统进不了,可是想知道本地IP及网关、DNS
这个小问题我还在网页查了不少,还真没有一个软件能有这个功能的,不知道是什么原因。
想请哪位大神写一个这样的工具出来不?<PE查看IP工具>
我在网上找了半天都只有那一种方法。图看不见就下附件有详细说明。


1. 准备一个安装好PE的U盘,并设置优盘为第一启动项。
2. 进入PE系统,开始->运行,输入regedit,打开注册表编辑器。
3. 选中HKEY_LOCAL_MACHINE
4. 点击 文件->加载配置单元,如果文件类型不是所有文件,改成所有文件,然后选择C:\Windows\System32\config\SYSTEM文件。
5. 此时会提示输入项名称,可以随便输入,此处我输入的是TEST。
6. 点击确定后,再次展开HKEY_LOCAL_MACHINE,此时在最下面一个子菜单会看到刚才导入的注册表项。
7.依次展开HKEY_LOCAL_MACHINE\TEST\ControlSet001\Services\Tcpip\Parameters\Interfaces,
在Interfaces目录下,有几个子目录,就是你电脑上的IP配置情况,有线网卡、无线网卡、虚拟网卡等。这里我使用的是手动配置的内网IP地址,对应参数为:
IP地址:IPAddress->192.168.6.100
子网掩码:SubnetMask->255.255.248.0
网关:DefaultGateway->192.168.0.1
DNS:NameServer->218.2.135.1

pznpt 发表于 2014-6-2 19:30:36

本帖最后由 pznpt 于 2014-9-2 01:23 编辑

P处理 获取网卡名称及IP信息.bat
考虑到在WinPE中运行,但PE精简程度不一样,除reg.exe外,未使用其它外部命令
也可以在正常系统中运行,查看其它系统安装分区的IP信息,或本系统IP信息
2014-9-1
改正按F8进入“最后一次正确配置”后,注册表项HKLM\SYSTEM\ControlSet001不存在而无法运行的问题;
增加获取Domain名称和HostName名称;
将结果保存到脚本所在目录下IPInfo.txt文本中,而不是打印到屏幕

2014-6-4
修正了在xp上获取的DNS地址可能出现多余的\0字符

@echo off 2>nul 3>nul
setlocal enabledelayedexpansion
set /p Input=输入要查询的系统安装盘符[例如D]:
if /i "%Input%:" neq "%systemDrive%" (
    for %%a in (software system) do (
      if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
    )
    reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
    reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
    call :GetIPInfo Temp_HIV1 Temp_HIV2
    reg unload HKLM\Temp_HIV1 >nul
    reg unload HKLM\Temp_HIV2 >nul
) else call :GetIPInfo SOFTWARE SYSTEM
start "" "%~dp0IPInfo.txt" & exit/b

:GetIPInfo
for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
    if /i "%%a" == "Default" set /a x=%%c
)
set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
set "v2=ControlSet00%x%\Control\Network"
set "v3=ControlSet00%x%\services\Tcpip\Parameters"
set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"

for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
    set "v=%%a"
    if "!v:%v1%\=!" neq "!v!" (
      set /a n+=1
      for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
            if /i "%%b" == "ServiceName" (
                set "Guid!n!=%%d"
            ) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
      )
    )
)
if not defined n echo,找不到网卡&pause & exit

(for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
    if /i "%%a" == "Domain" (
      if "%%c" neq "" (echo,域名名称:%%c)else echo,域名名称:^<nul^>
    ) else if /i "%%a" == "HostName" echo,主机名称:%%c
))>"%~dp0IPInfo.txt"

for %%a in (%s%) do set "_%%a=1"
(for /l %%a in (1 1 %n%) do (
    echo,&echo,网卡名称:!NetCard%%a!
    for %%b in (%s%) do set "%%b="
    for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
      if defined flag (
            for /f "tokens=1,2*" %%c in ("%%b") do (
                if /i "%%c" == "Name" echo,连接名称:%%e& set "flag="
            )
      ) else (
            set "v=%%b"
            for %%c in ("\!Guid%%a!\") do if "!v:%%~c=!" neq "!v!" set flag=1
      )
    )
    for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
      if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
    )
    if /i "!EnableDHCP!" == "0x1" (
      echo,IP 地 址:!DHCPIPAddress!
      echo,子网掩码:!DHCPSubnetMask!
      echo,默认网关:!DHCPDefaultGateway!
      echo,DNS 地址:!DHCPNameServer!
    ) else (
      echo,IP 地 址:!IPAddress!
      echo,子网掩码:!SubnetMask!
      echo,默认网关:!DefaultGateway!
      echo,DNS 地址:!NameServer!
    )
))>>"%~dp0IPInfo.txt"

zlgs 发表于 2014-7-9 21:59:10

求助还是教程啊? 我只知道命令行输入msconfig /all>d:\ip.txt

change_sh 发表于 2014-6-27 10:21:25

好复杂

皓轩你好 发表于 2014-7-11 14:27:20

谢谢楼主分享,宝贵资源

2012ass880 发表于 2014-8-10 09:42:23

本帖最后由 2012ass880 于 2014-8-10 09:43 编辑

zlgs 发表于 2014-7-9 21:59
求助还是教程啊? 我只知道命令行输入msconfig /all>d:\ip.txt

应该是ipconfig命令

2012ass880 发表于 2014-8-10 09:43:07

2012ass880 发表于 2014-8-10 09:42
应该是ipmsconfig命令

ipconfig

zlgs 发表于 2014-8-11 13:29:27

2012ass880 发表于 2014-8-10 09:43
ipconfig

谢谢纠正
命令提示行下查询
ipconfig /all
想复制粘贴地址可定向生成文件
ipconfig /all >d:\ip.txt

lbw2007 发表于 2014-8-25 06:31:47

谢谢分享,很需要!

saiz 发表于 2014-8-30 22:31:12

TO pznpt大大
十分感謝 用途很大!
但希望能多加點功能
如查詢PCNAME跟DOMAIN
ControlSet001\services\Tcpip\Parameters之下的HOSTNAME,DOMAIN
另外 因為我電腦上沒有ControlSet001
根據此篇所說
才知道 因為曾用過"最近一次的正確配置",造成只有2,3,4
程式能力不足 只能提供思路
非常希望能新增以上功能
麻煩拜託了!!
感謝! orz
是否可加上判斷式自動變改為ControlSet002 003 004等

邪恶海盗 发表于 2014-8-31 19:23:44

pznpt 发表于 2014-6-2 19:30
P处理

在 XP 上貌似有点小问题,改一下

建议再加几行代码,正确读取配置之后提示是否存储所得到的配置信息...

皓轩你好 发表于 2014-9-1 14:16:31

谢谢楼主分享资源,挺不错的

pznpt 发表于 2014-9-2 00:40:58

saiz 发表于 2014-8-30 22:31
TO pznpt大大
十分感謝 用途很大!
但希望能多加點功能


2楼请测试

zhuzihongyu 发表于 2017-4-26 21:57:34

谢谢分享!

zhuzihongyu 发表于 2017-4-29 18:50:20

pznpt 发表于 2014-9-2 00:40
2楼请测试

很不错在进不了系统时很有用

f2021z 发表于 2021-6-25 16:47:00

谢谢分享

33585190 发表于 2021-11-7 13:07:14

多谢楼主,试试看可以不

33585190 发表于 2021-11-7 13:07:54

谢谢分享给力

adslceo 发表于 2021-11-9 23:46:04

留痕,备不时之需。

chibuzhu 发表于 2021-11-14 14:42:07

学习了{:1_183:}

csh007001 发表于 2021-12-7 14:47:10

又伸手了

sounydqb 发表于 2022-4-17 11:54:05

感谢分享!

wang47zhe 发表于 2022-5-26 15:17:48

感谢大神分享

fu2010 发表于 2022-6-29 14:26:08

{:1_186:}

782159442 发表于 2022-10-20 10:43:24

支持

winlong102 发表于 2023-9-6 22:10:12

zlgs 发表于 2014-7-9 21:59
求助还是教程啊? 我只知道命令行输入msconfig /all>d:\ip.txt

人家都进不了系统了,怎么ipconfig

dayeye 发表于 2023-9-7 00:51:14

#在这里快速回复#        很给力!

hy77213 发表于 2023-12-12 15:42:38

pznpt 发表于 2014-6-2 19:30
P处理 获取网卡名称及IP信息.bat
考虑到在WinPE中运行,但PE精简程度不一样,除reg.exe外,未使用其它外部 ...

可以增加一下,获取网卡的MAC地址吗

zzzlllxyt 发表于 2023-12-14 10:59:03

谢谢分享
页: [1]
查看完整版本: 就是说系统进不了,可是想知道本地IP及网关、DNS