官方有提供彻底卸载接口，为什么不用？作者: 这是饭店 时间: 2022-4-12 23:35
' 卸载LTSC 2021内置Edge
Option Explicit
Dim fs : Set fs = CreateObject("Scripting.FileSystemObject")
Dim sh : Set sh = CreateObject("WScript.Shell")
On Error Resume Next
sh.RegRead("HKEY_USERS\S-1-5-19\Environment\TEMP")
If Err.number <> 0 Then
CreateObject("Shell.Application").ShellExecute "wscript", """" & WScript.ScriptFullName & """", ,"runas", 1
WScript.Quit
End If
On Error Goto 0
Dim i, UserSID
For Each i In GetObject("winmgmts:\\.\").ExecQuery("SELECT * FROM Win32_UserAccount WHERE Name LIKE '" & CreateObject("WScript.Network").UserName & "'")
UserSID = i.SID
Next
Const AppxEOL = "HKLM:\SOFTWARE\Microsoft\Windows\CurrentVersion\Appx\AppxAllUserStore\EndOfLife"
PSRun "foreach ($i in (Get-AppxProvisionedPackage -Online|? {$_.PackageName -Like '*MicrosoftEdge*'}).PackageName) {" &_
"New-Item """ & AppxEOL & "\" & UserSID & "\$i"" -Force;" &_
"New-Item """ & AppxEOL & "\S-1-5-18\$i"" -Force;" &_
"Remove-AppxProvisionedPackage -Online -PackageName $i}"
PSRun "foreach ($i in (Get-AppxPackage -allusers *MicrosoftEdge*).PackageFullName) {" &_
"New-Item """ & AppxEOL & "\" & UserSID & "\$i"" -Force;" &_
"New-Item """ & AppxEOL & "\S-1-5-18\$i"" -Force;" &_
"Remove-AppxPackage -AllUsers -Package $i}"
CMDRun "forfiles /S /P ""%ProgramFiles(x86)%\Microsoft\Edge"" /M setup.exe /C ""cmd /C " &_
"@path --uninstall --system-level --verbose-logging --force-uninstall --delete-profile"""
While fs.FolderExists(sh.ExpandEnvironmentStrings("%ProgramFiles(x86)%") & "\Microsoft\EdgeUpdate")
WScript.Sleep 5000
Wend
CMDRun "cmd /C RD /S /Q ""%ProgramFiles(x86)%\Microsoft\Edge"""
CMDRun "cmd /C DEL /F /Q /S ""%SystemDrive%\Microsoft Edge*.lnk"""
MsgBox "删除成功"
Sub CMDRun(sCommand)
sh.Run sCommand, 0, True
End Sub
