无忧启动论坛

标题: 【高手请绕行】在 NT6.x 中安装 Windows 7 PE，用加载 WIM 的方式启动 [打印本页]

作者: bootp 时间: 2012-3-1 09:52
标题: 【高手请绕行】在 NT6.x 中安装 Windows 7 PE，用加载 WIM 的方式启动
PE是个好东西，高手们折腾不辍，菜鸟们用之不迭。但是，对于菜鸟而言，更多的是奉行拿来主义，毕竟熟练配置启动、灵活组装部件还是需要一些技术和耐心的。

很多PE制作者都附带了安装程序，菜鸟可以用安装程序方便地安装部署PE，但毕竟缺乏一点点灵活性。所以，在使用PE的过程中，菜鸟会遇到很多小的困扰，比如安装部署方面。这类问题，有时候高手懒得说，菜鸟弄不准，还真困扰了不少人。

泡无忧已经很久了，为大家解决一点点困扰，也算是对论坛的一点点回报吧。

——这就是我写这个帖子的初衷：让菜鸟也能够灵活地、随心所欲地按照自己的意图安装PE。

下面一段批处理本人已亲测通过，该解释的地方我都加了注释，原文拷贝后运行即可。

***************代码从下一行开始
@ECHO OFF
rem ============================================================
rem    在 NT6.x 中安装 Windows 7 PE，用加载 WIM 的方式启动PE
rem ============================================================
rem
rem 运行条件：NT6.x 已经正确配置并启动正常，即：至少要有正确的启动文件 BOOTMGR 和启动目录 <BOOT> 。
rem
rem 可以用BCDBOOT V:\WINDOWS /S C: /L ZH-CN 生成，也可以通过安装 Windows 7 或安装其他 PE3.0 生成。

title 安装 Windows 7 Preinstallation Environment

rem 如果系统盘不是C:，请修改。
set boot_disk=c:

rem 建立 Windows 7 PE 的安装目录
md %boot_disk%\WinPE\Sources

rem 拷贝 Windows 7 PE 的两个文件到安装目标文件夹，此处设定为%boot_disk%\WinPE\Sources。
rem Windows 7 PE 的 boot.wim 文件和一个 boot.sdi 文件位置不同，请手工拷贝。
ECHO 拷贝 Windows 7 PE 文件……
rem copy boot.wim %boot_disk%\WinPE\Sources\boot.wim /y
rem copy boot.sdi %boot_disk%\WinPE\Sources\boot.sdi /y

if not exist %boot_disk%\WinPE\Sources\boot.wim @echo 请先把 Windows 7 PE 的 boot.wim 文件拷贝到 %boot_disk%\WinPE\Sources 目录中。
if not exist %boot_disk%\WinPE\Sources\boot.sdi @echo 请先把 Windows 7 PE 的 boot.sdi 文件拷贝到 %boot_disk%\WinPE\Sources 目录中。

set bcddir=/store %boot_disk%\boot\bcd

rem 建立并配置 BCD 启动项
ECHO 建立并配置 Windows 7 PE 启动菜单……

rem 第一步：创建一个 RamDisk 设备，并取得其唯一标识名
for /f "delims={,} tokens=2" %%a in ('bcdedit %bcddir% -create -d "Windows Preinstallation Environment" -device  ') do set RamdiskID={%%a}
rem 设定 RamDisk 的启动路径
bcdedit %bcddir% -set %RamdiskID% ramdisksdidevice partition=%boot_disk%
bcdedit %bcddir% -set %RamdiskID% ramdisksdipath \WinPE\Sources\boot.sdi

