无忧启动论坛

标题: 提升批处理文件的权限，暨mshta中的脚本的分行处理 [打印本页]

作者: xhwfq 时间: 2017-7-2 14:47
标题: 提升批处理文件的权限，暨mshta中的脚本的分行处理
高手飘过

@echo off

>nul 2>&1 cacls "%WinDir%\system32\config\system"
if %errorlevel% EQU 0 goto gotAdmin
set vbs=Set UAC = CreateObject(""Shell.Application""):^
UAC.ShellExecute ""%~0"", """", """", ""runas"", 1
mshta VBScript:Execute("%vbs%:close")
goto:eof

:gotAdmin
::以下为你的批处理内容

作者: lintrainwy 时间: 2017-7-2 16:20
本帖最后由 comzhongwy 于 2017-11-17 11:16 编辑

:: 批处理获取管理员权限
:-------------------------------------
%1 mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&&exit /b
pushd "%CD%"
CD /D "%~dp0"
:--------------------------------------

:: 批处理获取管理员权限
:-------------------------------------
echo 检查管理员权限...
>nul 2>&1 dir "%WinDir%\system32\config\"
if %errorlevel% NEQ 0 (
echo 请求管理员权限...
goto UACPrompt ) else (
goto gotAdmin
)

:UACPrompt
set vbs=Set UAC ^= CreateObject(""Shell.Application""):^
         UAC.ShellExecute ""%~0"", """", """", ""runas"", 1:window.close
mshta VBScript:Execute("%vbs%")
exit /b

:gotAdmin
echo.
pushd "%CD%"
CD /D "%~dp0"
:--------------------------------------

作者: 金牛座188 时间: 2017-7-2 22:19
::自动提升运行权限
%Windir%\System32\FLTMC.exe >nul 2>&1 || (
ECHO CreateObject^("Shell.Application"^).ShellExecute "%~f0", "%PAR1st%", "", "runas", 1 > "%TEMP%\AdminRun.vbs"
ECHO CreateObject^("Scripting.filesystemobject"^).DeleteFile ^(WScript.ScriptFullName^) >> "%TEMP%\AdminRun.vbs"
%Windir%\System32\CSCRIPT.exe //Nologo "%TEMP%\AdminRun.vbs"
Exit /b
)
:-----------------------------------------------------------:
::以下为你的批处理内容

作者: nttwqz 时间: 2017-7-2 22:52
貌似PowerShell也可以用来提权，就是反应速度慢。

reg query HKU\S-1-5-20>nul 2>nul || powershell start-process """%0""" -Verb Runas && exit

作者: singel 时间: 2017-7-9 05:26
学习一下

作者: Anson4 时间: 2017-7-9 12:13

金牛座188 发表于 2017-7-2 22:19
::自动提升运行权限
%Windir%\System32\FLTMC.exe >nul 2>&1 || (
ECHO CreateObject^("Shell.Applic ...

这段代码看着眼熟啊，其中的%PAR1st%改为%1才对。

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)