处理缺省值的问题 - 无忧启动论坛

复制代码

@echo off
setlocal EnableDelayedExpansion
:menuloop
set /a number=1
set /a sum=0
cls
for /f "tokens=1-3 delims=:" %%i in (setting.txt) do (
set /a sum+=!number!
set "Options=%%k"
if not defined de!sum! set "de!sum!=%%j"
set "optemp=%%k"
set optemp="!optemp:/=" "!"
if defined Options (set "op!sum!=!optemp!") else set "op!sum!="%%j""
if defined Options (call echo !sum!. %%i %%de!sum!%% ^(可选：%%k^)) else call echo !sum!. %%i %%de!sum!%%
)
for /l %%a in (1,1,%sum%) do (
set /a number=1
set /a len%%a=0
call set "optemp=%%op%%a%%"
call set "detemp=%%de%%a%%"
for %%i in (!optemp!) do (
set /a len%%a+=!number!
if "!detemp!"==%%i set num%%a=!len%%a!
)
)
echo.
<nul set /p key=请按数字 1-%sum% 改变设置，0 继续
echo.
call :GetKey
if %key%==0 goto :next
if not defined len%key% goto :menuloop
call set "lentemp=%%len%key%%%"
call set "numtemp=%%num%key%%%"
call set "optemp=%%op%key%%%"
set/a mod=(%numtemp%+1)%%%lentemp%
if %mod%==0 set/a mod=%lentemp%
set /a number=1
set /a sum=0
for %%i in (%optemp%) do (
set /a sum+=!number!
if %mod%==!sum! set detemp=%%i
)
set de%key%=%detemp:"=%
goto :menuloop
:GetKey
set "key="
for /F "usebackq delims=" %%i in (`xcopy /w . 2^>NUL`) do (
if not defined key set "key=%%i"
)
set "key=%key:~-1%"
goto :eof
:next
echo.
echo 继续运行其他
echo.
echo 设定的值如下：
for /l %%a in (1,1,%sum%) do call echo %%de%%a%%
pause
goto :eof

复制代码

复制代码

复制代码

复制代码