启动时随机选择PE桌面背景

hanzsim

前一阵研究某PE，觉得有个功能有点意思，这个PE启动时随机选择桌面背景。研究了一下，代码很简单，是将图片内置于PE中，文件名按数字规律命名，随机数产生一个匹配的文件名，然后LOGO命令设置背景。我对这个功能很有兴趣，就是有两个小问题，一是图多了的话，内置的话PE尺寸又大了不少，哪怕用PS加工过损失部分质量也很可观的；二是图像文件名、图像总个数有要求。于是决定弄个外置的、不要求文件名和文件个数的。
花了几个小时，整出个批处理来，使用7z将图像文件打包好，只要能访问到这个7z文件，在INI文件中，设置背景的命令前，使用两条语句，就能使用随机切换。
代码如下：
@Echo OFF
SetLocal ENABLEDELAYEDEXPANSION
Set count=0
Set files=
For /F "tokens=* skip=19" %%a In ('7z l -ir0^^!*.jpg %1') Do (
    Set file=%%a
    Set t=!file:~0,1!
    If !t!==- Goto SELECT
    Set t=!file:~20,1!
    If !t!==. (
        Set files=!files!"!file:~53!"
        Set /A count=count+1
    )
)
:SELECT
Set /A index=%2 %% count
For %%a In (!files!) Do (
    If !index! EQU 0 (
        Echo !index!
        Set file=%%a
        Set t=%%~na%%~xa
        Goto EXTRACT
    )
    Set /A index=index-1
)
:EXTRACT
7z e -aoa -oX:\Windows\Web\Wallpaper\Windows %1 !file!
Del X:\Windows\Web\Wallpaper\Windows\img0.jpg
Ren "X:\Windows\Web\Wallpaper\Windows\!t!" img0.jpg
Set file=
Set files=
Set count=
Set index=
Set t=

hanzsim

用法说明：
1、将需要的JPG图像打好7z压缩包，文件名、文件夹层次结构、个数随意。
2、将上面的代码保存为cmd文件。放在哪都行。
3、在INI文件的LOGO或WALL命令前，添加如下两条命令：
CALC #&index=%RANDOM%/4294967296
EXEC =*上面的批处理文件名  7z图像压缩包 %&index%
就这样。
*批处理只能支持32位整数，PECMD的64位随机数必须先处理成32位的，所以除以了4294967296，求余也可以。
*把这两句可以单独放在一个INI文件中，配合着WALL，可以随时切换桌面背景。
*这是假定桌面背景使用的是X:\Windwos\Web\Wallpaper\Windows\img0.jpg，如果PE中使用的是其它路径，把此批处理代码中的X:\Windows\Web\Wallpaper\Windows路径和文件名img0.jpg换成你真实的路径名称即可。
*这个批处理调用的是16.04的7z命令行，我没有做其它版本的试验，主要是不同版本的7z命令行输出的信息可能有差异，功能上应该是没问题的。建议使用前，命令行下执行一下7z命令，数一数开始时显示的无用信息是不是19行（包括空行）。如果不是19行，用这个行数替换掉批处理中skip=19中的19。

smartcowboy

这个好，先收藏

LLzz888

谢谢

双响炮

不错，已收藏

创新科技2015

谢谢

canghaisui

谢谢楼主分享，思路很好

tt911

Random, OutputVar , 1,20
DllCall("SystemParametersInfo", UInt, 0x14, UInt, 0, Str, A_WinDir . c:\WallPaper%OutputVar%.bmp, UInt, 2)
AHK只要两行代码完成。

2011mtw35

2年前就可以实现了，可以自定义启动顺序，更换的时间，但程序不是我写的，
所以没有分享出来。