求一个自动创建子vhd的批处理谢谢

879792799 发表于 2019-11-28 15:14:24

本帖最后由 879792799 于 2023-3-6 12:31 编辑

求如下效果
拖动一个VHD文件到此批处理上
自动创建一个文件名*_child.vhd{vhdx}的{子vhd文件}====={*代表父VHD名称}

求大大指点一下谢谢

--------------------------------------------------------------------------------------
补充一：：：：本人在用的成品----食用方法@修改批处理中路径--运行批处理生成vhd右键菜单--在vhd上点击右键
依照10#singel大大指点！谢谢singel大大!!!! 还有另外一位大大--sorry我忘记是谁了{:3_140:} 也谢谢了！！
我也依葫芦画瓢拼凑一个非原创自己拼凑感觉不错供大大们参考一下
可以在线VHD制作{在多级vhd系统中当前正在用的子VHD不可以但是上一级的vhd可以创建}子vhd系统
注意更改批处理中对应文件路径
------------------------------------------------------------------------------------
@echo off
if "%1"=="" goto :reg

echo off
color 1f

:vhd_path
bcdedit -enum {current}|find /i "vhd="
if %errorlevel%==0 (set drive=D:) else set drive=C:

color 1f
cls
echo.
echo.请输入已创建父VHD文件的路径。
echo.
set vhd_path=%1
if "%vhd_path%"=="" goto :vhd_path
if not "%vhd_path:~1,2%"==":\" (
color 4f
cls
echo.
echo.路径输入错误。
echo.
set /p t=按回车键重输。
goto :vhd_path
)

for /f "delims==" %%i in ("%vhd_path%") do set sys_drive=%%~di

if not exist %sys_drive%\nul (
color 4f
cls
echo.
echo.%sys_drive:~0,1%盘不存在。
echo.
set /p t=按回车键重新输入。
goto :vhd_path
)

if /i "%vhd_path:~-4%"==".vhd" (
for /f "delims==" %%i in ("%vhd_path%") do set vhd_name=%%~ni
for /f "delims==" %%i in ("%vhd_path%") do set sys_folder=%%~pi
) else (
for /f "delims==" %%i in ("%vhd_path%") do set vhd_name=Win7
for /f "delims==" %%i in ("%vhd_path%") do set sys_folder=%%~pnxi
)

if "%sys_folder:~-1%"=="\" set sys_folder=%sys_folder:~0,-1%

if "%sys_folder%"=="" (
COLOR 4f
cls
echo.
echo.请勿将路径设在分区根目录
echo.
set /p t=按回车键重输。
goto :vhd_path
)

if not exist "%sys_drive%%sys_folder%\%vhd_name%.vhd" (
COLOR 4f
cls
echo.
echo."%sys_drive%%sys_folder%\%vhd_name%.vhd"不存在。
echo.
set /p t=按回车键重输。
goto :vhd_path
)

:sub

color 1f
cls
echo.
echo.输入子VHD文件的名字。
echo.
set sub_name=
set /p sub_name=请输入：
if "%sub_name%"=="" goto :sub

color 0f
cls
echo.
echo.正在创建子VHD文件。。。
echo.

echo create vdisk file="%sys_drive%%sys_folder%\%sub_name%.vhd" parent="%sys_drive%%sys_folder%\%vhd_name%.vhd" > "%temp%\create.txt"
diskpart /s "%temp%\create.txt"

color 1f
cls
echo.
echo.已成功创建子VHD文件。
pause

exit
goto eof

:reg
reg add "HKCR\Windows.VhdFile\shell\vparent" /f /ve /t REG_SZ /d "建立差分VHD"
reg add "HKCR\Windows.VhdFile\shell\vparent\command" /f /ve /t REG_SZ /d "E:\创建子VHD.bat %%1"

goto eof
-----------------------------------------------------------------------------------
红字部分需要依照自己需要更改对应路径

===================================================================

newyun 发表于 2019-11-28 15:47:15

*又代表什么

kkkssc 发表于 2019-11-28 16:48:46

本帖最后由 kkkssc 于 2019-11-28 16:54 编辑

cmd /c "echo create vdisk file=C:\*_child.vhd maximum=2048 type=FIXED & echo select vdisk file=C:\*_child.vhd & echo attach vdisk & echo create partition primary & echo active & echo assign letter=VHD2G & echo format fs=NTFS quick label=VHD2G & echo exit"|diskpart.exe

要用管理员身份运行，上面的参数自己改

liujun2000 发表于 2019-11-28 18:27:01

