无忧启动论坛

标题: 你有办法破解已加密的.bat吗？ [打印本页]

作者: kidzgy 时间: 2007-7-7 20:10
标题: 你有办法破解已加密的.bat吗？
试试看！！

右键编辑竟然是一堆乱码，在临时文件夹根本找不着，看进程就一目了然，完全是他本身来的。

5.73 KB, 下载次数: 323, 下载积分: 无忧币 -2

作者: lianjiang 时间: 2007-7-7 20:47
试了一下，可以还原。方法到dos联盟去找。
--------------------------------------
cls
@echo off
:start
mode con cols=80 lines=34&color fc
cls
title 黑菜整合盘第8版__多功能系统优化设置控制台
echo.
ECHO                      《多功能系统优化设置控制台》 ——黑菜整理制作
echo.
echo ╭───────────§──────────§────────────╮
ECHO │                   §部分功能需重启后实现§                      │
ECHO │                   §──────────§                      │
ECHO │          A. 更改默认安装路径至任意盘符的Program Files文件夹       │
ECHO │          B. 转移系统文件到任意盘符 (建议刚装机完使用，慎用!)       │
ECHO │          C. 清除任何显卡生成的右键多余菜单                         │
ECHO │          D. 右键增加“用记事本打开此文件”                         │
ECHO │          E. 右键增加“用命令行打开此文件夹”                      │
ECHO │          F. 右键增加“复制到、移动到文件夹”                      │
ECHO │          G. 删除IPC$默认共享                                     │
ECHO │          H. IE7或WMP11或Defender的安装破解                         │
ECHO │          I. EXE可执行文件的关联修复                               │
ECHO │          J. 从我的电脑里移除共享文档                               │
ECHO │          K. 去除IE限制及主页恢复空白页                            │
ECHO │          L. 修复IE重新注册组件                                     │
ECHO │          M. IE6开启10线程下载                                     │
ECHO │          N. 恢复快捷方式上的小箭头                               │
ECHO │          O. 删除快捷方式上的小箭头                               │
ECHO │          P. 令本机U盘成为只读 (需重插拔)                         │
ECHO │          Q. 恢复本机U盘为可写 (需重插拔)                         │
ECHO │          R. 关闭所有驱动器自动播放                               │
ECHO │          S. 设置自动登录                                           │
ECHO │          T. 分区计算出整数G的方法                                  │
ECHO │          U. 退出                                                 │
ECHO │                                                                   │
ECHO ╰───────────────────────────────────╯
echo.
SET Choice=
SET /P Choice= 请选择要进行的操作（A/B/C/D/E/F/G/H/I/J/K/L/M/N/O/P/Q/R/S），然后按回车：
ECHO.
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
IF /I '%Choice%'=='A' GOTO A
IF /I '%Choice%'=='B' GOTO B
IF /I '%Choice%'=='C' GOTO C
IF /I '%Choice%'=='D' GOTO D
IF /I '%Choice%'=='E' GOTO E
IF /I '%Choice%'=='F' GOTO F
IF /I '%Choice%'=='G' GOTO G
IF /I '%Choice%'=='H' GOTO H
IF /I '%Choice%'=='I' GOTO I
IF /I '%Choice%'=='J' GOTO J
IF /I '%Choice%'=='K' GOTO K
IF /I '%Choice%'=='L' GOTO L
IF /I '%Choice%'=='M' GOTO M
IF /I '%Choice%'=='N' GOTO N
IF /I '%Choice%'=='O' GOTO O
IF /I '%Choice%'=='P' GOTO P
IF /I '%Choice%'=='Q' GOTO Q
IF /I '%Choice%'=='R' GOTO R
IF /I '%Choice%'=='S' GOTO S
IF /I '%Choice%'=='T' GOTO T
IF /I '%Choice%'=='U' GOTO U
GOTO Start
:A
CLS
echo.
SET select0=
SET /P select0= 请输入默认安装软件的盘符（默认为D盘），然后按回车：
IF '%select0%'=='' (set select0=D)
ECHO.
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion" /f /v "ProgramFilesDir" /d "%select0%:\Program Files"  >nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion" /f /v "CommonFilesDir" /d "%select0%:\Program Files\\Common Files" >nul
cls
echo.
echo.
echo.
echo.
echo             更改软件默认安装路径完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:B
cls
echo.
echo 此操作为经常Ghost还原C盘者带来方便。
echo.
echo 将从C盘移出以下5个文件夹：
echo ●  Desktop(桌面)
echo ●  Favorites(收藏夹)
echo ●  My Documents(我的文档)
echo ●  Temporary Internet Files(Internet临时文件)
echo ●  Temp(临时文件夹)。
echo.
SET queren=
SET /P queren= 注意!建议刚刚装完系统者使用!新手慎用!!!（确认转移请按Y，取消返回请按N。）
IF '%queren%'=='' GOTO B
IF NOT '%queren%'=='' SET queren=%queren:~0,1%
IF /I '%queren%'=='Y' GOTO next
IF /I '%queren%'=='N' GOTO start
:next
echo.
SET select=
SET /P select= 请输入将转移的目的盘符（默认为D盘），然后按回车：
IF '%select%'=='' (SET select=D)
ECHO.
echo REGEDIT4 >%systemroot%\shell.reg
echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]>>%systemroot%\shell.reg
echo "Cache"="%select%:\\Personal\\Temporary Internet Files">>%systemroot%\shell.reg
echo "Desktop"="%select%:\\Personal\\Desktop">>%systemroot%\shell.reg
echo "Favorites"="%select%:\\Personal\\Favorites">>%systemroot%\shell.reg
echo "Personal"="%select%:\\Personal\\My Documents">>%systemroot%\shell.reg
echo "My Music"="%select%:\\Personal\\My Documents\\My Music">>%systemroot%\shell.reg
echo "My Pictures"="%select%:\\Personal\\My Documents\\My Pictures">>%systemroot%\shell.reg
echo "Recent"="%select%:\\Personal\\Recent">>%systemroot%\shell.reg
echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders]>>%systemroot%\shell.reg
echo "Cache"="%select%:\\Personal\\Temporary Internet Files">>%systemroot%\shell.reg
echo "Desktop"="%select%:\\Personal\\Desktop">>%systemroot%\shell.reg
echo "My Music"="%select%:\\Personal\\My Documents\\My Music">>%systemroot%\shell.reg
echo "My Pictures"="%select%:\\Personal\\My Documents\\My Pictures">>%systemroot%\shell.reg
echo "Favorites"="%select%:\\Personal\\Favorites">>%systemroot%\shell.reg
echo "Personal"="%select%:\\Personal\\My Documents">>%systemroot%\shell.reg
echo "Recent"="%select%:\\Personal\\Recent">>%systemroot%\shell.reg
echo [HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]>>%systemroot%\shell.reg
echo "Desktop"="%select%:\\Personal\\Desktop">>%systemroot%\shell.reg
echo "Cache"="%select%:\\Personal\\My Documents">>%systemroot%\shell.reg
echo "Download Directory"="%select%:\\Personal\\My Documents">>%systemroot%\shell.reg
echo [HKEY_CURRENT_USER\Environment]>>%systemroot%\shell.reg
echo "TEMP"="%select%:\\Personal\Temp">>%systemroot%\shell.reg
echo "TMP"="%select%:\\Personal\\Temp">>%systemroot%\shell.reg
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment]>>%systemroot%\shell.reg
echo "TEMP"="D:\\personal\\TEMP">>%systemroot%\shell.reg
echo "TMP"="D:\\personal\\TEMP">>%systemroot%\shell.reg
regedit.exe /s %systemroot%\shell.reg
::del /F /Q %systemroot%\shell.reg
md "%select%:\Personal\Temp\">nul 2>nul
md "%select%:\Personal\My Documents\">nul 2>nul
xcopy C:\Docume~1\%USERNAME%\Mydocu~1\*.* %select%:\Personal\Mydocu~1\ /e /y>nul 2>nul
md "%select%:\Personal\Desktop\">nul 2>nul
xcopy C:\Docume~1\%USERNAME%\Desktop\*.* %select%:\Personal\Desktop\ /e /y>nul 2>nul
md "%select%:\Personal\Desktop\">nul 2>nul
xcopy C:\Docume~1\%USERNAME%\桌面\*.* %select%:\Personal\Desktop\ /e /y>nul 2>nul
md "%select%:\Personal\Favorites\">nul 2>nul
xcopy C:\Docume~1\%USERNAME%\Favori~1\*.* %select%:\Personal\Favori~1\ /e /y>nul 2>nul
if exist "%select%:\Personal\My Documents\Desktop.ini" goto shell1
echo [DeleteOnCopy]>"%select%:\Personal\My Documents\Desktop.ini"
echo Owner=Administrator>>"%select%:\Personal\My Documents\Desktop.ini"
echo Personalized=5 >>"%select%:\Personal\My Documents\Desktop.ini"
echo PersonalizedName=My Documents>>"%select%:\Personal\My Documents\Desktop.ini"
attrib "%select%:\Personal\My Documents\Desktop.ini" +s +h>nul 2>nul
:shell1
if exist "%select%:\Personal\My Documents\My Music\Desktop.ini" goto shell2
echo [DeleteOnCopy] >"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo Owner=Administrator>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo Personalized=13>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo PersonalizedName=My Music>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo [.ShellClassInfo]>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo InfoTip=@Shell32.dll,-12689>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo IconFile=%SystemRoot%\system32\SHELL32.dll>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
echo IconIndex=-237>>"%select%:\Personal\My Documents\My Music\Desktop.ini"
attrib "%select%:\Personal\My Documents\My Music\Desktop.ini" +s +h>nul 2>nul
:shell2
if exist "%select%:\Personal\My Documents\My pictures\Desktop.ini" goto shell3
echo [DeleteOnCopy]>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo Owner=Administrator>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo Personalized=39>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo PersonalizedName=My Pictures>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo [.ShellClassInfo]>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo InfoTip=@Shell32.dll,-12688>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo IconFile=%SystemRoot%\system32\mydocs.dll>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
echo IconIndex=-101>>"%select%:\Personal\My Documents\My pictures\Desktop.ini"
attrib "%select%:\Personal\My Documents\My pictures\Desktop.ini" +s +h>nul 2>nul
:shell3
cls
echo.
echo.
echo.
echo.
echo             转移系统文件完毕!
echo.
echo             请保存好资料。即将为你重启。
echo.
:yn1
SET yn=
SET /P yn=             （确认重启请按Y，稍后重启请按N。）
IF '%yn%'=='' GOTO yn1
IF /I '%yn%'=='Y' GOTO restart
IF /I '%yn%'=='N' GOTO norestart
:restart
shutdown -r -f -t 10 -c 转移系统文件后需要重新启动才有效。现在将在10秒内重启计算机
pause>nul
:norestart
cls
color 0c
echo.
echo  您选择了稍后重启。但注意请不要再对"桌面"，"收藏夹"，"我的文档"进行存放文件操作
echo.
echo  按任意键返回。
pause>nul
GOTO Start
:C
regsvr32 /u /s igfxpph.dll
reg delete HKEY_CLASSES_ROOT\Directory\Background\shellex\ContextMenuHandlers /f
reg add HKEY_CLASSES_ROOT\Directory\Background\shellex\ContextMenuHandlers\new /ve /d {D969A300-E7FF-11d0-A93B-00A0C90F2719} /f
cls
echo.
echo.
echo.
echo.
echo             清楚显卡右键菜单完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:D
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\txt.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Classes\*\shell]>>%systemroot%\txt.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Classes\*\shell\heicai]>>%systemroot%\txt.reg
echo @="用记事本打开此文件">>%systemroot%\txt.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Classes\*\shell\heicai\command]>>%systemroot%\txt.reg
echo @="notepad.exe \"%%1\"" >>%systemroot%\txt.reg
regedit.exe /s %systemroot%\txt.reg
del /F /Q %systemroot%\txt.reg
cls
echo.
echo.
echo.
echo.
echo             右键增加记事本完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:E
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\floder.reg
echo [HKEY_CLASSES_ROOT\Directory]>>%systemroot%\floder.reg
echo @="文件夹">>wenjianjia.reg>>%systemroot%\floder.reg
echo "AlwaysShowExt"="">>wenjianjia.reg>>%systemroot%\floder.reg
echo "EditFlags"=hex:d2,01,00,00>>%systemroot%\floder.reg
echo "InfoTip"="prop:Comment">>%systemroot%\floder.reg
echo [HKEY_CLASSES_ROOT\Directory\shell]>>%systemroot%\floder.reg
echo @="none">>%systemroot%\floder.reg
echo [HKEY_CLASSES_ROOT\Directory\shell\cmd]>>%systemroot%\floder.reg
echo @="用命令行打开此文件夹">>%systemroot%\floder.reg
echo [HKEY_CLASSES_ROOT\Directory\shell\cmd\command]>>%systemroot%\floder.reg
echo @="cmd.exe /k \"cd %%L\"">>%systemroot%\floder.reg
regedit.exe /s %systemroot%\floder.reg
del /F /Q %systemroot%\floder.reg
cls
echo.
echo.
echo.
echo.
echo             右键增加命令行完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:F
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\fzyd.reg
echo [HKEY_CLASSES_ROOT\AllFilesystemObjects\shellex\ContextMenuHandlers]>>%systemroot%\fzyd.reg
echo [HKEY_CLASSES_ROOT\AllFilesystemObjects\shellex\ContextMenuHandlers\复制到]>>%systemroot%\fzyd.reg
echo @="{C2FBB630-2971-11D1-A18C-00C04FD75D13}">>%systemroot%\fzyd.reg
echo [HKEY_CLASSES_ROOT\AllFilesystemObjects\shellex\ContextMenuHandlers\移动到]>>%systemroot%\fzyd.reg
echo @="{C2FBB631-2971-11D1-A18C-00C04FD75D13}">>%systemroot%\fzyd.reg
regedit /s %systemroot%\fzyd.reg
del /F /Q %systemroot%\fzyd.reg
cls
echo.
echo.
echo.
echo.
echo             右键增加复制、移动到文件夹完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:G
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\delshare.reg
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]>>%systemroot%\delshare.reg
echo "AutoShareWks"=dword:00000000>>%systemroot%\delshare.reg
echo "AutoShareServer"=dword:00000000>>%systemroot%\delshare.reg
regedit /s %systemroot%\delshare.reg
del /F /Q %systemroot%\delshare.reg
cls
net stop server /y
net start server
cls
echo.
echo.
echo.
echo.
echo             删除IPC$默认共享完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:H
cls
del /f /s /q "%systemdrive%\Documents and Settings\All Users\Application Data\Windows Genuine Advantage\data\data.dat"
cls
echo.
echo.
echo.
echo.
echo             破解完毕!请断网后再安装IE7或WMP11或Defender
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:I
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\exexf.reg
echo [HKEY_CLASSES_ROOT\exefile\shell\open\command]>>%systemroot%\exexf.reg
echo @="\"%%1\" %%*">>%systemroot%\exexf.reg
regedit /s %systemroot%\exexf.reg
del /F /Q %systemroot%\exexf.reg
cls
echo.
echo.
echo.
echo.
echo             EXE关联修复完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:J
cls
REG ADD "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoSharedDocuments" /t REG_DWORD /d 1 /f >nul 2>nul
REG ADD "HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoSharedDocuments" /t REG_DWORD /d 1 /f  >nul 2>nul
reg delete HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\DelegateFolders\{59031a47-3f72-44a7-89c5-5595fe6b30ee} /F >nul 2>nul
cls
echo.
echo.
echo.
echo.
echo             移除共享文档完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:K
cls
echo.
echo       ●  恢复主页修改
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v homepage /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  恢复IE的默认页面和起始为空白页
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Default_Page_URL" /d "about:blank">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Start Page" /d "about:blank">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer\Main" /f /v "Default_Page_URL" /d "about:blank">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer\Main" /f /v "Start Page" /d "about:blank">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main" /f /v "Local Page" /d "about:blank">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main" /f /v "Window Title" /d "Microsoft Internet Explorer">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main" /f /v "SearchAssistant" /d "about:blank">nul 2>nul
echo       ●  恢复IE工具栏的链接名称
reg add "HKCU\Software\Microsoft\Internet Explorer\Toolbar" /f /v LinksFolderName /d "链接">nul 2>nul
echo       ●  恢复IE地址默认前缀
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\URL\DefaultPrefix" /f /ve /d "http://">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\URL\Prefixes" /f /v www /d "http://">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\URL\Prefixes" /f /v ftp /d "ftp://">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main\UrlTemplate" /f /v 1 /d "www.%s.com">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main\UrlTemplate" /f /v 2 /d "www.%s.net">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main\UrlTemplate" /f /v 2 /d "www.%s.org">nul 2>nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Main\UrlTemplate" /f /v 2 /d "www.%s.edu">nul 2>nul
echo       ●  清除IE地址栏垃圾
reg delete "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\URLSearchHooks" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\TypeURLs" /f>nul 2>nul
echo       ●  恢复IE工具栏不能定制的限制
echo Y|reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\" /v NoBandCustomize /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\TypeURLs" /f>nul 2>nul
echo       ●  恢复internet选项安全页面自定义按钮
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v SecChangeSettings  REG_DWORD /d 00000000>nul 2>nul
echo       ●  恢复IE浏览器缺省主页的设置锁定状态
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v Settings /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v Links /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v SecAddSites /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKU\.DEFAULT\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v homepage /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  恢复允许下载
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3" /f /v 1803 /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Restrictions" /f /v NoSelectDownloadDir /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKLM\Software\Policies\Microsoft\Internet Explorer\Restrictions" /f /v NoSelectDownloadDir /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  删除分级审查密码
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\Policies\Ratings" /f>nul 2>nul
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\Policies\Ratings">nul 2>nul
echo       ●  恢复internet选项
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\restrictions" /f /v NoBrowserOptions /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /f /v NoFolderOptions /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v GeneralTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v SecurityTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v ContentTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v ConnectionsTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v ProgramsTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v AdvancedTab /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v Advanced /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v ConnectionSettings /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v Check_If_Default /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Control Panel" /f /v ResetWebSettings /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  修复IE察看源文件按钮
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Restrictions" /f /v NoViewSource /t REG_DWORD /d 00000000>nul 2>nul
reg add "HKLM\Software\Policies\Microsoft\Internet Explorer\Restrictions" /f /v NoViewSource /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  修复网页中右键菜单的广告
reg delete "HKCU\Software\Microsoft\Internet Explorer\MenuExt" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\MenuExt" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Internet Explorer\MenuExt2" /f>nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\MenuExt2" /f>nul 2>nul
echo       ●  恢复网页右键菜单
reg add "HKCU\Software\Policies\Microsoft\Internet Explorer\Restrictions" /f /v NoBrowserContextMenu /t REG_DWORD /d 00000000>nul 2>nul
echo       ●  恢复IE标题栏
reg add "HKLM\Software\Microsoft\Internet Explorer\Main" /f /v "Window Title" /d "Microsoft Internet Explorer">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Window Title" /d "Microsoft Internet Explorer">nul 2>nul
echo       ●  恢复IE搜索引擎
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Search Page" /d "http://www.google.com/intl/zh-CN/">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "SearchAssistant" /d "about:blank">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "CustomizeSearch" /d "about:blank">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "SearchUrl" /d "about:blank">nul 2>nul
reg add "HKCU\Software\Microsoft\Internet Explorer\" /f /ve /d "http://ie.search.msn.com/{SUB_RFC1766}/srchasst/srchasst.htm">nul 2>nul
reg add "HKLM\Software\Microsoft\Internet Explorer\Main" /f /v "Search Page" /d "http://www.google.com/intl/zh-CN/">nul 2>nul
reg add "HKLM\Software\Microsoft\Internet Explorer\Main" /f /v "SearchAssistant" /d "about:blank">nul 2>nul
reg add "HKLM\Software\Microsoft\Internet Explorer\Main" /f /v "CustomizeSearch" /d "about:blank">nul 2>nul
reg add "HKLM\Software\Microsoft\Internet Explorer\Main" /f /v "SearchUrl" /d "about:blank">nul 2>nul
reg add "HKLM\Software\Microsoft\Internet Explorer\" /f /ve /d "about:blank">nul 2>nul
echo       ●  修复IE工具栏广告
reg delete "HKLM\Software\Microsoft\Internet Explorer\Extensions" /f>nul 2>nul
reg delete "HKCU\Software\Microsoft\Internet Explorer\Extensions" /f>nul 2>nul
echo.
echo.
echo.
echo.
echo             去除IE限制及主页恢复空白页完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:L
cls
echo.
echo.
echo             请稍等，进行中……
rundll32.exe advpack.dll /DelNodeRunDLL32 %systemroot%\System32\dacui.dll
rundll32.exe advpack.dll /DelNodeRunDLL32 %systemroot%\Catroot\icatalog.mdb
regsvr32 /s comcat.dll
regsvr32 /s asctrls.ocx
regsvr32 /s oleaut32.dll
regsvr32 /s shdocvw.dll /I
regsvr32 /s shdocvw.dll
regsvr32 /s browseui.dll
regsvr32 /s browseui.dll /I
regsvr32 /s msrating.dll
regsvr32 /s mlang.dll
regsvr32 /s hlink.dll
regsvr32 /s mshtml.dll
regsvr32 /s mshtmled.dll
regsvr32 /s urlmon.dll
regsvr32 /s plugin.ocx
regsvr32 /s sendmail.dll
regsvr32 /s mshtml.dll /i
regsvr32 /s scrobj.dll
regsvr32 /s corpol.dll
regsvr32 /s jscript.dll
regsvr32 /s msxml.dll
regsvr32 /s imgutil.dll
regsvr32 /s cryptext.dll
regsvr32 /s inseng.dll
regsvr32 /s iesetup.dll /i
regsvr32 /s cryptdlg.dll
regsvr32 /s actxprxy.dll
regsvr32 /s dispex.dll
regsvr32 /s occache.dll
regsvr32 /s iepeers.dll
regsvr32 /s urlmon.dll /i
regsvr32 /s cdfview.dll
regsvr32 /s webcheck.dll
regsvr32 /s mobsync.dll
regsvr32 /s pngfilt.dll
regsvr32 /s licmgr10.dll
regsvr32 /s hhctrl.ocx
regsvr32 /s inetcfg.dll
regsvr32 /s trialoc.dll
regsvr32 /s tdc.ocx
regsvr32 /s MSR2C.DLL
regsvr32 /s msident.dll
regsvr32 /s msieftp.dll
regsvr32 /s xmsconf.ocx
regsvr32 /s ils.dll
regsvr32 /s msoeacct.dll
regsvr32 /s wab32.dll
regsvr32 /s wabimp.dll
regsvr32 /s wabfind.dll
regsvr32 /s oemiglib.dll
regsvr32 /s directdb.dll
regsvr32 /s inetcomm.dll
regsvr32 /s msoe.dll
regsvr32 /s oeimport.dll
regsvr32 /s msdxm.ocx
regsvr32 /s dxmasf.dll
regsvr32 /s laprxy.dll
regsvr32 /s l3codecx.ax
regsvr32 /s acelpdec.ax
regsvr32 /s mpg4ds32.ax
regsvr32 /s danim.dll
regsvr32 /s Daxctle.ocx
regsvr32 /s lmrt.dll
regsvr32 /s datime.dll
regsvr32 /s dxtrans.dll
regsvr32 /s dxtmsft.dll
regsvr32 /s wshom.ocx
regsvr32 /s wshext.dll
regsvr32 /s vbscript.dll
regsvr32 /s scrrun.dll mstinit.exe /setup
regsvr32 /s msnsspc.dll /SspcCreateSspiReg
regsvr32 /s msapsspc.dll /SspcCreateSspiReg
regsvr32 /u /s shimgvw.dll
cls
echo.
echo.
echo.
echo.
echo             修复IE重新注册组件完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:M
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\xiancheng.reg
echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings]>>%systemroot%\xiancheng.reg
echo "MaxConnectionsPer1_0Server"=dword:00000010>>%systemroot%\xiancheng.reg
echo "MaxConnectionsPerServer"=dword:00000010>>%systemroot%\xiancheng.reg
regedit /s %systemroot%\xiancheng.reg
del /F /Q %systemroot%\xiancheng.reg
cls
echo.
echo.
echo.
echo.
echo             IE6开启10线程完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:N
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\jiantou.reg
echo [HKEY_CLASSES_ROOT\lnkfile]>>%systemroot%\jiantou.reg
echo "IsShortcut"="">>%systemroot%\jiantou.reg
echo [HKEY_CLASSES_ROOT\piffile]>>%systemroot%\jiantou.reg
echo "IsShortcut"="">>%systemroot%\jiantou.reg
regedit /s %systemroot%\jiantou.reg
del /F /Q %systemroot%\jiantou.reg
cls
echo.
echo.
echo.
echo.
echo             恢复快捷方式的小箭头完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:O
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\jiantou.reg
echo [HKEY_CLASSES_ROOT\lnkfile]>>%systemroot%\jiantou.reg
echo "IsShortcut"=->>%systemroot%\jiantou.reg
echo [HKEY_CLASSES_ROOT\piffile]>>%systemroot%\jiantou.reg
echo "IsShortcut"=->>%systemroot%\jiantou.reg
regedit /s %systemroot%\jiantou.reg
del /F /Q %systemroot%\jiantou.reg
cls
echo.
echo.
echo.
echo.
echo             删除快捷方式的小箭头完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:P
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\nowrite.reg
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies]>>%systemroot%\nowrite.reg
echo "WriteProtect"=dword:00000001>>%systemroot%\nowrite.reg
regedit /s %systemroot%\nowrite.reg
del /F /Q %systemroot%\nowrite.reg
cls
echo.
echo.
echo.
echo.
echo             令本机U盘成为只读完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:Q
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\nowrite.reg
echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\StorageDevicePolicies]>>%systemroot%\nowrite.reg
echo "WriteProtect"=dword:00000000>>%systemroot%\nowrite.reg
regedit /s %systemroot%\nowrite.reg
del /F /Q %systemroot%\nowrite.reg
cls
echo.
echo.
echo.
echo.
echo             恢复本机U盘为可写完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:R
cls
echo Windows Registry Editor Version 5.00 >%systemroot%\autorun.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\policies\Explorer]>>%systemroot%\autorun.reg
echo "NoDriveTypeAutoRun"=dword:000000ff>>%systemroot%\autorun.reg
regedit /s %systemroot%\autorun.reg
del /F /Q %systemroot%\autorun.reg
cls
echo.
echo.
echo.
echo.
echo             关闭所有驱动器自动播放完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:S
@echo off
cls
echo.
echo.
:setauto
SET autologon=
SET /P autologon=　　设置自动登录吗？设置(Y),取消(N),返回(Q):
IF /I '%autologon%'=='' GOTO setauto
IF /I '%autologon%'=='Y' (
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v "AutoAdminLogon" /d 1 >nul
GOTO startset
)
IF /I '%autologon%'=='N' (
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v "AutoAdminLogon" /d 0 >nul
GOTO cancel
)
IF /I '%autologon%'=='Q' GOTO start
:startset
echo.
SET /P USERNAME=　　请输入自动登录的用户后回车(默认Administrator的话直接回车)。
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v "DefaultUserName" /d "%USERNAME%" >nul
echo.
SET USERPASS=
SET /P USERPASS=　　请输入自动登录的密码后回车(默认为空的话直接回车)。
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v "DefaultPassword" /d "%USERPASS%" >nul
echo.
SET /P USERDOMAIN=　　请输入自动登录的用户域后回车(默认为空的话直接回车)。
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /f /v "DefaultDomainName" /d "%USERDOMAIN%" >nul
cls
echo.
echo.
echo.
echo.
echo             自动登录设置完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO start
:cancel
cls
echo.
echo.
echo.
echo.
echo             取消完毕!请记住登录密码。
echo.
echo             按任意键返回主菜单
pause>nul
GOTO start
:T
cls
echo 计算方法: 整数GB＝1024M×GB数＋(GB数-1)×4
echo.
echo 例:
echo 2 G=2052 M
echo 3 G=3080 M
echo 4 G=4108 M
echo 5 G=5136 M
echo 6 G=6164 M
echo 7 G=7192 M
echo 8 G=8224 M
echo 9 G=9248 M
echo 10 G=10276 M
echo 15 G=15416 M
echo 20 G=20556 M
echo 25 G=25696 M
echo 30 G=30836 M
echo 40 G=41116 M
echo.
echo.
echo.
echo.
echo             显示完毕!
echo.
echo             按任意键返回主菜单
pause>nul
GOTO Start
:U
del %0

