无忧启动论坛

标题: 大伙帮忙看这个批处理问题出在哪里【FOR 和SET 联合应用】 [打印本页]

作者: hdzz 时间: 2011-2-22 10:54
标题: 大伙帮忙看这个批处理问题出在哪里【FOR 和SET 联合应用】

@echo off
setlocal enabledelayedexpansion
rem 下面一行是原文件名中要替换的字符串
set renname1=_DownG.com
rem 下面是新文件名的字符串，要删除1，则留空
set renname2=
for /r . %%a in (*_DownG.com*) do (
set hcy=%%a
e:\tools\winrar.exe d "%%a" 下载站*.htm -r
echo !hcy!
ren "%%~a" "!hcy:%renname1%=%renname2%!")
pause

复制代码

执行到 ren "%%~a" "!hcy:%renname1%=%renname2%!")
会语法错误~~~我那个找不出来。

下面这个是我现在正在用的，只能对当前目录进行操作。我想对子目录也操作，于是有了上面的代码。

@echo off
setlocal enabledelayedexpansion
rem 下面一行是原文件名中要替换的字符串
set renname1=_DownG.com
rem 下面是新文件名的字符串，要删除1，则留空
set renname2=
for /f "delims=" %%a in ('dir /b *_DownG.com*') do (
set hcy=%%a
e:\tools\winrar.exe d "%%a" 下载站*.htm -r
echo !hcy!
ren "%%~a" "!hcy:%renname1%=%renname2%!")
pause

复制代码

测试的时候要有形如"新建 WinRAR 压缩_DownG.com文件.rar"的文件，（文件名有空格，无空格都要能运行这个批处理）。
希望高手帮我看看第一段代码的问题出在哪里。我估计是setlocal enabledelayedexpansion的问题，可是我不知道怎么修改。

[ 本帖最后由 hdzz 于 2011-2-22 14:41 编辑 ]

作者: haiou327 时间: 2011-2-22 14:24

执行到 ren "%%~a" "!hcy:%renname1%=%renname2%!")
会语法错误~~~我那个找不出来。
只能对当前目录进行操作。我想对子目录也操作

setlocal ENABLEDELAYEDEXPANSION
for /f "delims=" %%a in ('dir /s /b *_DownG.com*') do (
   set Sour=%%a
   set Dst=%%~nxa
   "e:\tools\winrar.exe" d "%%a" "下载站*.htm" -r
   set Dst=!Dst:_DownG.com=!"
   ren "!Sour!" "!Dst!"
                     )
pause

作者: hdzz 时间: 2011-2-22 14:41
分离路径、文件名~~~这一步很重要。
之前我忘记了。以为这个 %%a 还是跟只在当前目录运行的那个一样。
不知道该怎么感谢你了。
set Dst=!Dst:_DownG.com=!"
ren "!Sour!" "!Dst!"
这样写看的也明白。
当时我也想这么写的，可是没写出来~~~~~再次感谢。

作者: haiou327 时间: 2011-2-22 14:47
不分离路径就用MOVE

setlocal ENABLEDELAYEDEXPANSION
for /f "delims=" %%a in ('dir /s /b *_DownG.com*') do (
   set Sour=%%a
   set renname=_DownG.com
   "e:\tools\winrar.exe" d "%%a" "下载站*.htm" -r
   set Dst=!Sour:%renname%=!"
   Move "!Sour!" "!Dst!"
                              )

作者: hdzz 时间: 2011-2-22 15:11
刚刚仔细试验了下。
比较好用。
现在可以说是完美的解决了这个问题了。
文件夹也可以操作（其中的winrar一行不会对文件夹操作）
有空格照样可以。

呵呵。高兴啊，多谢超版

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)