;Windows cmd批处理脚本，一键创建/挂载/格式化/分离，VHD虚拟硬盘
@echo off
;Cacls．exe命令
;这是一个在Windows 2000/XP/Server 2003操作系统下都可以使用的命令，作用是显示或者修改文件的访问控制表，在命令中可以使用通配符指定多个文件，也可以在命令中指定多个用户。
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
if exist %tmp%\vhdconf (del /f /q %tmp%\vhdconf)
title Www.ZhiQiang.Name
mode con: cols=45 lines=10
color 2F
pushd "%~dp0"
for /f "delims=" %%i in ('dir /b %~dp0^|findstr ".*\.vhd"') do (set name=%%i)
:menu
cls
echo.
echo 1.挂载 %name%
echo.
echo 2.分离 %name%
echo.
echo 3.创建 VHD
echo.
echo 4.格式化 %name%
echo.
choice /C:1234 /N /M "请输入你的选择"：
if errorlevel 4 goto:vhdformat
if errorlevel 3 goto:vhdadd
if errorlevel 2 goto:vhdoff
if errorlevel 1 goto:vhdon
:vhdon
echo SELECT VDISK FILE= "%~dp0%name%" >%tmp%\vhdconf
echo ATTACH VDISK NOERR >>%tmp%\vhdconf
echo LIST DISK >>%tmp%\vhdconf
DISKPART /s %tmp%\vhdconf > nul
exit
:vhdoff
echo SELECT VDISK FILE= "%~dp0%name%" >%tmp%\vhdconf
echo ATTACH VDISK NOERR >>%tmp%\vhdconf
echo DETACH VDISK >>%tmp%\vhdconf
echo LIST DISK >>%tmp%\vhdconf
DISKPART /s %tmp%\vhdconf > nul
exit
:vhdadd
cls
echo.
echo 自定义vhd虚拟硬盘文件名称与大小,按回车
echo.
set /p newname=文件名：
echo.
set /p value=大小(G):
set /a mx = (value)*(1024)
echo CREATE VDISK FILE="%~dp0%newname%.vhd" TYPE=FIXED MAXIMUM=%mx% >>%tmp%\vhdconf
echo SELECT VDISK FILE="%~dp0%newname%.vhd" >>%tmp%\vhdconf
echo ATTACH VDISK NOERR >>%tmp%\vhdconf
echo CLEAN >>%tmp%\vhdconf
echo CREATE PARTITION PRIMARY >>%tmp%\vhdconf
echo FORMAT FS=NTFS QUICK >>%tmp%\vhdconf
echo ASSIGN >>%tmp%\vhdconf
DISKPART /s %tmp%\vhdconf > nul
exit
:vhdformat
echo SELECT VDISK FILE="%~dp0%name%" >>%tmp%\vhdconf
echo ATTACH VDISK NOERR >>%tmp%\vhdconf
echo CLEAN >>%tmp%\vhdconf
echo CREATE PARTITION PRIMARY >>%tmp%\vhdconf
echo FORMAT FS=NTFS QUICK >>%tmp%\vhdconf
echo ASSIGN >>%tmp%\vhdconf
DISKPART /s %tmp%\vhdconf > nul
exit

879792799 发表于 2019-11-28 20:26:50

kkkssc 发表于 2019-11-28 16:48
cmd /c "echo create vdisk file=C:\*_child.vhd maximum=2048 type=FIXED & echo select vdisk file=C:\*_ ...

多谢大大我去试一下{:1_195:}

flyer809 发表于 2019-11-29 09:35:00

好东西，支持

ngy 发表于 2019-12-5 10:49:55

唉！！！！！！！！！

ngy 发表于 2019-12-5 10:49:59

唉！！！！！！！！！

879792799 发表于 2019-12-5 13:23:38

ngy 发表于 2019-12-5 10:49
唉！！！！！！！！！

咋了？？是不是哪里不对请指点指点！！

singel 发表于 2019-12-10 04:40:34

@echo off
if "%1"=="" goto :reg

set vhd_file=%1
if exist "%temp%\attach.txt" del "%temp%\attach.txt"

echo select vdisk file="%vhd_file%">"%temp%\attach.txt"
echo compact vdisk>>"%temp%\attach.txt"
echo create vdisk file="%vhd_file:win=win_1%" parent="%vhd_file%">>"%temp%\attach.txt"
diskpart /s "%temp%\attach.txt"
del "%temp%\attach.txt"
goto eof

:reg
reg add "HKCR\Windows.VhdFile\shell\vparent" /f /ve /t REG_SZ /d "建立差分VHD"
reg add "HKCR\Windows.VhdFile\shell\vparent\command" /f /ve /t REG_SZ /d "D:\VHDTest\vparent.cmd %%1"
goto eof

879792799 发表于 2019-12-10 10:12:34

本帖最后由 879792799 于 2019-12-10 10:19 编辑

singel 发表于 2019-12-10 04:40

谢谢大大我用的过程中出现百分比的cmd窗口过一会一闪关闭了没有找到建立的子文件
什么原因了？？大大
补充一：大大是不是要排除正在使用用VHD文件我试了另外一个离线的VHD可以成功！！！

singel 发表于 2019-12-13 17:42:51

879792799 发表于 2019-12-10 10:12
谢谢大大我用的过程中出现百分比的cmd窗口过一会一闪关闭了没有找到建立的子文件
什么原因了？ ...

确实是，正在使用的不行。

zhangz9 发表于 2023-5-16 23:25:19

学习了

页: [1]

无忧启动论坛's Archiver

求一个自动创建子vhd的批处理 谢谢

求一个自动创建子vhd的批处理谢谢