rem 第二步：创建一个启动菜单项，并取得其唯一标识名
for /f "delims={,} tokens=2" %%a in ('bcdedit %bcddir% -create /d "Windows Preinstallation Environment" -application osloader  ') do set PE_GUID={%%a}
rem 配置创建的菜单项
bcdedit %bcddir% -set %PE_GUID% device ramdisk=[%boot_disk%]\WinPE\Sources\boot.wim,%RamdiskID%
bcdedit %bcddir% -set %PE_GUID% osdevice ramdisk=[%boot_disk%]\WinPE\Sources\boot.wim,%RamdiskID%
bcdedit %bcddir% -set %PE_GUID% path \windows\system32\boot\winload.exe
bcdedit %bcddir% -set %PE_GUID% locale zh-CN
bcdedit %bcddir% -set %PE_GUID% inherit {bootloadersettings}
bcdedit %bcddir% -set %PE_GUID% systemroot \windows
bcdedit %bcddir% -set %PE_GUID% detecthal yes
bcdedit %bcddir% -set %PE_GUID% winpe yes
bcdedit %bcddir% -set %PE_GUID% ems yes
bcdedit %bcddir% -displayorder %PE_GUID% -addlast

rem 第三步，设定全局菜单的启动参数，此处设定了等待时间，还可以设定启动次序等参数。
rem 菜单设置的更多用法，请参阅 bcdedit.exe 文件的帮助。
bcdedit -timeout 6

ECHO.
ECHO 已将 Windows 7 PE 成功安装到 %boot_disk%\WinPE\Sources 目录。
ECHO.
rem Windows 7 Preinstallation Environment 安装并配置完成！
ECHO.
PAUSE
***************代码到上一行结束

感谢你浏览到本帖的末尾。

其实，菜单配置好之后，想试验其他PE的效果，不需要再次配置，只手工拷贝替换一下boot.wim、boot.sdi两个文件就可以了。

本帖首发于无忧，转帖请注明出处，谢谢！

[ 本帖最后由 bootp 于 2012-3-1 10:50 编辑 ]

作者: 2010gdmzs 时间: 2012-3-1 09:59
“有时候高手懒得说，菜鸟弄不准”，确实“困扰了不少”菜鸟，这句话很实在；学习了；多谢。

作者: cheong0hk 时间: 2012-3-1 10:56
学习了多谢!!!!!

作者: 2011jjkkll 时间: 2012-3-1 15:22
"但是，对于菜鸟而言，更多的是奉行拿来主义"
这个同意,LZ知菜鸟...难得啊

作者: 2011jjkkll 时间: 2012-3-1 15:27
从幼儿园读到教授,万里长征...菜鸟谁走谁知道 ......三十万仅剩二万几...残不忍睹啊放菜鸟一条生路吧呵呵

作者: 2010sya 时间: 2012-3-1 16:47
标题: 回复 #1 bootp 的帖子
不错，硬盘装PE确实方便多了。
执行完配置文件，然后把PE中的boot.sdi和boot.wim两个文件复制到 C:\WinPE\Sources\ 就行了。
http://kuai.xunlei.com/d/BDQFNTPNNYRV

作者: bootp 时间: 2012-3-1 17:05

原帖由 2010sya 于 2012-3-1 16:47 发表
不错，硬盘装PE确实方便多了。
执行完配置文件，然后把PE中的boot.sdi和boot.wim两个文件复制到 C:\WinPE\Sources\ 就行了。
http://kuai.xunlei.com/d/BDQFNTPNNYRV

谢谢您！这样大家直接下载使用更方便了。

作者: bootp 时间: 2012-3-5 11:40

原帖由 2011jjkkll 于 2012-3-1 15:22 发表
"但是，对于菜鸟而言，更多的是奉行拿来主义"
这个同意,LZ知菜鸟...难得啊

握手！！

作者: 20120301 时间: 2012-3-5 11:59
把\WinPE\Sources\放到其它分区更好

作者: 2012cwz 时间: 2012-3-5 12:27
见笑了，boot.wim、boot.sdi是标准文件还是啥？

作者: bootp 时间: 2012-3-5 17:30

原帖由 20120301 于 2012-3-5 11:59 发表
把\WinPE\Sources\放到其它分区更好

这个位置是自由的，放到哪个分区都一样。但是启动WIM文件，都需要用到系统盘上的引导文件和BOOTP目录，所以我图省事，就放到了C盘上。

作者: bootp 时间: 2012-3-5 17:31

原帖由 2012cwz 于 2012-3-5 12:27 发表
见笑了，boot.wim、boot.sdi是标准文件还是啥？

也许会把外置程序放到其他地方，但是以WIM格式封装的WIN7pe，必定有这两个核心文件。

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)