作者: hytmtet 时间: 2007-7-7 20:54
同意楼上
一点难度没有

用winhex打开
然后全选
ctrl+c
到记事本粘贴

完成~

不过觉得改人家东西不好...

作者: lianjiang 时间: 2007-7-7 21:21
同意，改人家东西不好。
特别是全般照抄，只把别人的名字改掉就成自己东西的那种，应坚决反对。
不过借鉴和学习别人的思路和方法还是可以的。呵呵。

作者: jxf268 时间: 2007-7-8 15:18
用这个，文件类型选全部。

各式文本浏览器.rar

294.25 KB, 下载次数: 604, 下载积分: 无忧币 -2

作者: kidzgy 时间: 2007-7-8 17:05
我很想知道，为什么保存的时候竟然是乱码呢？

作者: kidzgy 时间: 2007-7-8 17:10
我不会拿全部般抄的，我也讨厌那种人，有几个功能常用的，我想取出来想知道原代码，所以。。。

原先我觉得好奇，怎么有加密的.bat呢？文本编辑怎么编辑不着呢，以为在这论坛上找不到解决办法，所以上传玩玩。

没想到，轻而易举！

作者: namejm 时间: 2007-7-8 20:14
　　破解代码来了：

@echo off
cd.>control.txt
for /f "skip=2 delims=" %%i in ('findstr /n .* control.bat') do (
set "str=%%i"
setlocal enabledelayedexpansion
set str=!str:*:=!
echo.!str!>>control.txt
endlocal
)
start control.txt

