虚拟磁盘自动挂载与卸载
本帖最后由 nttwqz 于 2016-10-7 12:46 编辑咳咳,还是那句话,大神请绕道。也不晓得要发到哪个区,本坛有还是没有,如果有,请版主删除,如果区不对,请版主移贴。
本来自己修改PE用VHD挂载与卸载都是通过计算机管理实现,但是,后来觉得太繁琐了,想写个批处理来实现,后来写出来了,是手动选择的,要输入,还是觉得麻烦,于是就做成了自动的了。打开,已挂载,则卸载;已卸载,则挂载。就像拉线式电灯开关,拉一次就好了。
filepath=后面的内容是个例子,改成自己的路径,也可以改成%1或%~f1,建个快捷方式到发送到文件夹,以后只要右键vhd文件发送到即可自动挂载与卸载。
需要管理员权限,建立个快捷方式,属性→快捷方式选项卡→高级→用管理员身份运行。
@echo off
color 3f
title 虚拟磁盘自动挂载与卸载
reg query HKU\S-1-5-20>nul 2>nul||echo 需要管理员权限运行!&&pause>Nul&&exit
rem 全自动挂载与卸载指定虚拟磁盘文件
rem 打开后自动检测并执行,若已挂载,则卸载,若已经卸载,则挂载。
rem 请将虚拟磁盘文件的完整路径写在”filepath=“后面,支持带空格路径。
rem “autoopen=ON” 可在挂载后自动打开虚拟磁盘上的所有分区,“ON”改成其它值则不打开。
rem 设置
set filepath=C:\Users\ABC\VirtualBox VMs\7\asdfa.vhd
set autoopen=ON
if not exist "%filepath%" echo filepath设置错误,请检查并重试!&&pause>nul&&exit
pushd %~dp0\
rem 检测
echo select vdisk file="%filepath%">vdisktemp.txt
echo detail vdisk>>vdisktemp.txt
diskpart /s vdisktemp.txt|(findstr 找不到关联的磁盘号 >nul 2>nul)&&goto :挂载||goto :卸载
:挂载
echo select vdisk file="%filepath%">vdisk-attach.txt
echo attach vdisk>>vdisk-attach.txt
echo detail disk>>vdisk-attach.txt
diskpart /s vdisk-attach.txt>vdisklog.txt
for /f "tokens=3" %%a in ('findstr 磁盘分区 vdisklog.txt') do (if /i "%autoopen%"=="ON" start %%a:)
goto :清理临时文件
:卸载
echo select vdisk file="%filepath%">vdisk-detach.txt
echo detach vdisk>>vdisk-detach.txt
diskpart /s vdisk-detach.txt
goto :清理临时文件
:清理临时文件
del vdisk-attach.txt /f /q>nul 2>nul
del vdisk-detach.txt /f /q>nul 2>nul
del vdisktemp.txt /f /q>nul 2>nul
del vdisklog.txt /f /q>nul 2>nul
exit 不错,学习一下!
感谢分享! 真的不错,很好用!
谢谢楼主分享! 之前也有人发过,
感谢分享! lbw2007 发表于 2015-9-3 12:39
之前也有人发过,
感谢分享!
早知道我就搜索一下,也省的自己编了…… nttwqz 发表于 2015-9-3 15:40
早知道我就搜索一下,也省的自己编了……
就是这个,他也是转载别人的:
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=369369 lbw2007 发表于 2015-9-6 09:13
就是这个,他也是转载别人的:
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=369369
竟然是vbs脚本,我不会写。。。
前天也搜出来一个批处理(拖动版)。 不错!可以学习一下下…… 请教楼主,如果是VHD盘是加密的,代码里需写上密码,
这个如何写呢? 这个可以用到右键吗?须要TXT吗? 支持
页:
[1]