Win7PE升级及NVME/USB3.0/3.1R的注入 - 无忧启动论坛

@Echo Off
REM 原创by chiannet，修改by TCLSHX、H3
COLOR 1F
Echo.
ECHO 本工具用来给W7PE增加驱动，各文件夹及文件意义如下：
ECHO 　　w7pe文件夹----w7pe.wim之挂载目标
ECHO 　　bot文件夹-----boot.wim之挂载目标
ECHO 　　wim文件夹-----boot.wim w7pe.wim等WIM文件存放处
ECHO 　　drv文件夹-----欲添加的驱动文件存放处
Echo.
ECHO 请按以上要求将WIM文件和驱动文件准备好（以上位于根或子文件夹均可）！
ECHO 本批处理必须要在安装了Windows AIK（KB3AIK_CN.ISO）的环境中运行！
Echo.
ECHO 如果已经作好上述准备工作，按任意键继续......
pause>nul
Echo.
ECHO 第1步：检查用于挂载的WIM文件......
Echo.
set nowim=0
If not Exist wim\W7PE.WIM set nowim=1 &&echo 没有Win7PE镜像文件w7pe.wim！
If not Exist wim\boot.wim set nowim=1 &&echo 没有Win7原版boot.wim镜像文件！
if not "%nowim%"=="0" pause&&goto end
Echo.
ECHO 第2步：挂载WIM镜像......
Echo.
If Exist w7pe RD w7pe /S /Q>NUL 2>NUL
If Exist bot RD bot /S /Q>NUL 2>NUL
md w7pe
md bot
Dism /Mount-Wim /WimFile:wim\W7PE.WIM /index:1 /MountDir:%CD%\w7pe
Dism /Mount-Wim /WimFile:wim\boot.wim /index:1 /MountDir:%CD%\bot
dir /a-d /b bot\windows\system32\*.dll >BOOTFN.OLD
ECHO .
ECHO 第3步：集成驱动文件......
ECHO .
REM 将w7pe中驱动有关文件移到bot中
rd bot\windows\inf /s /q
rd bot\windows\system32\drivers /s /q
rd bot\windows\system32\config /s /q
rd bot\windows\system32\DriverStore /s /q
move w7pe\windows\inf bot\windows\
move w7pe\windows\system32\drivers bot\windows\system32\
move w7pe\windows\system32\config bot\windows\system32\
move w7pe\windows\system32\DriverStore bot\windows\system32\
REM 集成驱动
Dism /image:bot /Add-Driver /driver:"DRV" /recurse /ForceUnsigned
REM 将已经集成好的位于bot中的原w7pe中驱动有关文件移回w7pe中
move "bot\windows\inf" "w7pe\windows"
move "bot\windows\system32\config" "w7pe\windows\system32"
move "bot\windows\system32\drivers" "w7pe\windows\system32"
move "bot\windows\system32\DriverStore" "w7pe\windows\system32"
del "w7pe\windows\system32\*.pnf" /s /q
del "w7pe\windows\system32\config\*.log?" /s /q /a:h
del "w7pe\windows\inf\*.log" /q
del "w7pe\windows\system32\config\*.blf" /s /q /a:h
del "w7pe\windows\system32\config\*.regtrans-ms" /s /q /a:h
del "w7pe\Windows\System32\DriverStore\*.1" /q
ECHO .
ECHO 第4步：更新DLL文件......
ECHO .
ECHO .
setlocal EnableDelayedExpansion
REM 比较文件列表
if exist ADDDLL.TXT del ADDDLL.TXT /q
dir /a-d /b bot\windows\system32\*.dll >BOOTFN.NEW
for /f "tokens=*" %%i in (BOOTFN.OLD) do (
set %%i=m
)
for /f "delims=" %%a in (BOOTFN.NEW) do (
if not defined %%a >>ADDDLL.TXT echo %%a
)
IF NOT EXIST ADDDLL.TXT GOTO UNMOUNT
REM 复制差异文件......
for /f "delims=" %%a in (ADDDLL.TXT) do (
copy /y "bot\windows\system32\%%a" "w7pe\windows\system32"
)
:UNMOUNT
ECHO .
ECHO 第5步：更新DLL已经完成，按任意键写入wim\w7pe.wim并卸挂boot......
pause>nul
for %%i in (ADDDLL.TXT BOOTFN.OLD BOOTFN.NEW) do del %%i /Q
Dism /unmount-Wim /MountDir:"%CD%\w7pe" /Commit
Dism /unmount-Wim /MountDir:"%CD%\bot" /discard
:END

复制代码