复制代码

作者: kidzgy 时间: 2007-7-9 06:23
:o :o :o :o 高手太多了，这里真是高手如云！

作者: anycrane 时间: 2007-7-9 13:30
用RAR看不就好了？？？？

RAR里右键文件选查看啊:L

作者: sangmei 时间: 2007-7-10 13:21

原帖由 anycrane 于 2007-7-9 01:30 PM 发表
用RAR看不就好了？？？？

RAR里右键文件选查看啊:L

........................高招！

作者: 沙漠之子 时间: 2007-7-11 01:54
仅仅使用winhex等编辑器修改了文件头2个字节而已

作者: 怪怪 时间: 2007-7-11 13:53
都是高手阿，努力学习中

作者: 33ch 时间: 2007-7-15 22:22

原帖由 hytmtet 于 2007-7-7 20:54 发表
同意楼上
一点难度没有

用winhex打开
然后全选
ctrl+c
到记事本粘贴

完成~

不过觉得改人家东西不好...

学了一手，winhex机子上存在很久，终于发挥作用了

作者: lizhenduo 时间: 2007-7-20 14:57
以上高手:
这个install_uninstall.bat文件用以上办法变成明文后就不能执行了,它的加密办法太高了,我想学习学习,请大家给予指导.谢谢.

install_uninstall.rar (121.64 KB, 下载次数: 122)

