WIM2VHD 制作VHD的好工具【加上自己做的WIM2VHD[WIN7.VHD].CMD】

0cat0 · 发表于 2010-5-1 21:30:47

这两天没事开始折腾WIN7和VHD，发现这里怎么没有WIM2VHD这个方便的工具，于是自己去官方下载，然后折腾了一天，已经打包到附件下载，喜欢官方的可以去官方下载：

http://code.msdn.microsoft.com/wim2vhd

可以用官方脚本的CMD，下载：

WIM2VHD.rar (792 Bytes, 下载次数: 482)

发现官方的WIM2VHD做出来的VHD有点问题（可能是我不会用），做出来的VHD放VM及别的机子都无法使用，只有本机没问题，于是自己做了个CMD，只要ImageX和install.wim就行了，其它的用系统自带的，说明一下，这东西我只在WIN7U版里试过没问题，08R2不知道行不行的，截图：

打包好的附件：

WIM2VHD[WIN7.VHD].rar (246.71 KB, 下载次数: 654)

[ 本帖最后由 0cat0 于 2010-5-4 10:01 编辑 ]

0cat0 · 发表于 2010-5-1 21:40:15

另外，还发现一个Disk2VHD，可以将现有硬盘转成VHD，不过我还没试，官方下载：

http://technet.microsoft.com/en-us/sysinternals/ee656415.aspx

ziyun · 发表于 2010-5-1 22:39:12

又一个精品。谢谢楼主，太谢谢了，支持

caomaoLBL · 发表于 2010-5-1 23:21:40

好东西，可以下载来试试！

xuxuezeng · 发表于 2010-5-1 23:23:11

楼主真厉害，为广大朋友提供了又也利器！

yueyezhan · 发表于 2010-5-2 02:02:00

感谢分享，收藏了，好工具

x9tian · 发表于 2010-5-2 08:30:50

哈哈，我还说有空自己整个出来，没想到楼主己经做出来了

ck · 发表于 2010-5-2 09:50:56

好工具，收藏。

0cat0 · 发表于 2010-5-2 17:29:09

更新了一下WIM2VHD[WIN7.VHD].CMD，原来用COPY {CURRENT}有时可能不行，现在改用CREATE，应该没问题了，顶楼已经添加更新：

原来的：
BCDEDIT /STORE "C:\BOOT\BCD" /COPY {CURRENT} /D "%~DP0WIN7.VHD" >"%TEMP%\VID.TXT"

现在的：
BCDEDIT /CREATE /D "%~DP0WIN7.VHD" /APPLICATION OSLOADER >"%TEMP%\VID.TXT"

xianglang · 发表于 2010-5-2 18:37:58

是不是只能在WIN7下使用，而不能在XP下用的呀？

0cat0 · 发表于 2010-5-2 19:18:54

我是XP+WIN7双系统的，这个在XP下面还试过，我是在WIN7下面做的。

单系统XP下面的还在试，弄了一天没弄出来个结果，我想问一下大家，是不是在单个系统XP下面是不是不能挂VHD呀？？？？

因为我在VM里面测试，把引导已经改为NT6，NT可以启动XP，但一加载VHD就出错，不知道什么原因？？？

0cat0 · 发表于 2010-5-2 19:28:38

刚才去官网看了一下，WIM3VHD不能在XP下用，下面是复制官方的东西：

*Q: Can I use WIM2VHD to create .VHDs for Windows Vista and Windows Server 2008? What about Windows Server 2003? Or NT 4? Or Windows 1.0?
A: No. This process is only "supported" for Windows 7 and Windows Server 2008 R2.

lc1212 · 发表于 2010-5-2 20:59:39

运行后怎么提示找不到DP0WIM2VHD.WSF？

0cat0 · 发表于 2010-5-2 21:20:46

是不是没有下载全部附件呀？只有一个CMD是不行的，要WIM2VHD.WSF放在一起才行。。。

lc1212 · 发表于 2010-5-2 21:43:38

原帖由 0cat0 于 2010-5-2 21:20 发表
是不是没有下载全部附件呀？只有一个CMD是不行的，要WIM2VHD.WSF放在一起才行。。。

已解决了，没运行 WIM2VHD_WIN7.VHD.EXE，直接运行那个CMD去了，就是生成太慢了，没法等啊好像死机一样。

[ 本帖最后由 lc1212 于 2010-5-2 21:45 编辑 ]

0cat0 · 发表于 2010-5-2 21:47:25

呵呵，慢是慢一点，好在是全自动的，还有，我的CMD里面设置生成的是64G的VHD，如果不想要这么大的，请自行修改。。。。。。。。

