用批处理送大家一个“国庆快乐”

batche

更新：调了一下色，在原来的淡入后又加了闪烁、跳动特效。

1. @echo off
   
2. set "Marx=毛"
   
3. 
   
4. If "%1"=="" (reg add HKCU\Console\National_Day /V "FontSize" /T Reg_DWORD /D 0x0006000C /F >nul
   
5. Start "National_Day" "%ComSpec%" /C %0 arg & exit) else reg delete HKCU\Console\National_Day /F >nul
   
6. Mode Con: Cols=220 Lines=25 & Chcp 437>nul&setlocal EnableDelayedExpansion
   
7. for /f %%m in ('cmd/u/cecho !Marx!')do set "Marx=%%m"&set Marx=!Marx:~0,1!!Marx:~0,1!
   
8. for /f "delims=#" %%e in ('"Prompt #$e#&for %%$ in (esc) do rem"') do set "esc=%%e["&Set /p=!esc!?25l<nul
   
9. set "Chr[1]=0,0,0x0,0x7e48,0x0248,0x0248,0x0488,0x0488,0x0908,0x09fe,0x1008,0x1108,0x1288,0x3c78,0x1010,0x0aa0,0x1450,0x2818,0x0"
   
10. set "Chr[2]=0,0,0x7ffe,0x4002,0x4002,0x4ff2,0x4102,0x4102,0x4102,0x4ff2,0x4102,0x4122,0x4132,0x4102,0x5ffa,0x4002,0x4002,0x7ffe,0"
    
11. set "Chr[3]=0,0,0x0080,0x0040,0x1fff,0x1000,0x1040,0x0840,0x10e0,0x17ff,0x3040,0x20b0,0x2108,0x6108,0x4204,0x4204,0x8c06,0,0"
    
12. set "Chr[4]=0,0,0x0,0x1080,0x1080,0x1080,0x1088,0x5BFC,0x5488,0x5088,0x9088,0x1088,0x1FFE,0x1080,0x1140,0x1120,0x1210,0x140E,0x1804"
    
13. set "Chr[5]=0,0,0x0020,0x00F0,0x1F00,0x1000,0x1100,0x1100,0x2104,0x7FFE,0x0100,0x0100,0x0920,0x0910,0x1108,0x210C,0x4504,0x0200,0"
    
14. for /l %%l in (1,1,68) do (
    
15.     if %%l leq 20 (set /a c=14+%%l*12,ye=%%l*11)
    
16.     set /p=%ESC%38;2;!c!;0;0m<nul<nul&set /a sw=%%l%%2
    
17.     if %%l gtr 20 (if !sw! equ 1 (set /p=%ESC%38;2;!c!;!ye!;0m<nul) else (
    
18.     set /p=%ESC%38;2;!c!;0;0m<nul))
    
19.     if %%l equ 68 set /p=%ESC%38;2;!c!;!ye!;0m<nul&set /p=%ESC%48;2;!c!;0;0m<nul&cls
    
20.     for /l %%i in (1,1,5) do (
    
21.         if %%l equ 21 set "Chr[%%i]=!Chr[%%i]!,0"
    
22.         set /a _x=^(%%i-1^)*40+10,_y=5
    
23.         for %%_ in (!Chr[%%i]!) do (
    
24.              set /a n=1
    
25.              set "xy="
    
26.              for /l %%l in (1,1,20) do (
    
27.                  set /a x=^(%%_^&n^)/n,n*=2
    
28.                  set "xy=!x!!xy!"
    
29.                  )
    
30.              set xy=!xy:1=%Marx%!
    
31.              set xy=!xy:0=  !
    
32.              set /p=%ESC%!_y!;!_x!H<nul
    
33.              echo(!xy!
    
34.              set /a _y+=1
    
35.        )
    
36.        echo,
    
37.     )
    
38.     if %%l equ 20 timeout /t 1 /NOBREAK >nul 2>nul
    
39. )
    
40. pause>nul

复制代码

batche

sunsea 发表于 2023-9-30 23:07
上半部分74，下半部分不认识。

是五角星，没画好。

batche

享β亻寸木东 发表于 2023-10-1 16:50
这个真厉害，牛！能生成微信二维码吗？

理论上可以，实际上用这个方法很难实现。

batche

kingstonlj 发表于 2023-10-3 22:28
win11显示起来貌似有bug

首先，你应该把脚本保存为ansi编码。然后，在win11下有问题是因为其默认终端变成了wt，而代码中有设置缓冲区、字体大小的部分，只对原来的控制台主机有效。要么直接把默认终端改回去，要么通过修改wt的设置选项或settings.json文件来设置缓冲区、字体大小。