如何用批处理，删除boot.ini里面的这些信息

jasonwang · 发表于 2007-5-21 16:10:45

boot.ini里面的信息如下：
c:\grldr= "1 Key Ghost"
c:\grldr= "1 Key Ghost"

需要批处理命令删除掉，看了论坛的其它文章，不是很懂啊，看不明白，只看到有个添加参数的批处理，删除如何来做呢？

barton · 发表于 2007-5-21 16:26:16

INIFILE.COM

看看这个行不行

lianjiang · 发表于 2007-5-21 16:27:17

检索帖子，会找到的。

jasonwang · 发表于 2007-5-21 16:29:39

不采用第三方软件的话，如何做到？

lianjiang · 发表于 2007-5-21 17:03:44

这时我在用的批处理中的一部分。
attrib -h -r -s c:\boot.ini  >nul
if exist c:\boot.ggh attrib -h -r -s c:\boot.ggh >nul&&del c:\boot.ggh >nul
ren c:\boot.ini boot.ggh >nul
findstr /b /i /v /c:"C:\GHLDR=" c:\boot.ggh>c:\boot.ini
notepad c:\boot.ini  >nul
cls
echo.
echo  请确认修改过的boot.ini文件内容。
echo.
echo  无误的话，按任意键结束。
pause>nul
attrib +h +r +s c:\boot.ini  >nul
del c:\boot.ggh  >nul

wjh6088 · 发表于 2007-5-21 17:05:26

cmd下测试通过

@echo off
attrib -s -r -h %SystemDrive%\boot.ini
if exist %SystemDrive%\boot2.iii del %SystemDrive%\boot2.iii
for /f "skip=2 tokens=* delims=$$$" %%i in ('find /v /i "1 Key Ghost" c:\boot.ini') do echo %%i >>c:\boot2.iii
del %SystemDrive%\boot.ini
ren %SystemDrive%\boot2.iii boot.ini
attrib +s +r +h %SystemDrive%\boot.ini
pause
exit

复制代码

[ 本帖最后由 wjh6088 于 2007-5-21 05:18 PM 编辑 ]

terse · 发表于 2007-5-21 17:41:00

@echo off
type %systemdrive%\boot.ini>%systemdrive%\boot.bak
attrib -h -r -s %systemdrive%\boot.ini
type %systemdrive%\boot.bak|find "c:\grldr=" /i /v>%systemdrive%\boot.ini
attrib +s +r +h %systemdrive%\boot.ini

jasonwang · 发表于 2007-5-22 10:32:56

不错，findstr这个命令太好了，原理利用重新打印生成新文件。

barton · 发表于 2007-5-22 14:45:40

原帖由 terse 于 2007-5-21 05:41 PM 发表
@echo off
type %systemdrive%\boot.ini>%systemdrive%\boot.bak
attrib -h -r -s %systemdrive%\boot.ini
type %systemdrive%\boot.bak|find "c:\grldr=" /i /v>%systemdrive%\boot.ini
attrib +s +r +h % ...

type |find这个很简介

starrysky · 发表于 2007-6-1 11:59:52

原帖由 terse 于 2007-5-21 05:41 PM 发表
@echo off
type %systemdrive%\boot.ini>%systemdrive%\boot.bak
attrib -h -r -s %systemdrive%\boot.ini
type %systemdrive%\boot.bak|find "c:\grldr=" /i /v>%systemdrive%\boot.ini
attrib +s +r +h % ...

这个是最清晰明了、最简单也是最好的答案。

netwinxp · 发表于 2007-6-1 21:22:59

拜托，没进windows哪来的%Systemdrive%?

lianjiang · 发表于 2007-6-1 21:56:11

原帖由 netwinxp 于 2007-6-1 09:22 PM 发表
拜托，没进windows哪来的%Systemdrive%?

楼主没要求是dos下，因此假定是cmd环境。

sha · 发表于 2007-7-8 22:37:54

有一个Bootcfg 命令专门调整 boot.ini设置

		自动登录	找回密码
密码			注册

如何用批处理，删除boot.ini里面的这些信息

在 cmd下