|
C大,怎么回事;这次会提示有病毒,请你看看
@echo off
setlocal
pushd "%~dp0"
title ImDisk Virtual Disk Driver 安装
echo ImDisk Virtual Disk Driver 安装
echo.
set IMDISK_TOTAL_DEVICES=0
set IMDISK_VALID_DEVICES=0
set IMDISK_PENDING_REMOVAL_DEVICES=0
if exist "%SystemRoot%\system32\imdisk.exe" (
for /f %%a in ('imdisk -l -n ^| find /v /i ^"No^"') do call :addline "%%a"
)
if %IMDISK_VALID_DEVICES% GTR 0 (
echo Number of existing ImDisk virtual disks: %IMDISK_VALID_DEVICES%
echo.
if "%IMDISK_SILENT_SETUP%" == "1" (
echo 请在升级前卸载所有现有的 ImDisk 虚拟磁盘!
echo.
) else (
.\msgboxw.exe "请在升级前卸载所有现有的 ImDisk 虚拟磁盘!" 16 "ImDisk Virtual Disk Driver setup"
start "" "%SystemRoot%\system32\control.exe" "%SystemRoot%\system32\imdisk.cpl"
)
popd
endlocal
goto :eof
)
echo 现有 ImDisk 虚拟磁盘数量: %IMDISK_TOTAL_DEVICES%
echo.
if %IMDISK_TOTAL_DEVICES% == 0 (
"%SystemRoot%\system32\net.exe" stop imdsksvc
"%SystemRoot%\system32\net.exe" stop awealloc
"%SystemRoot%\system32\net.exe" stop imdisk
if exist "%SystemRoot%\system32\taskkill.exe" "%SystemRoot%\system32\taskkill.exe" /F /IM imdsksvc.exe
)
"%SystemRoot%\system32\rundll32.exe" setupapi.dll,InstallHinfSection DefaultInstall 132 .\imdisk.inf
if errorlevel 1 (
if not "%IMDISK_SILENT_SETUP%" == "1" .\msgboxw.exe "安装失败。 请尝试重新启动计算机,然后再次尝试运行安装程序包。" 16 "ImDisk Virtual Disk Driver setup"
popd
endlocal
goto :eof
)
set IMDISK_START_FAILED=1
if %IMDISK_TOTAL_DEVICES% == 0 (
set IMDISK_START_FAILED=0
net start imdsksvc || set IMDISK_START_FAILED=1
net start awealloc || set IMDISK_START_FAILED=1
net start imdisk || set IMDISK_START_FAILED=1
)
if not "%IMDISK_SILENT_SETUP%" == "1" (
if %IMDISK_START_FAILED% == 0 (
.\msgboxw.exe "安装成功完成。 在控制面板中打开 ImDisk 虚拟磁盘驱动程序小程序或使用 imdisk 命令行来管理您的虚拟磁盘!" 0 "ImDisk Virtual Disk Driver setup"
) else (
.\msgboxw.exe "安装完成,但驱动程序或服务无法启动。 请尝试重新启动计算机,然后再次尝试运行安装程序包。" 16 "ImDisk Virtual Disk Driver setup"
)
)
popd
endlocal
goto :eof
:addline
"%SystemRoot%\system32\imdisk.exe" -l -u %~1 > nul 2>&1
if errorlevel 1 (
set /a IMDISK_PENDING_REMOVAL_DEVICES=%IMDISK_PENDING_REMOVAL_DEVICES% + 1 > nul
) else (
set /a IMDISK_VALID_DEVICES=%IMDISK_VALID_DEVICES% + 1 > nul
)
set /a IMDISK_TOTAL_DEVICES=%IMDISK_TOTAL_DEVICES% + 1 > nul
goto :eof
|
|