如何备份手机系统镜像？ - 无忧启动论坛

@ECHO OFF
CLS
SETLOCAL EnableDelayedExpansion
MODE con: cols=80 lines=25
TITLE MTK ROM 提取工具 V1.0 (c)2011 mzecn
::缺省备份保存目录，可修改
SET folder=C:\MTK\Backups
SET IP=192.168.1.92
:Menu
CLS
ECHO.
ECHO MTK ROM提取工具
ECHO.
ECHO.
ECHO [ 1 ] 提取
ECHO [ 2 ] 退出
ECHO.
SET /P MenuOption=请选择（1-2）:
IF %MenuOption%==1 GOTO adbstuff
IF %MenuOption%==2 GOTO end
ECHO.
ECHO 选择错误
ECHO.
ECHO 请选择1-2
PAUSE
GOTO menu
:adbstuff
ECHO 启动ADB中，请稍候.
adb kill-server >NUL
adb start-server >NUL
adb connect %IP%
echo 响应天猫魔盒端提示：
echo 允许 USB 调试吗？
echo 确定
pause>nul
:phonepluggedin
adb devices|find "device"|find /v "List"
ECHO.
IF %ERRORLEVEL% NEQ 0 (
ECHO.
ECHO Tab 没有连接.
ECHO 请接好数据线~
ECHO 稍候...
adb wait-for-device
GOTO phonepluggedin
)
ECHO.
ECHO 你设置的目录为： %folder%
SET /P pathconfirm=确认使用该备份目录吗？ [Y/N]
IF /I %pathconfirm%==n (
ECHO.
SET /P folder=请输入你要使用的备份目录:
ECHO.
)
adb devices|find "device"|find /v "List" > _device
for /f "tokens=1" %%a in (_device) do (
set gtab=%%a
del _device
)
IF NOT EXIST %folder% MKDIR %folder%
IF %MenuOption%==1 GOTO backup
IF %MenuOption%==2 GOTO restore
::------------------------------------------------------Backup
:Backup
::Removes quotes from the folder variable if present
IF %folder:~0,1%%folder:~-1%=="" (
SET folder=%folder:~0,-1%
SET folder=%folder:~1%
)
::Removes the trailing \ if present
IF %folder:~-1%==\ (
SET folder=%folder:~0,-1%
)
::Prevents the root of the drive being used, as that breaks the restore part
IF %folder:~-1%==: (
ECHO.
ECHO 不支持备份到分区的根目录. 请重新开始，正确设置备份目录.
ECHO.
PAUSE
GOTO end
)
::Check if the folder is present
IF NOT EXIST "%folder%" (
ECHO.
ECHO 备份目录不正确
ECHO 你需要手动创建该目录.
ECHO.
PAUSE
GOTO end
)
SET Goodtime=%time%
IF "%Goodtime:~0,1%"==" " (
SET Goodtime=0%Goodtime:~1,10%
)
SET fbackup=%date:~0,4%-%date:~5,2%-%date:~8,2%-%Goodtime:~0,2%-%Goodtime:~3,2%
mkdir "%folder%\%fbackup%"
adb get-serialno > "%folder%\%fbackup%\serno"
:ECHO. > "%folder%\%fbackup%\%fbackup%.date"
pushd "%folder%\%fbackup%"
pause
cls
ECHO 正在备份你的MTK鸡鸡 %gtab%...
ECHO.
ECHO 备份你鸡鸡的boot.img中.......
%~dp0adb shell su -c "dd if=/dev/mtd/mtd4 of=/sdcard/boot.img bs=4096"
%~dp0adb pull /sdcard/boot.img .
%~dp0adb shell rm /sdcard/boot.img
ECHO 备份你鸡鸡的SYSTEM中......
%~dp0adb -s %gtab% pull /system system
ECHO.
ECHO 备份完成！
ECHO.
PAUSE
GOTO menu
:end
ECHO.
ECHO 谢谢使用。
ECHO.

复制代码