PE下读取硬盘系统计算机名的工具有吗？

jnwin123 · 发表于前天 13:17

有没有什么工具在PE下一键读出硬盘系统的计算机名？
或者简单的方法可以查看到计算机名？

邪恶海盗 · 发表于前天 13:56

NTPWEdit？

二○二五年五月十六日

邪恶海盗 · 发表于前天 14:05

计算机名啊，看错了，可以参考一下0PE里的提取网络连接信息的批处理，反正都是读注册表：

@echo off 2>nul 3>nul
setlocal enabledelayedexpansion
set /p Input=输入要查询的系统安装盘符[例如D]：
if /i "%Input%:" neq "%systemDrive%" (
for %%a in (software system) do (
if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
)
reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
call :GetIPInfo Temp_HIV1 Temp_HIV2
reg unload HKLM\Temp_HIV1 >nul
reg unload HKLM\Temp_HIV2 >nul
) else call :GetIPInfo SOFTWARE SYSTEM
start "" "%TEMP%\IPInfo.txt" & exit/b
:GetIPInfo
for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
if /i "%%a" == "Default" set /a x=%%c
)
set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
set "v2=ControlSet00%x%\Control\Network"
set "v3=ControlSet00%x%\services\Tcpip\Parameters"
set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
set "v=%%a"
if "!v:%v1%\=!" neq "!v!" (
set /a n+=1
for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
if /i "%%b" == "ServiceName" (
set "Guid!n!=%%d"
) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
)
)
)
if not defined n echo,找不到网卡&pause & exit
(for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
if /i "%%a" == "Domain" (
if "%%c" neq "" (echo,域名名称：%%c)else echo,域名名称：^<nul^>
) else if /i "%%a" == "HostName" echo,主机名称：%%c
))>"%TEMP%\IPInfo.txt"
for %%a in (%s%) do set "_%%a=1"
(for /l %%a in (1 1 %n%) do (
echo,&echo,网卡名称：!NetCard%%a!
for %%b in (%s%) do set "%%b="
for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
if defined flag (
for /f "tokens=1,2*" %%c in ("%%b") do (
if /i "%%c" == "Name" echo,连接名称：%%e& set "flag="
)
) else (
set "v=%%b"
for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" set flag=1
)
)
for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
)
if /i "!EnableDHCP!" == "0x1" (
echo,IP 地址：!DHCPIPAddress!
echo,子网掩码：!DHCPSubnetMask!
echo,默认网关：!DHCPDefaultGateway!
echo,DNS 地址：!DHCPNameServer!
) else (
echo,IP 地址：!IPAddress!
echo,子网掩码：!SubnetMask!
echo,默认网关：!DefaultGateway!
echo,DNS 地址：!NameServer!
)
))>>"%TEMP%\IPInfo.txt"

复制代码

HendrikXL · 发表于前天 14:05

常用的方法应该是进pe后把原系统的注册表挂载起来找到HKEY_LOCAL_MACHINE\System\CurrenControlSet\Control\ComputerName\ComputerName项就能看到了楼上大佬就是这个方法

jnwin123 · 发表于前天 14:48

HendrikXL 发表于 2025-5-16 14:05
常用的方法应该是进pe后把原系统的注册表挂载起来找到HKEY_LOCAL_MACHINE\System\CurrenControlSet\Control ...

这个方法我知道，想找个更简单的工具一键读取的不知道有没有，

laott · 发表于前天 14:58

WinosInfo

jnwin123 · 发表于前天 15:17

laott 发表于 2025-5-16 14:58
WinosInfo

PE下读硬盘系统的计算机名

技束源 · 发表于前天 15:18

雷电PE作者的WinosInfo工具

idcicp · 发表于前天 15:20

我在PE下也是用WinosInfo

太湖哥 · 发表于前天 15:27

也是用WinosInfo

lixiangliuyi · 发表于前天 17:01

破解密码的软件都能显示用户名

jnwin123 · 发表于前天 18:54

lixiangliuyi 发表于 2025-5-16 17:01
破解密码的软件都能显示用户名

我问的计算机名

jnwin123 · 发表于前天 18:58

技束源发表于 2025-5-16 15:18
雷电PE作者的WinosInfo工具

显示的是PE系统的计算机名

Bluebells · 发表于前天 20:12

本帖最后由 Bluebells 于 2025-5-16 21:07 编辑

不是所谓的一键:

OfflineComputerNameFinder.zip (452.27 KB, 下载次数: 53)

jnwin123 · 发表于前天 20:30

本帖最后由 jnwin123 于 2025-5-16 20:38 编辑

Bluebells 发表于 2025-5-16 20:12
不是所谓的一键:

PE下报未找到所需的offreg.dll动态链接库文件，拷一个补上可以打开用，但计算机名：0，读取不到。

Bluebells · 发表于前天 20:53

本帖最后由 Bluebells 于 2025-5-16 21:09 编辑

jnwin123 发表于 2025-5-16 20:30
PE下报未找到所需的offreg.dll动态链接库文件，拷一个补上可以打开用，但计算机名：0，读取不到。

无图无真相
(不要告诉我, 你补充的 offreg.dll 是 64 位版本的动态链接库文件; 14楼附件我更新加入了 offreg.dll 库文件)

jnwin123 · 发表于前天 21:22

本帖最后由 jnwin123 于 2025-5-16 21:47 编辑

Bluebells 发表于 2025-5-16 20:53
无图无真相
(不要告诉我, 你补充的 offreg.dll 是 64 位版本的动态链接库文件; 14楼附件我更新加入了 of ...

更新后的可以了。感谢！

zhtq · 发表于前天 21:25

Bluebells 发表于 2025-5-16 20:12
不是所谓的一键:

感谢分享

jnwin123 · 发表于前天 21:29

Bluebells 发表于 2025-5-16 20:12
不是所谓的一键:

是否可以直接默认C：\windows ，如果不是再自行选择更改？

Bluebells · 发表于前天 22:09

jnwin123 发表于 2025-5-16 21:29
是否可以直接默认C：\windows ，如果不是再自行选择更改？

我推荐你改用 nirsoft 的 OfflineRegistryView

ljq0527 · 发表于昨天 01:20

本帖最后由 ljq0527 于 2025-5-17 01:32 编辑

有的，用IT天空“小鱼儿yr系统封装优化设置辅助工具”有这个功能，图片是在桌面环境运行的懒得重启进pe截图了，在pe下运行效果一样（注意选择目标系统盘符）

ylac · 发表于昨天 07:27

能不能看IP的？

jnwin123 · 发表于昨天 07:39

ljq0527 发表于 2025-5-17 01:20
有的，用IT天空“小鱼儿yr系统封装优化设置辅助工具”有这个功能，图片是在桌面环境运行的懒得重启进pe截图 ...

感谢

jnwin123 · 发表于昨天 07:40

ylac 发表于 2025-5-17 07:27
能不能看IP的？

不能，自动获取的只提示自动获取

guong · 发表于昨天 11:30

来了解下

[求助] PE下读取硬盘系统计算机名的工具有吗？

点评

点评

点评

点评

点评

点评

点评

点评

点评

点评

浏览过的版块

		自动登录	找回密码
密码			注册