名单内删除不了，删除了非名单内的

wenbieba · 发表于 2024-9-2 22:22:36

本帖最后由 wenbieba 于 2024-9-3 15:57 编辑

用此命令删除ReserveWinSxS.txt文本里的项，结果删除了文本名单之外的，折腾好久无果，麻烦各位大神指点哪里不对，

cd /d "%~dp0"
set Temp=%~dp0Temp
for /f "eol=: delims=" %%i in ('dir /b "%SystemDrive%\Windows\WinSxS" /ad^|findstr /vxilg:"%Temp%\ReserveWinSxS.txt"') do (
if exist "%SystemDrive%\Windows\WinSxS\%%i" (
cmd.exe /c takeown /f "%SystemDrive%\Windows\WinSxS\%%i" /r /d y && icacls "%SystemDrive%\Windows\WinSxS\%%i" /grant administrators:F /t
RD /Q /S "%SystemDrive%\Windows\WinSxS\%%i" ))

ReserveWinSxS.txt名单，一项一行

_userexperience-desktop_
_dual_
-defender-
-senseclient-
-onedrive-
-mediaplayer-
-cursors_
-pinyinds-
-userexperience-
…………

wenbieba · 发表于 2024-9-3 08:01:11

窄口牛发表于 2024-9-3 07:36

什么意思

wenbieba · 发表于 2024-9-3 08:03:38

窄口牛发表于 2024-9-3 07:36

大佬级别，也灌水吗

窄口牛 · 发表于 2024-9-3 08:11:16

窄口牛 · 发表于 2024-9-3 08:21:28

你就先执行下

dir /b "%SystemDrive%\Windows\WinSxS" /ad|findstr /vxilg:"%Temp%\ReserveWinSxS.txt"

这句呢？

ppll2030 · 发表于 2024-9-3 08:33:59

你在cmd下，输入findstr /? ，再看看 /v 这个参数是什么意思

tanglf · 发表于 2024-9-3 08:34:01

精简系统？

wenbieba · 发表于 2024-9-3 08:34:09

窄口牛发表于 2024-9-3 08:21
你就先执行下
dir /b "%SystemDrive%\Windows\WinSxS" /ad|findstr /vxilg:"%Temp%\ReserveWinSxS.txt"

...

字体乱码，在手机上正常，换了两个电脑，均显示正常。

TXT内是想删除的项目，一项一行。结果文本内想删除的他没删除，把不需要删除的给删了

holley2008 · 发表于 2024-9-3 10:11:53

本帖最后由 holley2008 于 2024-9-3 10:13 编辑

你的名单怎么有的是下划线有的是连接线？？？

@echo off
cd /d "%~dp0"
set Temp=%~dp0Temp
for /f "eol=: delims=" %%i in ('dir /b "%SystemDrive%\Windows\WinSxS" /ad') do (
findstr /ixc:"%%i" "%Temp%\ReserveWinSxS.txt" >nul
if errorlevel 1 (
if exist "%SystemDrive%\Windows\WinSxS\%%i" (
echo Processing: %%i
takeown /f "%SystemDrive%\Windows\WinSxS\%%i" /r /d y
icacls "%SystemDrive%\Windows\WinSxS\%%i" /grant administrators:F /t
RD /Q /S "%SystemDrive%\Windows\WinSxS\%%i"
)
) else (
echo Skipping: %%i
)
)

复制代码

wenbieba · 发表于 2024-9-3 10:48:30

holley2008 发表于 2024-9-3 10:11
你的名单怎么有的是下划线有的是连接线？？？

应该是下划线，谢谢，一会改下

wenbieba · 发表于 2024-9-3 11:13:55

ppll2030 发表于 2024-9-3 08:33
你在cmd下，输入findstr /? ，再看看 /v 这个参数是什么意思

只打印不包含

wenbieba · 发表于 2024-9-3 12:16:20

holley2008 发表于 2024-9-3 10:11
你的名单怎么有的是下划线有的是连接线？？？

刚看了，原文件明部分连接线部分下划线

wenbieba · 发表于 2024-9-3 12:18:37

holley2008 发表于 2024-9-3 10:11
你的名单怎么有的是下划线有的是连接线？？？

Processing: %%i 处理
Skipping: %%i 跳过
这个跳过能去掉吗

holley2008 · 发表于 2024-9-3 13:30:06

wenbieba 发表于 2024-9-3 12:18
Processing: %%i 处理
Skipping: %%i 跳过
这个跳过能去掉吗

直接rem注释掉或删除即可

yzqmxh · 发表于 2024-9-3 15:36:29

学习了

wenbieba · 发表于 2024-9-4 23:34:10

holley2008 发表于 2024-9-3 10:11
你的名单怎么有的是下划线有的是连接线？？？

