驱动总裁全自动安装驱动脚本（系统封装部署专用）

baby1277 · 发表于 2025-12-20 11:16:00

本帖最后由 baby1277 于 2025-12-24 10:23 编辑

@echo off
cd /d %~dp0
title baby1277 @2025.12.24
:: 检测网络连接，没有联网则退出。
ping baidu.com >nul 2>nul
if errorlevel 1 goto DrvCeo4
:: 设置下载地址，如地址有变自行更改。
set CeoDL=https://cdn-download.soft.360.cn/softmanager-installation/20250912/1900060398_fec19421f7dbb267cc1770cb9109b8f4.exe
for /f "delims=" %%i in ('echo %CeoDL%') do set CeoN=%%~nxi
:DrvCeo1
timeout /t 2 >nul
start /min /wait cmd /c curl -O %CeoDL%
timeout /t 2 >nul
:: 检测下载的安装包有误则重新下载。
if exist %CeoN% for %%i in (%CeoN%) do if %%~zi lss 888888 del /f /q %CeoN% & goto DrvCeo1
if not exist %CeoN% echo.&echo 下载地址错误，请重新设置下载地址。&timeout /t 10 >nul&goto DrvCeo4
:: 安装驱动总裁自动安装驱动
start /wait "" "%cd%\%CeoN%" /S
if exist "C:\Windows\SysWOW64" (set "CeoPath=C:\Program Files (x86)\SysCeo") else set "CeoPath=C:\Program Files\SysCeo"
:: 等待安装所有驱动完成
:DrvCeo2
timeout /t 5 >nul
if not exist "%CeoPath%" goto DrvCeo2
cd /d %CeoPath%&cd ..
:DrvCeo3
timeout /t 5 >nul
ren SysCeo SysCeo2 >nul 2>nul
if exist "%CeoPath%" goto DrvCeo3
timeout /t 2 >nul
:: 删除注册表相关
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\SysCeo\DrvCeo" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\SysCeo\DrvCeo" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\DrvCeo2.0" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\DrvCeo2.0" /f
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\DrvCeo2.0" /f
:: 删除文件相关
rd /s /q "C:\DrvPath"
rd /s /q "%CeoPath%2"
rd /s /q "C:\Windows\Temp\Sysceo"
rd /s /q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\驱动总裁2.0"
del /f /q "C:\Users\Public\Desktop\驱动总裁.lnk"
del /f /q "%~dp0%CeoN%"
:DrvCeo4
timeout /t 10 >nul

复制代码

此脚本可以实现全自动安装驱动（需要联网），驱动总裁对封装部署有优化加持，非常好用的软件。

保存为 “安装驱动.cmd” ANSI格式

使用方法1：使用unattend.xml 或者离线挂载注册表添加RunOnce开机启动部署脚本

使用方法2：在现有的开机启动部署脚本中间插入脚本

使用方法3：桌面环境直接运行

驱动总裁安装驱动.zip (1.11 KB, 下载次数: 115)

baby1277 · 发表于 2025-12-20 11:16:01

本帖最后由 baby1277 于 2025-12-20 13:39 编辑

如果下载地址失效请自行到官方网站获取

驱动总裁官方下载地址：https://www.sysceo.com/software-softwarei-id-258.html

smile_z · 发表于 2025-12-20 12:18:46

感谢分享

wcs · 发表于 2025-12-20 13:05:24

试了一下不错。支持了

guong · 发表于 2025-12-20 13:15:28

谢谢楼主分享！

轻松是心 · 发表于 2025-12-20 13:23:49

谢谢楼主分享！

wangnianf · 发表于 2025-12-20 13:28:38

试了一下，可以应用

it323 · 发表于 2025-12-20 13:28:50

感谢分享！

wn168cn@163.com · 发表于 2025-12-20 13:37:53

支持原创

wyqdabcd · 发表于 2025-12-20 14:19:21

感谢分享

wuxinwei110 · 发表于 2025-12-20 14:29:18

sdewerewrerer

wang1126 · 发表于 2025-12-20 15:31:14

谢谢楼主分享

handsome_xiang · 发表于 2025-12-20 15:35:19

感谢分享！

liuzhidong1217 · 发表于 2025-12-20 18:29:08

感谢分享

红旗下的霸霸 · 发表于 2025-12-20 18:43:15

感谢分享

a66 · 发表于 2025-12-20 19:24:29

支持~

hhcha · 发表于 2025-12-20 19:34:47

感谢分享!

唐峰 · 发表于 2025-12-20 19:36:56

谢谢提供分享

vindo · 发表于 2025-12-20 21:07:40

感谢分享！~

youxia1220 · 发表于 2025-12-20 21:25:31

谢谢分享

mouse723 · 发表于 2025-12-20 21:41:30

驚為天人的神作，看了讓人熱血沸騰，感謝分享。

ntcjq999 · 发表于 7 天前

感谢分享

pan001 · 发表于 7 天前

感谢感谢

guong · 发表于 7 天前

感谢楼主分享了！

rengrancunzai · 发表于 7 天前

感谢分享

fegr · 发表于 7 天前

谢谢分享

进士小站 · 发表于 7 天前

个人感觉这个应该效果不错

wyp858 · 发表于 7 天前

可以自动安装不错，感谢楼主分享

yswb166 · 发表于 7 天前

感谢楼主分享

dshit · 发表于 6 天前

那你这个搞完还会改主页吗

		自动登录	找回密码
密码			注册

[分享] 驱动总裁全自动安装驱动脚本（系统封装部署专用）

点评