求一个批处理，不胜感激！

香国妙手

D盘666文件夹内有5个文件，分别为
D:\666\000.txt
D:\666\001.bat
D:\666\002.bat
D:\666\003.bat
D:\666\004.bat

000.txt为随机生成，总共只有两行内容
第一行可能为A或B
第二行可能为C或D

现求一个批处理，自动获取000.txt内容
假如获取的第一行内容为A，第二行内容为C，则call 001.bat
假如获取的第一行内容为A，第二行内容为D，则call 002.bat
假如获取的第一行内容为B，第二行内容为C，则call 003.bat
假如获取的第一行内容为B，第二行内容为D，则call 004.bat

恳请赐教，不胜感激！

WUMEIHAI

1. @echo off
   
2. setlocal EnableDelayedExpansion
   
3. 
   
4. REM 读取 000.txt 的内容
   
5. for /f "tokens=1,2" %%a in (D:\666\000.txt) do (
   
6.     set "line1=%%a"
   
7.     set "line2=%%b"
   
8. )
   
9. 
   
10. REM 根据内容调用相应的批处理文件
    
11. if "!line1!"=="A" (
    
12.     if "!line2!"=="C" (
    
13.         call D:\666\001.bat
    
14.     ) else (
    
15.         call D:\666\002.bat
    
16.     )
    
17. ) else (
    
18.     if "!line2!"=="C" (
    
19.         call D:\666\003.bat
    
20.     ) else (
    
21.         call D:\666\004.bat
    
22.     )
    
23. )
    
24. 
    
25. endlocal
    

复制代码

zlq_hysy

很绕口的哈，

香国妙手

WUMEIHAI 发表于 2024-4-30 10:10

感谢您的热心解答！刚才测试了一下，不管我如何修改000.txt的内容，比如：AC,AD,BC,BD，当然也只有这4种情况，但结果都是运行了004.bat
能否买麻烦您重新修改一下？谢谢！

maisifu

学习。。。

Climbing

WUMEIHAI 发表于 2024-4-30 10:10

2楼这个批处理的问题在于获取000.txt内容时看错了题意，按他的代码，AC组合是在一行上，而且，中间有分隔符，实际上000.txt有两行内容，类似这样：
A
C
所以，他的代码无法获取line1和line2的内容。稍微改一下：

1. 
   
2. @echo off
   
3. setlocal EnableDelayedExpansion
   
4. 
   
5. :: 读取 000.txt 的内容
   
6. if exist ~setvar.bat del /f/q ~setvar.bat
   
7. set n=0
   
8. for /f "tokens=*" %%a in (D:\666\000.txt) do (
   
9. set /a n=n+1
   
10. echo set "line!n!=%%a" >>~setvar.bat
    
11. )
    
12. call ~setvar.bat
    
13. del /f/q ~setvar.bat
    
14. 
    
15. REM 根据内容调用相应的批处理文件
    
16. if "!line1!"=="A" (
    
17.     if "!line2!"=="C" (
    
18.         call D:\666\001.bat
    
19.     ) else (
    
20.         call D:\666\002.bat
    
21.     )
    
22. ) else (
    
23.     if "!line2!"=="C" (
    
24.         call D:\666\003.bat
    
25.     ) else (
    
26.         call D:\666\004.bat
    
27.     )
    
28. )
    
29. endlocal
    

复制代码

香国妙手

Climbing 发表于 2024-4-30 11:45
2楼这个批处理的问题在于获取000.txt内容时看错了题意，按他的代码，AC组合是在一行上，而且，中间有分隔 ...

感谢Climbing大神！
完美实现预期效果！

Climbing

问了一下chatGPT，它的第三个回复跟我的思路差不多，但不需要产生临时文件了，如下：

1. 
   
2. @echo off
   
3. setlocal enabledelayedexpansion
   
4. 
   
5. rem Set the input file name
   
6. set "inputFile=000.txt"
   
7. 
   
8. rem Read the content of the file into an array
   
9. set i=0
   
10. for /f "usebackq tokens=*" %%a in ("%inputFile%") do (
    
11.     set /a i+=1
    
12.     set "line[!i!]=%%a"
    
13. )
    
14. 
    
15. rem Assign the lines to separate variables
    
16. set "line1=!line[1]!"
    
17. set "line2=!line[2]!"
    
18. 
    
19. echo First line: !line1!
    
20. echo Second line: !line2!
    
21. 
    
22. endlocal
    

复制代码

x光人

学习了！！

wang1126

Climbing 发表于 2024-4-30 11:45
2楼这个批处理的问题在于获取000.txt内容时看错了题意，按他的代码，AC组合是在一行上，而且，中间有分隔 ...

谢谢分享

2012飘水

感谢大佬们的精彩答复，学习了

qingyi78

问了下copilot 回答如下：请大家看看CHATGPT和COPILOT的区别。@echo off
setlocal enabledelayedexpansion

REM Read the first line from 000.txt
set "firstLine="
for /f "usebackq delims=" %%a in ("D:\666\000.txt") do (
    set "firstLine=%%a"
    goto :break
)
:break

