|
|
以上问题感觉是进入GHOST后找不到对应盘符，应该是img文件中的autoexec.bat中的代码有问题，现贴出来求解决：
@echo off
IF NOT %CONFIG%==DOS LH SHSUCDX /D:?IDECD1 /D:?USBCD1 /D:?FWRCD1
IF NOT %CONFIG%==DOS FINDCD /S>NUL
IF "%CDROM%"=="" SET CDROM=0
TW /ns /np >nul
SMARTDRV.EXE
CTMOUSE.EXE
rem 如果选择驱动IDE/SATA/SCSI光驱，则认为从光盘启动，否则认为从U盘启动
set dstdisk=2
if %config%==CDROM set dstdisk=1
cls
echo.
echo.
echo.
echo 下面将搜索各盘GHO下的镜像和克隆工具，请按任意键……
echo.
echo （注意：如出现 Abort,Retry,Fail 出错提示，请按A键直接跳过）
echo.
pause >nul
set hd4drv=
call findudrv winsys\hd4.gho
set hd4drv=%udrv%
set ucddrv=
call findudrv winsys\sys.gho
set ucddrv=%udrv%
set gstdrv=
call findudrv winsys\ghost.exe
set gstdrv=%udrv%
set ucdinf=搜索结果：位于%ucddrv%
if #%ucddrv%==# set ucdinf=搜索结果：未找到
set hd4inf=搜索结果：位于%hd4drv%
if #%hd4drv%==# set hd4inf=搜索结果：未找到
set gstinf=搜索结果：位于%gstdrv%
if #%gstdrv%==# set gstinf=搜索结果：未找到
set vcdinf=(找到光驱%cdrom%个，盘符为%cdrom1% %cdrom2% %cdrom3% )
if #%cdrom1%==# set vcdinf=(找到光驱%cdrom%个。 )
:menu
cls
echo ┌─────────────────────┐
echo ┌────┤ DOS下系统克隆选单 ├─────┐
echo │ └─────────────────────┘ │
echo │ 1 - 手动运行SPFDISK分区 │
echo │ 2 - 手动运行GHOST克隆 │
echo │ 3 - 自动一键分区（极危险，主机中第一硬盘的所有数据将丢失！） │
echo │ 4 - 自动克隆（危险，主机中第一硬盘第一分区原有数据将丢失！） │
echo │ 5 - 退出到DOS │
echo │ 6 - 重启 │
echo ├────────────────────────────────┤
echo │注意： │
echo │ A.如果从U盘启动，Ghost中U盘占据第一个盘，主机硬盘为第二个盘 │
echo │ B.如克隆包位于U盘且分配了盘符，Ghost选文件时，请从盘符中选， │
echo │ 而不要从分区中去定位克隆包文件，否则克隆可能中断！ │
echo │ C.克隆前必须在本机任何DOS下可读盘winsysy目录中准备如下文件：│
echo │ 系统克隆镜像：“SYS.GHO”(%ucdinf%) │
echo │ 一键分区镜像：“HD4.GHO”(%hd4inf%) │
echo │ 系统克隆工具：“GHOST.EXE”(%gstinf%) │
echo ├────────────────────────────────┤
echo │ %vcdinf% │
echo │ Email:hhh333@tom.com│
echo └────────────────────────────────┘
echo.
choice /C:123456 "请输入你的选择:"
if errorlevel 6 goto 6
if errorlevel 5 goto 5
if errorlevel 4 goto 4
if errorlevel 3 goto 3
if errorlevel 2 goto 2
if errorlevel 1 goto 1
:1
spfdisk
goto menu
:2
if #%gstdrv%==# goto gsterr
%gstdrv%\winsys\ghost.exe
goto menu
:3
if #%gstdrv%==# goto gsterr
if not #%hd4drv%==# goto autopart
echo 错误：
echo 一键分区镜像 hd4.gho 未找到！
echo 击任意键回主选单……
pause >nul
goto menu
:4
if #%gstdrv%==# goto gsterr
if not #%ucddrv%==# goto autoghost
echo 错误：
echo 系统克隆镜像 sys.gho 未找到！
echo 击任意键回主选单……
pause >nul
goto menu
:5
cls
type a:help.txt
goto end
:6
r.com
goto end
:autopart
echo.
echo 警告：
echo 主机第一个硬盘的所有数据将全部丢失，
echo 你可以按Ctrl-Alt-Del来中断本操作，否则按任意键继续……
pause >nul
%gstdrv%\winsys\ghost.exe -clone,mode=load,src=%hd4drv%\winsys\hd4.gho,dst=%dstdisk% -sure
echo.
echo 一键分区完成，按任意健回主菜单。
pause >nul
goto menu
:autoghost
echo.
echo 警告：
echo 主机第一个硬盘第一分区上的所有数据将全部丢失，
echo 你可以按Ctrl-Alt-Del来中断本操作，否则按任意键继续……
pause >nul
%gstdrv%\winsys\ghost.exe -clone,mode=pload,src=%ucddrv%\winsys\sys.gho:1,dst=%dstdisk%:1 -sure -rb
goto end
:gsterr
echo 错误：
echo 克隆工具Ghost.exe未找到，不能进行系统克隆操作！
:end
|
|
[复制链接]
IP卡
狗仔卡
发表于 2010-5-2 17:32:45
显身卡