lc1212 · 发表于 2010-5-2 22:02:15

原帖由 0cat0 于 2010-5-2 21:47 发表
呵呵，慢是慢一点，好在是全自动的，还有，我的CMD里面设置生成的是64G的VHD，如果不想要这么大的，请自行修改。。。。。。。。

好的，感谢楼主提供这么好的工具，明天接着整，回家了。

yang162 · 发表于 2010-5-3 12:50:07

又一个精品。谢谢楼主，太谢谢了，支持

cjx2665 · 发表于 2010-5-3 14:02:49

谢谢分享，先顶后下。

0cat0 · 发表于 2010-5-3 17:04:12

很郁闷的发现。。。。。这个 WIM2VHD 制作出来的VHD有点问题，做出来的VHD在本机上面用是没有问题的，如果像我一样放VM里面测试用的就不行了，不知道什么原因。。。。。

我自己手动在控制面板建立一个盘然后手动灌注到生成的盘里面，这样做出来的VHD，直接放VM下面就可以启动了。。。。。。。。。。。。。

0cat0 · 发表于 2010-5-3 17:04:22

很郁闷的发现。。。。。这个 WIM2VHD 制作出来的VHD有点问题，我自己手动在控制面板建立一个盘然后手动灌注到生成的盘里面，这样做出来的VHD，直接放VM下面就可以启动了。。。。。。。。。。。。。

fujianabc · 发表于 2010-5-3 17:21:16

原帖由 0cat0 于 2010-5-3 17:04 发表
很郁闷的发现。。。。。这个 WIM2VHD 制作出来的VHD有点问题，我自己手动在控制面板建立一个盘然后手动灌注到生成的盘里面，这样做出来的VHD，直接放VM下面就可以启动了。。。。。。。。。。。。。

其实找一个vhdtool.exe就能很方便快速的创建vhd。

0cat0 · 发表于 2010-5-3 17:31:18

VHDTOOL.EXE这个倒是已经打到包里面了，不过还没有试过，现在试试看。。。。。。。。

刚刚又看了一下，VHDTOOL只能创建VHD，不能挂VHD，那还不如直接用DISKPART算了，还没用过DISKPART，现在去看看命令行再说了。。。。。。。。。。。

[ 本帖最后由 0cat0 于 2010-5-3 17:41 编辑 ]

假大空 · 发表于 2010-5-3 19:22:02

也是用的vhdtool创建。看下楼主这个

0cat0 · 发表于 2010-5-3 19:43:31

发现WIM2VHD的问题后，自己弄了个在WIN7下只要有ImageX和install.wim就可以自动生成VHD的，方便自己方便别人，以下是CMD：

