右键创建、加载、卸载VHD完美方法 - 无忧启动论坛

@echo off
:: 右键菜单支持
if defined vhdpath goto vhdFilesok
:: 拖拽操作支持
set vhdpath=%~1
if defined vhdpath goto vhdFilesok
:: 常规批处理窗口输入
set /p vhdpath=请输入VHD文件完整路径后按回车键，PS:提示可以将VHD文件拖拽进来：
:: 检测路径错误
for /f "delims=" %%i in ('echo %vhdpath%') do if not exist "%%~i" msg %username% /time:3 输入错误文件不存在！ && exit
:: 去掉路径的引号，记录文件夹名，并判断文件后缀名。
: vhdFilesok
for /f "delims=" %%i in ('echo %vhdpath%') do set vhdname=%%~ni && set vhdpath=%%~i && if /i not "%%~xi"==".vhd" if /i not "%%~xi"==".vhdx" msg %username% /time:3 错误，不是VHD文件！ && exit
:: 判断固件类型
bcdedit /enum bootmgr |find /i "efi" && set exef=efi || set exef=exe
:: 添加休眠条目恢复项
for /f "tokens=2" %%i in ('bcdedit /create /d "%vhdname%_VHD" /application resume') do set id1=%%i
bcdedit /set %id1% device vhd=[%vhdpath:~0,2%]%vhdpath:~2%
bcdedit /set %id1% path \windows\system32\winresume.%exef%
bcdedit /set %id1% locale zh-cn
bcdedit /set %id1% inherit {resumeloadersettings}
bcdedit /set %id1% isolatedcontext Yes
bcdedit /set %id1% allowedinmemorysettings 0x15000075
bcdedit /set %id1% filepath \hiberfil.sys
bcdedit /set %id1% bootmenupolicy Standard
:: 添加操作系统条目
for /f "tokens=2" %%i in ('bcdedit /create /d "%vhdname%_VHD" /application osloader') do set id2=%%i
bcdedit /set %id2% device vhd=[%vhdpath:~0,2%]%vhdpath:~2%
bcdedit /set %id2% osdevice vhd=[%vhdpath:~0,2%]%vhdpath:~2%
bcdedit /set %id2% path \Windows\System32\winload.%exef%
bcdedit /set %id2% systemroot \Windows
bcdedit /set %id2% Locale zh-cn
bcdedit /set %id2% inherit {bootloadersettings}
bcdedit /set %id2% isolatedcontext Yes
bcdedit /set %id2% allowedinmemorysettings 0x15000075
bcdedit /set %id2% nx OptIn
bcdedit /set %id2% bootmenupolicy Standard
bcdedit /set %id2% resumeobject %id1%
:: 将引导菜单放置最后
bcdedit /displayorder %id2% -addlast
msg %username% /time:3 添加%vhdname%_VHD引导菜单完成

复制代码

@echo off
title VHD还原
cd /d %~dp0
:: 检查脚本安装环境
set auto=baby1277
if not exist bcd\bcdab0z goto error
if not exist Windown11_back.vhdx goto error
reg query "HKEY_CLASSES_ROOT\DesktopBackground\shell\vhdstart" >nul 2>nul
if errorlevel 1 call 添加桌面右键菜单.bat
:: 查询 "Windown11_back.vhdx" VHD副本文件大小
for %%i in (Windown11_back.vhdx) do set back=%%~zi
:: 查询 "Windown11 正常模式" 的VHD文件大小
for %%i in (Windown11_10.vhdx) do set z0=%%~zi
for %%i in (Windown11_1a.vhdx) do set za=%%~zi
:: 查询 "Windown11 还原模式" 的VHD文件大小
for %%i in (Windown11_11.vhdx) do set z1=%%~zi
for %%i in (Windown11_1b.vhdx) do set zb=%%~zi
:: 重置符合条件的 "Windown11 正常模式" 的VHD文件
if %z0% gtr %za% if %za% gtr %back% copy /y Windown11_back.vhdx Windown11_1a.vhdx&&set v4=z
if %za% gtr %z0% if %z0% gtr %back% copy /y Windown11_back.vhdx Windown11_10.vhdx&&set v4=z
:: 重置符合条件的 "Windown11 还原模式" 的VHD文件
if %zb% gtr %back% copy /y Windown11_back.vhdx Windown11_1b.vhdx
if %z1% gtr %back% copy /y Windown11_back.vhdx Windown11_11.vhdx
:: 重新查询 "Windown11 正常模式" 的VHD文件大小
for %%i in (Windown11_10.vhdx) do set d0=%%~zi
for %%i in (Windown11_1a.vhdx) do set da=%%~zi
:: 重新查询 "Windown11 还原模式" 的VHD文件大小
for %%i in (Windown11_11.vhdx) do set d1=%%~zi
for %%i in (Windown11_1b.vhdx) do set db=%%~zi
:: 根据文件大小来设置默认引导菜单
if %d0% geq %da% set v1=0&set v3=a
if %da% geq %d0% set v1=a&set v3=0
if %d1% leq %db% set v2=1
if %db% leq %d1% set v2=b
if %d1% neq %db% set v4=h
if defined v4 bcdedit /import bcd\bcd%v1%%v2%%v3%%v4%
:: 更新桌面右键菜单
set reg=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CommandStore\shell
if %d1% neq %db% goto menu
reg add "%reg%\start.1" /v "" /t REG_SZ /d "Windown11 正常模式 √" /f
reg add "%reg%\start.2" /v "" /t REG_SZ /d "Windown11 还原模式" /f
reg add "%reg%\start.3" /v "" /t REG_SZ /d "Windown11 出厂模式" /f
exit
:menu
if %d1% equ %db% exit
reg add "%reg%\start.1" /v "" /t REG_SZ /d "Windown11 正常模式" /f
reg add "%reg%\start.2" /v "" /t REG_SZ /d "Windown11 还原模式 √" /f
reg add "%reg%\start.3" /v "" /t REG_SZ /d "Windown11 出厂模式" /f
exit
:error
msg %username% /time:5 VHD还原脚本安装错误，请查看安装说明。

复制代码