作者: gotowelcome 时间: 2007-7-20 16:15
学习中。。如果别人做了EXE的格式不知能否查看不

作者: su123 时间: 2007-7-24 01:32
高手太多了，这里真是高手如云！

作者: lianjiang 时间: 2007-7-24 10:02

原帖由 lizhenduo 于 2007-7-20 02:57 PM 发表
以上高手:
这个install_uninstall.bat文件用以上办法变成明文后就不能执行了,它的加密办法太高了,我想学习学习,请大家给予指导.谢谢.25521

@Echo Off
cls
mode con: cols=80 lines=26
Set TT=1KEY GHOST  (rebuild by lianjiang)
COLOR f9
TITLE %TT%
set winver=
if  exist %systemdrive%\boot.ini  goto winnt
cls
echo.
echo  Sorry ,this program is only for Windows 2k/xp/2k3.
PING/n 5 127.1>NUL
Goto Exit
:winnt
set winver=winnt
set ggpath0=%systemdrive%\dosh
set ggpath1=%systemdrive%
:g_boot1
if exist %ggpath1%\g_boot.ini goto g_boot_al >nul

if exist %ggpath1%\grldr (
attrib %ggpath1%\grldr -r -h -s >nul
copy %ggpath1%\grldr %ggpath1%\g_grldr >nul
)
if exist %ggpath1%\menu.lst ren %ggpath1%\menu.lst g_menu.lst >nul
myins x onekey.dll  %ggpath1%\ -y >nul
Copy %ggpath0%\tools\grldr %ggpath1%\ /y >nul
attrib %ggpath1%\grldr +r +h +s >nul
rem attrib %ggpath0% +r +h +s >nul
:add1
attrib %ggpath1%\boot.ini -r -h -s >nul
Copy %ggpath1%\boot.ini %ggpath1%\g_boot.ini /y >nul
%ggpath0%\tools\inifile %ggpath1%\boot.ini [boot loader] timeout=3 >nul
%ggpath0%\tools\inifile %ggpath1%\boot.ini [operating systems] %ggpath1%\grldr="1KEY GHOST (rebuild by lianjiang)" >nul
attrib %ggpath1%\boot.ini +r +h +s >nul
attrib %ggpath1%\g_boot.ini +r +h +s >nul