@ECHO OFF
@CD /D "%~DP0"
:MENU
ECHO.
ECHO.
ECHO.
ECHO.             ┏━━━━━━━━━━━━━━━━━━━━━━━┓
ECHO                ┃                                           ┃
ECHO                ┃    [1] 利用[INSTALL.WIM]生成[WIN7.VHD]    ┃
ECHO                ┃                                           ┃
ECHO                ┃    [2] 将生成的[WIN7.VHD]加到[BCD]菜单    ┃
ECHO                ┃                                           ┃
ECHO                ┗━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
:IMENU
SET CHOICE=
SET /P CHOICE=请输入数字或字母 [回车] 退出:
IF NOT "%CHOICE%"=="" SET CHOICE=%CHOICE%
IF /I "%CHOICE%"=="1" GOTO VHD
IF /I "%CHOICE%"=="2" GOTO BCD
IF /I "%CHOICE%"=="" @EXIT
CLS
GOTO MENU
:VHD
CLS
@ECHO CREATE VDISK FILE="%~DP0WIN7.VHD" MAXIMUM=65539 TYPE=EXPANDABLE>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO SELECT VDISK FILE="%~DP0WIN7.VHD">>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO ATTACH VDISK>>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO CREATE PARTITION PRIMARY>>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO ASSIGN LETTER=V>>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO FORMAT FS=NTFS QUICK LABEL=SYS-WIN7VHD>>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO EXIT>>"%TEMP%\DiskPart[ATTACH].TXT"
@ECHO SELECT VDISK FILE="%~DP0WIN7.VHD">"%TEMP%\DiskPart[DETACH].TXT"
@ECHO DETACH VDISK>>"%TEMP%\DiskPart[DETACH].TXT"
@ECHO EXIT>>"%TEMP%\DiskPart[DETACH].TXT"
ECHO.
ECHO.
ECHO.
ECHO.             ┏━━━━━━━━━━━━━━━━━━━━━━━┓
ECHO                ┃                                           ┃
ECHO                ┃    请不要关闭窗口，后台正在处理中...    ┃
ECHO                ┃                                           ┃
ECHO                ┃    看进度请打开当前目录的 WIN7.VHD.TXT    ┃
ECHO                ┃                                           ┃
ECHO                ┗━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
DISKPART.EXE /S "%TEMP%\DiskPart[ATTACH].TXT">"%~DP0WIN7.VHD.TXT"
ImageX.EXE /APPLY "%~DP0INSTALL.WIM" 5 "V:">>"%~DP0WIN7.VHD.TXT"
DISKPART.EXE /S "%TEMP%\DiskPart[DETACH].TXT">>"%~DP0WIN7.VHD.TXT"
@START "" "%~DP0WIN7.VHD.TXT"
ECHO.
ECHO.
ECHO.
ECHO.             ┏━━━━━━━━━━━━━━━━━━━━━━━┓
ECHO                ┃                                           ┃
ECHO                ┃       操作完成，按任意键返回菜单       ┃
ECHO                ┃                                           ┃
ECHO                ┗━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
PAUSE>NUL
CLS
GOTO MENU
:BCD
CLS
SET VID=
BCDEDIT.EXE /CREATE /D "%~DP0WIN7.VHD" /APPLICATION OSLOADER >"%TEMP%\VID.TXT"
FOR,/F,"TOKENS=2 DELIMS={",%%I,IN (%TEMP%\VID.TXT) DO (SET VIDA=%%I)
FOR,/F,"TOKENS=1 DELIMS=}",%%I,IN ("%VIDA%") DO (SET VID={%%I})
ECHO %VID%>"%TEMP%\VID.TXT"
BCDEDIT.EXE /SET %VID% DEVICE VHD="[%~D0]%~P0WIN7.VHD" >NUL
BCDEDIT.EXE /SET %VID% PATH "\WINDOWS\SYSTEM32\WINLOAD.EXE" >NUL
BCDEDIT.EXE /SET %VID% LOCALE "zh-CN" >NUL
BCDEDIT.EXE /SET %VID% INHERIT {BOOTLOADERSETTINGS} >NUL
BCDEDIT.EXE /SET %VID% SYSTEMROOT "\WINDOWS" >NUL
BCDEDIT.EXE /SET %VID% OSDEVICE VHD="[%~D0]%~P0WIN7.VHD" >NUL
BCDEDIT.EXE /SET %VID% DETECTHAL ON >NUL
BCDEDIT.EXE /DISPLAYORDER %VID% /ADDLAST >NUL
BCDEDIT.EXE /TIMEOUT 9 >NUL
@DEL /F /A /Q "%TEMP%\VID.TXT" >NUL
ECHO.
ECHO.
ECHO.
ECHO.             ┏━━━━━━━━━━━━━━━━━━━━━━━┓
ECHO                ┃                                           ┃
ECHO                ┃       操作完成，按任意键返回菜单       ┃
ECHO                ┃                                           ┃
ECHO                ┗━━━━━━━━━━━━━━━━━━━━━━━┛
ECHO.
PAUSE>NUL
CLS
GOTO MENU

0cat0 · 发表于 2010-5-3 20:55:30

更新一下顶楼的附件，加上自己做的CMD，到此WIM2VHD基本OK了，明天有时间就开始折腾做好的VHD了。。。。。。

0cat0 · 发表于 2010-5-3 21:15:15

想了一想好象还可以再改改，把INSTALL.WIM文件的路径也做拖放或输入的，这样就可以在空硬盘上面用虚拟光驱加载WIN7系统ISO生成VHD，然后修改引导加入菜单，然后。。。。。。。。。

等明天有空再试了。。。。。。。。。。。

ming6595 · 发表于 2010-5-3 21:22:54

http://bbs.wuyou.net/forum.php?m ... &extra=page%3D2

0cat0 · 发表于 2010-5-3 21:35:25

多谢提供，不过还是想自己折腾，这样比较容易找问题。。。。。。。

0cat0 · 发表于 2010-5-3 22:11:51

顶楼更新一下，现在可能拖放install.wim文件了。。。。。。

		自动登录	找回密码
密码			注册

WIM2VHD 制作VHD的好工具【加上自己做的WIM2VHD[WIN7.VHD].CMD】

回复 #10 xianglang 的帖子

回复 #10 xianglang 的帖子

回复 #13 lc1212 的帖子

回复 #15 lc1212 的帖子

回复 #22 fujianabc 的帖子

回复 #27 0cat0 的帖子

回复 #28 ming6595 的帖子