搜狗拼音输入法 for XP/7 安装程序源码 - 无忧启动论坛

;InnoSetupVersion=5.6.1 (Unicode)
[Setup]
;--必需--
AppName=搜狗输入法
AppVerName=搜狗输入法 v10.5 正式版
DefaultDirName={pf}\SogouInput
;--程序组--
DefaultGroupName=搜狗输入法
;--构架--
ArchitecturesAllowed=x86 x64
ArchitecturesInstallIn64BitMode=x64
;--权限--
PrivilegesRequired=admin
UsedUserAreasWarning=no
;--版本需求--
MinVersion=0,5.1
OnlyBelowVersion=0,6.2
;--向导页--
DisableDirPage=no
DisableFinishedPage=yes
DisableProgramGroupPage=yes
DisableReadyMemo=yes
DisableReadyPage=yes
DisableStartupPrompt=yes
DisableWelcomePage=yes
;--刷新关联--
ChangesAssociations=yes
;--压缩--
Compression=lzma/max
SolidCompression=yes
;--输出--
SetupIconFile=SetupIcon.ico
OutputBaseFilename=sogou_pinyin_105b
;--卸载程序--
Uninstallable=yes
;--文件时间戳--
TouchDate=2021-06-28
TouchTime=00:00
;--文件属性--
AppCopyright=© 2021 Sogou.com Inc. All rights reserved.
AppPublisher=Sogou.com Inc.
VersionInfoVersion=10.5.0.4737
;--界面图片--
WizardImageFile=$PLUGINSDIR\modern-wizard.bmp
WizardSmallImageFile=$PLUGINSDIR\modern-header.bmp
[Files]
;核心文件
Source: "$PLUGINSDIR\SogouPY.ime"; DestDir: "{sys}"; Check: "Not IsWin64"; Components: SogouPY; Flags: touch
Source: "$PLUGINSDIR\SogouPY.ime"; DestDir: "{syswow64}"; Check: "IsWin64"; Components: SogouPY; Flags: touch
Source: "$PLUGINSDIR\SogouPY64.ime"; DestDir: "{sys}"; DestName: "SogouPY.ime"; Check: "IsWin64"; Components: SogouPY; Flags: touch
Source: "10.5.0.4737\Install64.exe"; DestDir: "{app}\10.5.0.4737"; Check: "IsWin64"; Components: Install; Flags: touch
Source: "10.5.0.4737\Punctures.ini"; DestDir: "{app}\10.5.0.4737"; Components: Punctures; Flags: touch
Source: "10.5.0.4737\Resource.dll"; DestDir: "{app}\10.5.0.4737"; Components: Resource; Flags: touch
Source: "10.5.0.4737\sgim_hz.bin"; DestDir: "{app}\10.5.0.4737"; Components: sgim_HZ; Flags: touch
Source: "10.5.0.4737\sgim_py.bin"; DestDir: "{app}\10.5.0.4737"; Components: sgim_PY; Flags: touch
Source: "10.5.0.4737\Skin.dat"; DestDir: "{app}\10.5.0.4737"; Components: Skin; Flags: touch
Source: "10.5.0.4737\SGTool.exe"; DestDir: "{app}\10.5.0.4737"; Components: SGTool; Flags: touch
Source: "10.5.0.4737\sysmodel.bin"; DestDir: "{app}\10.5.0.4737"; Components: SysModel; Flags: deleteafterinstall touch
;简繁切换
Source: "10.5.0.4737\sgim_simtra.bin"; DestDir: "{app}\10.5.0.4737"; Components: SimTra; Flags: touch
;输入方式
Source: "10.5.0.4737\PersonalCenter.cupf"; DestDir: "{app}\10.5.0.4737"; Components: PersonalCenter; Flags: touch
;软键盘
Source: "10.5.0.4737\SoftKeyBoard.cupf"; DestDir: "{app}\10.5.0.4737"; Components: SoftKeyBoard; Flags: touch
;搜狗工具箱
Source: "10.5.0.4737\pandorabox.cupf"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
;工具在线安装
Source: "$_14_\SogouComMgr.exe"; DestDir: "{app}\Components"; Components: ToolBox; Flags: touch
Source: "$_14_\ComponentConfig.ini"; DestDir: "{app}\Components"; Components: ToolBox;Flags: touch
Source: "10.5.0.4737\HWSignature.dll"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\SGDownload.exe"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\sgutil.dll"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\ZipLib.dll"; DestDir: "{app}\10.5.0.4737"; Check: "Not IsWin64"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\ZipLib64.dll"; DestDir: "{app}\10.5.0.4737"; DestName: "ZipLib.dll"; Check: "IsWin64"; Components: ToolBox; Flags: touch
;工具配置
Source: "$_14_\AppBox\list.ini"; DestDir: "{app}\Components\AppBox"; Components: ToolBox; Flags: touch
Source: "$_14_\AppBox\recommend.ini"; DestDir: "{app}\Components\AppBox"; Components: ToolBox; Flags: touch
;图片表情图标
Source: "$_14_\AppBox\icon\exinputBundle.picfaceCom.ico"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
Source: "$_14_\AppBox\icon\exinputBundle.picfaceCom.png"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
;手写输入图标
Source: "$_14_\AppBox\icon\handinputBundle.ico"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
Source: "$_14_\AppBox\icon\handinputBundle.png"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
;语音输入图标
Source: "$_14_\AppBox\icon\VoiceInputBundle.ico"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
Source: "$_14_\AppBox\icon\VoiceInputBundle.png"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
;符号大全
Source: "10.5.0.4737\sgim_quick.bin"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\richinput.cupf"; DestDir: "{app}\10.5.0.4737"; Components: ToolBox; Flags: touch
Source: "10.5.0.4737\RichInput\richinputconfig.ini"; DestDir: "{app}\10.5.0.4737\RichInput"; Components: ToolBox; Flags: touch
;符号大全图标
Source: "$_14_\AppBox\icon\exinputBundle.symbolCom.ico"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
Source: "$_14_\AppBox\icon\exinputBundle.symbolCom.png"; DestDir: "{app}\Components\AppBox\icon"; Components: ToolBox; Flags: touch
[INI]
;候选项数: 9
Filename: "{userappdata}\SogouPY\env.ini"; Section: "Setting"; Key: "PageSize"; String: "9"
Filename: "{userappdata}\SogouPY\env.ini"; Section: "SyncMode"; Key: "PageSize"; String: "remote"
;关闭细胞词库
Filename: "{userappdata}\SogouPY\env.ini"; Section: "Setting"; Key: "UseCellDict"; String: "0"
;升级模式: 禁止升级
Filename: "{userappdata}\SogouPY\env.ini"; Section: "Setting"; Key: "AutoUpdate"; String: "0"
Filename: "{userappdata}\SogouPY\env.ini"; Section: "SyncMode"; Key: "AutoUpdate"; String: "remote"
;关闭i模式换肤
Filename: "{userappdata}\SogouPY\env.ini"; Section: "Setting"; Key: "IModeQuickChangeSkin"; String: "0"
Filename: "{userappdata}\SogouPY\env.ini"; Section: "SyncMode"; Key: "IModeQuickChangeSkin"; String: "remote"
[Registry]
Root: HKLM; Subkey: "SOFTWARE\SogouComponents"; Components: ToolBox;
Root: HKLM; Subkey: "SOFTWARE\SogouComponents"; ValueName: ""; ValueType: String; ValueData: "{app}\Components"; Components: ToolBox;
Root: HKLM; Subkey: "SOFTWARE\SogouInput";
Root: HKLM; Subkey: "SOFTWARE\SogouInput"; ValueName: ""; ValueType: String; ValueData: "{app}";
Root: HKLM; Subkey: "SOFTWARE\SogouInput"; ValueName: "Region"; ValueType: String; ValueData: "0000_sogou_pinyin_105b";
Root: HKLM; Subkey: "SOFTWARE\SogouInput"; ValueName: "StartMenuFolder"; ValueType: String; ValueData: "搜狗输入法";
Root: HKLM; Subkey: "SOFTWARE\SogouInput"; ValueName: "Version"; ValueType: String; ValueData: "10.5.0.4737";
Root: HKLM; Subkey: "SOFTWARE\SogouInput"; ValueName: "VersionType"; ValueType: String; ValueData: "Final";
[Run]
Filename: "{app}\10.5.0.4737\SGTool.exe"; Parameters: "--appid=sysdicmk --src=""{app}\10.5.0.4737\sysmodel.bin"" --des=""{app}\10.5.0.4737\sgim_core.bin"""; WorkingDir: "{app}\10.5.0.4737"; Description: "转换核心词库"; StatusMsg: "正在转换核心词库...";
Filename: "{app}\10.5.0.4737\SGTool.exe"; Parameters: "--appid=install -i -w"; WorkingDir: "{app}"; Description: "安装输入法"; StatusMsg: "正在安装输入法...";
Filename: "{app}\10.5.0.4737\Install64.exe"; Parameters: "-i -w"; WorkingDir: "{app}"; Description: "安装输入法"; StatusMsg: "正在安装输入法..."; Check: "IsWin64"; Flags: runhidden
Filename: "{sys}\taskkill.exe"; Parameters: "/f /im SGTool.exe"; WorkingDir: "{app}"; Description: "结束进程"; StatusMsg: "正在结束进程..."; Flags: runhidden
[UninstallRun]
Filename: "{app}\10.5.0.4737\SGTool.exe"; Parameters: "--appid=install -u -w"; WorkingDir: "{app}"; StatusMsg: "正在卸载输入法...";
Filename: "{app}\10.5.0.4737\Install64.exe"; Parameters: "-u -w"; WorkingDir: "{app}"; StatusMsg: "正在卸载输入法..."; Flags: runhidden
Filename: "{sys}\taskkill.exe"; Parameters: "/f /im SGTool.exe"; WorkingDir: "{app}"; StatusMsg: "正在结束进程..."; Flags: runhidden
[Icons]
;Name: "{group}\{cm:UninstallProgram,搜狗输入法}"; Filename: "{uninstallexe}";
[Types]
Name: "Lite"; Description: "精简版";
Name: "Core"; Description: "核心版";
Name: "Custom"; Description: "定制版"; Flags: iscustom
[Components]
Name: "SogouPY"; Description: "搜狗拼音"; Types: "Core Lite Custom"; Flags: fixed
Name: "Install"; Description: "安装程序"; Types: "Core Lite Custom"; Flags: fixed
Name: "Punctures"; Description: "自定义标点"; Types: "Core Lite Custom"; Flags: fixed
Name: "Resource"; Description: "资源"; Types: "Core Lite Custom"; Flags: fixed
Name: "sgim_HZ"; Description: "汉字编码"; Types: "Core Lite Custom"; Flags: fixed
Name: "sgim_PY"; Description: "拼音编码"; Types: "Core Lite Custom"; Flags: fixed
Name: "Skin"; Description: "皮肤"; Types: "Core Lite Custom"; Flags: fixed
Name: "SGTool"; Description: "搜狗工具"; Types: "Core Lite Custom"; Flags: fixed
Name: "SysModel"; Description: "系统词库"; Types: "Core Lite Custom"; Flags: fixed
Name: "SimTra"; Description: "简繁转换"; Types: "Core Lite Custom"; Flags: fixed
Name: "PersonalCenter"; Description: "输入方式"; Types: "Lite Custom";
Name: "SoftKeyBoard"; Description: "软键盘"; Types: "Lite Custom";
Name: "ToolBox"; Description: "工具箱"; Types: "Lite Custom";
[UninstallDelete]
Type: filesandordirs; Name: "{app}"
Type: filesandordirs; Name: "{userappdata}\SogouPY"
Type: filesandordirs; Name: "{userappdata}\SogouPY.users"
[Messages]
BeveledLabel=——— ChiShingChan
[Code]
procedure InitializeWizard();
begin
WizardForm.LICENSEACCEPTEDRADIO.Checked := true;
WizardForm.WizardSmallBitmapImage.width:=170;
WizardForm.WizardSmallBitmapImage.left:=0;
WizardForm.PAGENAMELABEL.left:=170+20;
WizardForm.PAGENAMELABEL.width:=WizardForm.width-170-26;
WizardForm.PAGEDESCRIPTIONLABEL.left:=170+20;
WizardForm.PAGEDESCRIPTIONLABEL.width:=WizardForm.width-170-26;
end;

复制代码