Goto exit
:g_boot_al
cls
echo.
echo Uninstall 1KEY GHOST (rebuild by lianjiang).
echo.
echo -------------------------------------
pause>nul
attrib %ggpath1%\boot.ini -r -h -s >nul
if exist %ggpath1%\g_boot.ini attrib %ggpath1%\g_boot.ini -r -h -s >nul
if exist %ggpath1%\g_grldr attrib %ggpath1%\g_grldr -r -h -s >nul
if exist %ggpath1%\grldr attrib %ggpath1%\grldr -r -h -s >nul
if not exist %ggpath1%\g_boot.ini  goto sub_30 >nul
copy %ggpath1%\g_boot.ini %ggpath1%\boot.ini /y >nul
del %ggpath1%\g_boot.ini >nul

:sub_30
if not exist %ggpath1%\g_grldr del %ggpath1%\grldr&&goto sub_30a >nul
copy %ggpath1%\g_grldr %ggpath1%\grldr  >nul
del %ggpath1%\g_grldr >nul
if exist %ggpath1%\g_menu.lst attrib %ggpath1%\g_menu.lst -r -h -s >nul&&ren %ggpath1%\g_menu.lst menu.lst >nul
:sub_30a
attrib %ggpath1%\boot.ini +r +h +s >nul
rd /s /q %ggpath0%\ >nul