REM Read the second line from 000.txt
set "secondLine="
for /f "usebackq skip=1 delims=" %%b in ("D:\666\000.txt") do (
    set "secondLine=%%b"
    goto :continue
)
:continue

REM Determine which batch file to call based on the content of the lines
if "!firstLine!"=="A" (
    if "!secondLine!"=="C" (
        call "D:\666\001.bat"
    ) else if "!secondLine!"=="D" (
        call "D:\666\002.bat"
    )
) else if "!firstLine!"=="B" (
    if "!secondLine!"=="C" (
        call "D:\666\003.bat"
    ) else if "!secondLine!"=="D" (
        call "D:\666\004.bat"
    )
)

endlocal

君临唯一

坐等

hilsonma

如果000.txt的内容确实如同楼主描述的话，可以简化批如下：

1. @echo off
   
2. setlocal EnableDelayedExpansion
   
3. for /f %%a in (000.txt) do set v=!v!%%a
   
4. goto !v!
   
5. 
   
6. :AC
   
7. 001.bat
   
8. 
   
9. :AD
   
10. 002.bat
    
11. 
    
12. :BC
    
13. 003.bat
    
14. 
    
15. :BD
    
16. 004.bat

复制代码

如果本批不是放在相同文件夹，而是放在其他位置的话，则相应文件名要改为全路径。如：
000.txt 改为 D:\666\000.txt
001.bat 改为 D:\666\001.bat
依次类推。

yc2428

学习了！

lusir401

有大神在，放心学习。

万人之上

进来学习

Climbing

13楼和15楼的实现都非常巧妙，学习了。

香国妙手

hilsonma 发表于 2024-4-30 14:18
如果000.txt的内容确实如同楼主描述的话，可以简化批如下：

香国妙手

szwp

窄口牛 发表于 2024-5-1 00:16
每个标签都必须加一个跳出语句，否则会把所有标签轮流执行一次。

没call不会回来了

szwp

窄口牛 发表于 2024-5-1 00:16
每个标签都必须加一个跳出语句，否则会把所有标签轮流执行一次。

没call不会回来了

窄口牛

szwp 发表于 2024-5-1 07:04
没call不会回来了

哦，看错了，标签是运行bat。

dos时代菜鸟

1. @echo off
   
2. setlocal ENABLEDELAYEDEXPANSION
   
3. set "path1=D:\666"
   
4. set "file0=!path1!\000.txt"
   
5. set AC=001.BAT
   
6. SET AD=002.BAT
   
7. SET BC=003.BAT
   
8. SET BD=004.BAT
   
9. 
   
10. set  x=
    
11. for /f %%c in ('type "!file0!"')  DO (
    
12.     set x=!x!%%c
    
13. )
    
14. for %%c in (!x!) do (
    
15.     echo !x!=!%%c!
    
16.     call "!path1!\!%%c!"
    
17. )
    
18. pause
    

复制代码

szwp

窄口牛 发表于 2024-5-1 07:20
哦，看错了，标签是运行bat。

set /a w=(0x%v:~,1%-0xa)*2+0x%v:~1%-0xb

香国妙手

dos时代菜鸟 发表于 2024-5-1 23:26

妙不可言！感谢大神的热心帮助！

再次请教大神：我想把call命令改为goto命令，这样一个bat文件就可以搞定了。请问怎样才能实现？

麻烦您了！

我其实是一名初二的学生，这几天放假了，是用我爸的账号发帖求助的。论坛前辈才高八斗，学富五车，我等后生小辈真是大开眼界，受益匪浅！感谢无忧论坛！感谢各位叔伯大神！

dos时代菜鸟

香国妙手 发表于 2024-5-2 15:58
妙不可言！感谢大神的热心帮助！

再次请教大神：我想把call命令改为goto命令，这样一个bat文件就可以 ...

用 goto 不如用 call 调取脚本内部函数。 结构 与goto 差不多 只是 每段 结尾 加个 exit /b  

1. @echo off
   
2. setlocal ENABLEDELAYEDEXPANSION
   
3. set "path1=D:\666"
   
4. set "file0=!path1!\000.txt"
   
5. 
   
6. set  x=
   
7. for /f %%c in ('type "!file0!"')  DO (set x=!x!%%c)
   
8. CALL :!X!
   
9. 
   
10. pause
    
11. goto :eof
    
12. 
    
13. :ac
    
14. echo AC
    
15. EXIT /B
    
16. 
    
17. :AD
    
18. ECHO AD
    
19. EXIT /B
    
20. 
    
21. :BC
    
22. ECHO BC
    
23. EXIT /B
    
24. 
    
25. :BD
    
26. ECHO BD
    
27. EXIT /B

复制代码

香国妙手

dos时代菜鸟 发表于 2024-5-2 16:14
用 goto 不如用 call 调取脚本内部函数。 结构 与goto 差不多 只是 每段 结尾 加个 exit /b

已拜读，学习了！
感恩无忧，感谢有您！

cxincn

学无止境.又学到东西了

贺云飞2

太牛了，膜拜