怎么样实现自动添加XP启动菜单

rplover

（由于早期雨林木风出的 WINDOWS 一键还原是以wgldr.mbr引导，C盘要是DBR损坏，开机热键就激活不了一键还原菜单）现改成GRLDR引导菜单，又加入了些工具菜单与PE菜单，热键F9在其它盘都可以激活菜单。

现在需要一个批处理之类的能自动在XP系统下对BOOT.ini添加一键还原的菜单项，C:\wgldr.mbr=一键恢复系统

同时WIN7启动菜单如何自动加入“一键恢复系统”

求助帮写个。

rplover

谢谢大家的帮助。

zhxy9804

@echo off
title 正在判定系统引导器类型……
color 1f
attrib -s -r -h >nul 2>nul
set disname=启动系统维护工具-20110210版
set timeout=3
if exist c:\boot.ini goto ntldr
if exist c:\boot\bcd goto bootmgr  
goto nosys

:ntldr
title 系统启动属于ntldr类型，正在安装工具，请稍等……
type c:\boot.ini| find "\ZHANGHD.LDR" >nul && echo. && title 本工具已经安装，请退出。&& pause && goto clear
echo=>>c:\boot.ini
echo=>>c:\boot.ini
echo C:\ZTPE\GRUB\ZHANGHD.LDR="%disname%">>c:\boot.ini
bootcfg /timeout %timeout% >nul 2>nul
goto clear

:bootmgr
title 系统启动属于bootmgr类型，正在安装工具，请稍等……
set vid=
bcdedit >bcdtemp.txt
type bcdtemp.txt | find "\ZHANGHD.LDR" >nul && echo. && title 本工具已经安装，请退出。&& pause && del ntldr && goto clear
bcdedit  /create /d "%disname%" /application bootsector >vid.ini
for,/f,"tokens=2 delims={",%%i,in (vid.ini) do (
                  set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,in ("%vida%") do (
                  set vid={%%i}
)
echo %vid%>vid.ini
bcdedit  /set %vid% device boot >nul
bcdedit  /set %vid% path \ZTPE\GRUB\ZHANGHD.LDR >nul
bcdedit  /displayorder %vid% /addlast >nul
bcdedit  /timeout  %timeout% >nul
del ntldr >nul 2>nul
goto clear

:nosys
title C盘没有发现系统引导器，正在安装工具到硬盘，请稍等……
echo 请手动删除C盘的NTLDR，然后重命名文件ZHANG到文件名NTLDR,然后按任意键继续
@pause >nul 2>nul
bootsect /nt52 C:
goto clear

:clear
del ntdetect.com >nul 2>nul
del bootfont.bin >nul 2>nul
del autoexec.bat >nul 2>nul
del config.sys >nul 2>nul
del autoexec.bat >nul 2>nul
del config.sys >nul 2>nul
del bcdtemp.txt >nul 2>nul
del vid.ini >nul 2>nul
del vid.txt >nul 2>nul
del bcd_backup.log >nul 2>nul
del bcd_backup.log1 >nul 2>nul
del bcd_backup.log2 >nul 2>nul
del bcd_backup.log1 >nul 2>nul
attrib +s +r +h   >nul 2>nul
attrib +s +r +h  ZTPE >nul
attrib +s +r +h  ZTPE\DESKTOP.INI >nul
attrib -s -r -h SETUP.CMD
title 安装已经完成,重新启动选择菜单进入系统维护工具。
@pause
del %0

zlgs

加 echo. 很有必要相当于回车输出一空行，避免加到文件尾部，如果文件结束有空行则看不出来~~
保险起见批处理要以下最少三行内容
attrib -r c:\boot.ini
echo. >>c:\boot.ini
echo C:\wgldr.mbr="一键恢复系统" >>c:\boot.ini

zlgs

利用echo的重定向">>"向某文件末尾添加内容
li例如
echo C:\wgldr.mbr="一键恢复系统" >>c:\boot.ini
避免出错用attrib加去除文件属性等
看图说话

天君

kingder

XP现在用的人很少了吧

jinql

主要是为了掌握技术，感谢版主，学习了。