:exit
del %temp%\*.bat >nul 2>nul
cls
echo.
echo OK!
echo.
pause

作者: greenrock 时间: 2007-7-24 12:44
bat加密是这样实现的啊！！
为什么不影响执行呢

作者: skyxieyi 时间: 2007-7-24 13:36
BAT的加密还真没接触过

作者: mfkwgij 时间: 2007-7-25 12:28
:o 高手太多了，这里真是高手如云！

作者: bbysgx 时间: 2007-7-29 02:51
呵呵``让我看看`我就知道咋个搞了```

作者: 天涯行 时间: 2007-7-30 01:01
真是佩服这些高人们,.bat文件都能弄到这么复杂. 我只有收藏的份了.

作者: hszz8888 时间: 2007-7-30 23:33
天啊~~~从来不知道原来可以这样学习学习~~~~:loveliness:

作者: xwgod 时间: 2007-7-31 01:38
破解别人的也只是学习，更重要的是自己写

作者: magictek 时间: 2007-7-31 02:27
加密原理：NotePad会自动识别字符集，无文件头的则按照ANSI判读文件内容，如果采用UniCode保留字符作为文件头欺骗，NotePad会将后面的正文中每两个Byte组合起来当作一个UTF-16字符显示，或者将四个Byte组合起来当作一个UTF-32字符显示，导致显示乱码，但是CMD只支持ANSI，反而能够正确判读并正确执行本来就应该是ANSI的Batch。

