无忧启动论坛

标题: 求助把pe装在win7里的方法 [打印本页]

作者: fdsa0 时间: 2011-12-28 00:01
标题: 求助把pe装在win7里的方法
我搜索了一下论坛,我搜索不到,怎么把pe装在win7里,听说要改bcd. 不知道有没有自动化的工具吗,我只会把pe装在xp中,因为xp貌似只是改boot.ini

是不是把pe装在win7里面也要复制一个bcd文件去覆盖原有的bcd,然后再复制一些启动pe的东西吗?

[ 本帖最后由 fdsa0 于 2011-12-28 00:02 编辑 ]

作者: 6669913 时间: 2012-1-1 21:24
@echo off
:_done
echo 准备安装到D盘。要安装到其他盘请自行修改该文件！
echo 安装前请将\sources\BOOT.WIM,\BOOT\boot.sdi及根目录下所有文件拷贝到D盘根目录下！
pause
echo 正在安装梦幻 WIN7PE，请稍后...
echo.
echo.
echo.
REM
REM {ad6c7bc8-fa0f-11da-8ddf-0013200354d8}
REM
set RAMDISK_OPTIONS={ad6c7bc8-fa0f-11da-8ddf-0013200354d8}
REM
REM {572bcd56-ffa7-11d9-aae0-0007e994107d}, GUID for the WinPE boot entry
REM
set WINPE_GUID={572bcd56-ffa7-11d9-aae0-0007e994107d}
REM
REM Set Timeout
REM
bcdedit.exe -timeout 5
REM
REM Create Ramdisk device options for the boot.sdi file
REM
bcdedit.exe -create %RAMDISK_OPTIONS% -d "梦幻 WIN7PE (Ramdisk)" -device
bcdedit.exe -set %RAMDISK_OPTIONS% ramdisksdidevice partition=D:
bcdedit.exe -set %RAMDISK_OPTIONS% ramdisksdipath \boot.sdi
REM
REM Create WinRE boot entry
REM
bcdedit.exe -create %WINPE_GUID% -d "梦幻 WIN7PE" -application OSLOADER
bcdedit.exe -set %WINPE_GUID% device ramdisk=[D:]\BOOT.wim,%RAMDISK_OPTIONS%
bcdedit.exe -set %WINPE_GUID% path \windows\system32\boot\winload.exe
bcdedit.exe -set %WINPE_GUID% osdevice ramdisk=[D:]\BOOT.wim,%RAMDISK_OPTIONS%
bcdedit.exe -set %WINPE_GUID% systemroot \windows
bcdedit.exe -set %WINPE_GUID% detecthal yes
bcdedit.exe -set %WINPE_GUID% nx optin
bcdedit.exe -set %WINPE_GUID% winpe yes
bcdedit.exe -set %WINPE_GUID% locale "zh-CN"
bcdedit.exe -displayorder %WINPE_GUID% /addlast
echo Windows Preinstallation Environment安装完毕。
echo.
echo Thanks for you ！！
echo.
pause

脚本是由南狮王写的，呵呵，借用了，在此表示谢意！！！！

作者: 6669913 时间: 2012-1-1 21:25
bcdedit.EXE BCDBOOT.EXE 要在安装分区的根目录

作者: 6669913 时间: 2012-1-1 21:26
还有一种方法就是把BOOT.WIM改名为WINRE.WIM替换win7系统中的winre.WIM
开机时按f8就可以了

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)