大师你好，刚试了一下，把%SystemDrive%\Windows\WinSxS下文件夹挨着齐删除，没有按名单里边的进行删除，麻烦大佬在修改一下

wenbieba · 发表于 2024-9-5 09:07:07

holley2008 发表于 2024-9-3 13:30
直接rem注释掉或删除即可

劳烦大师看看，测试了一下，文件夹里的文件夹挨着给删除，没有按照TXT内指定删除

holley2008 · 发表于 2024-9-5 09:09:36

wenbieba 发表于 2024-9-4 23:34
大师你好，刚试了一下，把%SystemDrive%\Windows\WinSxS下文件夹挨着齐删除，没有按名单里边的进行删除， ...

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "Temp=%~dp0Temp"
set "WinSxSPath=%SystemDrive%\Windows\WinSxS"
for /f "usebackq delims=" %%a in ("%Temp%\ReserveWinSxS.txt") do (
set "folderPattern=%%a"
if not "!folderPattern!"=="" (
for /f "delims=" %%i in ('dir /b "%WinSxSPath%" /ad ^| findstr /i "!folderPattern!"') do (
if exist "%WinSxSPath%\%%i" (
echo Deleting: %%i
takeown /f "%WinSxSPath%\%%i" /r /d y >nul
icacls "%WinSxSPath%\%%i" /grant administrators:F /t >nul
rd /s /q "%WinSxSPath%\%%i"
)
)
)
)
endlocal

复制代码

wenbieba · 发表于 2024-9-5 09:11:49

holley2008 发表于 2024-9-5 09:09

谢谢，我下班回去试一下下

martin313 · 发表于 2024-9-5 09:17:37

这是在折腾 WinSxS 的精简么

louther · 发表于 2024-9-5 09:19:00

看不懂，学习下

mlgq · 发表于 2024-9-5 09:22:18

wenbieba · 发表于 2024-9-5 09:25:44

martin313 发表于 2024-9-5 09:17
这是在折腾 WinSxS 的精简么

是的，轻微精简一下

szwp · 发表于 2024-9-5 09:31:55

名单里只放一个文件练习

martin313 · 发表于 2024-9-5 09:38:15

wenbieba 发表于 2024-9-5 09:25
是的，轻微精简一下

如果是PE的话，那可以精简的狠一些，可参照骨头PE的精简法

wenbieba · 发表于 2024-9-5 11:51:52

holley2008 发表于 2024-9-5 09:09

大佬你好，刚测试闪退了

holley2008 · 发表于 2024-9-5 14:47:39

wenbieba 发表于 2024-9-5 11:51
大佬你好，刚测试闪退了

改了下，换成当前目录了，输出log日志
我win7下测试正常

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set "CurrentDir=%~dp0"
set "WinSxSPath=%SystemDrive%\Windows\WinSxS"
set "LogFile=%CurrentDir%\script_log.txt"
echo Script started at %date% %time% > "%LogFile%"
for /f "usebackq delims=" %%a in ("%CurrentDir%\ReserveWinSxS.txt") do (
set "folderPattern=%%a"
if not "!folderPattern!"=="" (
echo Processing pattern: !folderPattern! >> "%LogFile%"
for /f "delims=" %%i in ('dir /b "%WinSxSPath%" /ad ^| findstr /i /c:"!folderPattern!"') do (
if exist "%WinSxSPath%\%%i" (
echo Deleting: %%i >> "%LogFile%"
takeown /f "%WinSxSPath%\%%i" /r /d y >> "%LogFile%" 2>&1
icacls "%WinSxSPath%\%%i" /grant administrators:F /t >> "%LogFile%" 2>&1
rd /s /q "%WinSxSPath%\%%i" >> "%LogFile%" 2>&1
if %ERRORLEVEL% neq 0 (
echo Failed to delete: %%i >> "%LogFile%"
) else (
echo Successfully deleted: %%i >> "%LogFile%"
)
)
)
)
)
echo Script ended at %date% %time% >> "%LogFile%"
endlocal

复制代码

wenbieba · 发表于 2024-9-5 18:07:42

本帖最后由 wenbieba 于 2024-9-5 18:11 编辑

holley2008 发表于 2024-9-5 14:47
改了下，换成当前目录了，输出log日志
我win7下测试正常

谢谢，我测试一下，辛苦大佬了

wenbieba · 发表于 2024-9-5 22:21:26

holley2008 发表于 2024-9-5 14:47
改了下，换成当前目录了，输出log日志
我win7下测试正常

谢谢大佬，已成功

		自动登录	找回密码
密码			注册

[求助] 名单内删除不了，删除了非名单内的

点评

点评

评分

点评

点评

点评

点评

点评

点评

点评

点评