制作方法：将文件头按两个或者四个空格加一个回车，然后使用UltraEdit或者WinHex将文件头的保留区按照下面的格式代码修改，同样可以正常执行，还可以乱的不一样，呵呵。

UniCode格式代码，大家自己欺骗自己玩玩：
EF BB BF UTF-8编码（单Byte解码）
FF FE UTF-16 LittleEndian编码（双Byte解码）
FE FF UTF-16 BigEndian编码（双Byte解码）
FF FE 00 00 UTF-32 LittleEndian编码（四Byte解码）
00 00 FE FF UTF-32 BigEndian编码（四Byte解码）

缺点：伪装头在CMD内按照ANSI执行的时候会报错，因此此类Batch一般在伪装头后面紧跟Cls清除报错信息。

以上是Bat伪装的全部工作原理，使用两种文本查看器可以正常查看：
1、支持多字符集，并可自由选择字符集的，上面有朋友介绍了，懒得去载下来看了；
2、仅仅支持ANSI单字符集的，例如DOS自带的Edit，或者WinRAR自带的文件查看器。

[ 本帖最后由 magictek 于 2007-7-31 03:46 AM 编辑 ]

抓图1.JPG (197.64 KB, 下载次数: 106)

作者: amio 时间: 2007-8-4 13:44
;P ;P ;P 学习拉

