PE下自动安装操作系统批处理0516更新 - 无忧启动论坛

@echo off
color 0a
mode con: cols=65 lines=40
title Windows系统全自动化安装器 By:as8686886
REM 判断ISO内是否有install.wim
IF NOT EXIST Y:\sources\install.wim (goto NoInsWIM)
REM 判断当前运行环境：WinPE执行、非PE拒绝执行
@reg query HKLM\SYSTEM\CurrentControlSet\Control |find "WinPE">NUL&&goto WinPE||goto NoWinPE
:WinPE
REM 判断启动模式BIOS或者UEFI
@reg query HKLM\System\CurrentControlSet\Control /v PEFirmwareType |find "0x1" >NUL&& set OSmode=BIOS || set OSmode=UEFI
if "%OSMode%"=="BIOS" goto BIOS
if "%OSMode%"=="UEFI" goto UEFI
REM goto NoWinPe
:BIOS
set BootDrv=C:
setlocal enabledelayedexpansion
(
echo select disk 0
echo clean
echo convert mbr
echo create partition primary
echo active
echo format fs=ntfs label="OS" quick
echo assign letter C
)>%~dp0DISKPART.TXT
goto FDISK
:UEFI
set BootDrv=Z:
setlocal enabledelayedexpansion
(
echo select disk 0
echo clean
echo convert GPT
echo create partition efi size=500
echo format fs=fat32 label="ESP" quick
echo assign letter z
echo create partition primary
echo format fs=ntfs label="OS" quick
echo assign letter C
)>%~dp0DISKPART.TXT
goto FDISK
:FDISK
echo.&echo 正在对磁盘进行分区……
diskpart /s DISKPART.TXT>NUL
cls
goto InstallOS
:InstallOS
set ISOPath=Y:\sources
echo 本ISO包含以下系统镜像:
dism /Get-WimInfo /WimFile:%ISOPath%\install.wim
set /P NUM=请输入要安装的系统索引号：
cls
dism /Apply-Image /ImageFile:%ISOPath%\install.wim /Index:%NUM% /ApplyDir:C:\
bcdboot C:\Windows /l zh-cn /s %BootDrv% /f %OSMode%
goto end
:NoWinPe
echo.&echo 当前系统环境为非WinPE环境，程序不允许执行,程序退出！
echo.&pause
exit
:NoInsWIM
echo.&echo 当前挂载的ISO不是标准的Windows系统的ISO或未挂载系统ISO，安装无法进行,程序退出！
echo.&pause
exit
:end
echo.&echo 系统安装完毕！
echo.&pause
exit

复制代码

@echo off
color 0a
mode con: cols=65 lines=50
title Windows系统全自动化安装器 By:as8686886
REM 判断DISM运行环境
@dism /Get-WimInfo |find "get-wiminfo">NUL&&goto CopyFile||goto WIM
:CopyFile
xcopy %~dp0fx\wimprovider.dll %SystemRoot%\System32\Dism\ /y>NUL
xcopy %~dp0fx\wimprovider.dll.mui %SystemRoot%\System32\Dism\zh-CN\ /y>NUL
:WIM
REM 判断ISO内是否有install.wim
IF NOT EXIST Y:\sources\install.wim (goto NoInsWIM)
REM 判断当前运行环境：WinPE执行、非PE拒绝执行
@reg query HKLM\SYSTEM\CurrentControlSet\Control |find "WinPE">NUL&&goto WinPE||goto NoWinPE
:WinPE
REM 判断启动模式BIOS或者UEFI
@reg query HKLM\System\CurrentControlSet\Control /v PEFirmwareType |find "0x1" >NUL&& set OSmode=BIOS || set OSmode=UEFI
if "%OSMode%"=="BIOS" goto BIOS
if "%OSMode%"=="UEFI" goto UEFI
REM goto NoWinPe
:BIOS
set BootDrv=C:
setlocal enabledelayedexpansion
(
echo select disk 0
echo clean
echo convert mbr
echo create partition primary
echo active
echo format fs=ntfs label="OS" quick
echo assign letter C
)>%temp%\DISKPART.TXT
goto InstallOS
:UEFI
set BootDrv=Z:
setlocal enabledelayedexpansion
(
echo select disk 0
echo clean
echo convert GPT
echo create partition efi size=500
echo format fs=fat32 label="ESP" quick
echo assign letter z
echo create partition primary
echo format fs=ntfs label="OS" quick
echo assign letter C
)>%temp%\DISKPART.TXT
goto InstallOS
:InstallOS
set ISOPath=Y:\sources
echo 挂载的ISO包含以下系统镜像:
dism /Get-WimInfo /WimFile:%ISOPath%\install.wim
echo.
set /P NUM=请输入要安装的系统索引号：
goto FDISK
:FDISK
cls
echo.&echo 警告：此操作会丢失全盘数据，确认要继续操作？
echo.&echo 即将运行磁盘分区，如不需要运行关闭该窗口即可,10秒后开始执行...
timeout /t 10 /nobreak
echo.&echo 正在对磁盘进行分区……
diskpart /s %temp%\DISKPART.TXT>NUL
choice /t 2 /d y /n >nul
del /q/s %temp%\DISKPART.TXT>NUL
echo.&echo 磁盘分区完成。
choice /t 2 /d y /n >nul
cls
goto startos
:startos
REM 判断卷标OS分区的盘符，防止有的情况下磁盘盘符为非C盘
for /f "tokens=2 delims==" %%a in ('wmic logicaldisk where "VolumeName='OS'" get Name /Value') do set SysDrv=%%a
dism /Apply-Image /ImageFile:%ISOPath%\install.wim /Index:%NUM% /ApplyDir:%SysDrv%\
bcdboot %SysDrv%\Windows /l zh-cn /s %BootDrv% /f %OSMode%
echo 是否需要unattend无人值守安装(是1 否0)？
set /p oobe=请输入[0,1]：
if "%oobe%"=="1" goto unattend
if "%oobe%"=="0" goto end
:unattend
xcopy %~dp0fx\oobe.cmd %SysDrv%\Windows\Setup\Scripts\ /y >nul
goto end
:NoWinPe
echo.&echo 当前系统环境为非WinPE环境，程序不允许执行,程序退出！
echo.&pause
exit
:NoInsWIM
echo.&echo 当前挂载的ISO不是标准的Windows系统的ISO或未挂载系统ISO，安装无法进行,程序退出！
echo.&pause
exit
:end
echo.&echo 系统安装完毕！
echo.&pause
exit

复制代码