作者: zhuchl 时间: 2007-8-5 20:11
26解释得太好了，又学习了

作者: kaixinguo 时间: 2007-8-6 10:31

原帖由 jxf268 于 2007-7-8 03:18 PM 发表
用这个，文件类型选全部。

这个软件很多格式都打不开,更别说各式了

作者: zealic 时间: 2007-8-6 13:08
编码问题
用好点的文本编辑器就可以看了

作者: su123 时间: 2007-8-7 10:24
RAR里右键文件选查看

作者: jxyun99 时间: 2009-4-5 17:28
学习一下！！！！！！

作者: haiou327 时间: 2009-4-5 18:11
用winrar的查看功能.
用WINHEX去掉文件的头部即可.

作者: yidaren 时间: 2009-4-7 18:53
一个很简单的方法:先打开一个WORD 文档，再将批处理拖到WORD 文档中打开，我想这样可以看到远代码吧！！

可以去尝试一下！！

作者: yidaren 时间: 2009-4-7 18:54
这样要看它是如何进行加密的，如果是用代码加密码的话，我想用以上方法可以奏效！！

如果是用批处理加壳软件的话，那就这样不行了！！

作者: 折腾不停 时间: 2009-4-20 13:58
学习了，很不错
那么有没有办法直接用记事本编辑文件头呢？

作者: 23070205 时间: 2009-5-28 16:48
呵呵，不错啊，真是藏龙卧虎

作者: zxw 时间: 2009-6-2 09:25
善用winhex，一些所谓加密的东东都可破解

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)