哪位能帮忙上传一个可以自动复制外置程序目录的文件

Webdiy

原来看到一个PE的安装工具，可以连外置程序一起复制的，现在找了很久没找到，用搜索搜索了几次都搜不到，搜索只能搜标题，不能搜内容，哪位下载了的话麻烦给个链接，谢谢

[ 本帖最后由 Webdiy 于 2007-1-25 03:28 PM 编辑 ]

dgxhls

下贴49楼老九元旦PE光盘版模板里有：
http://bbs.wuyou.net/forum.php?m ... page%3D2&page=4

Webdiy

非常谢谢
@Echo Off
color 0A
Set Prog=老九的 WinPE 专用安装工具
Set L1=　　　　　　　　　　　╭─────────────╮
Set L2=　　　　　　╭────┤老九的 WinPE 专用安装工具 ├────╮
Set L3=　　　　　　│　　　　╰─────────────╯　　　　│
Set L4=　　　　　　│==============================================│
Set L5=　　　　　　│ 打狗协会理事剽窃老毛桃的安装工具程序代码制作 │
Set L6=　　　　　　╰───────────────────────╯

Title %Prog%
Set RP=RP
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If %RP%==RP Goto NoSys
If Exist %RP%\PELDR Goto :EXISTPE
If Exist %RP%\AVLDR.PE Goto :EXISTPE
FIND /I "C:\AVLDR.PE" %RP%\BOOT.INI >NUL
If %Errorlevel%==0 Goto :EXISTPE
Goto Start

:EXISTPE
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo 　　　　　　│ 检测到您机器中已经安装了 WinPE，您要卸载吗？ │
Echo 　　　　　　│　[1] 卸载原有的 WinPE，并重新安装 WinPE　　　│
Echo 　　　　　　│　[2] 卸载原有的 WinPE，并删除原有的 WinPE　　│
Echo 　　　　　　│　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L4%
Echo %L5%
Echo %L6%

Echo.
Set Choice=
Set /P Choice=　　　　　　　请选择要进行的操作 (1/2/Q) ，然后按回车：
If %Choice%Choice==Choice Goto :EXISTPE
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' SET Choi=1&&GOTO :UnInstall
If /I '%Choice%'=='2' GOTO :UnInstall
If /I '%Choice%'=='Q' EXIT
Goto :EXISTPE

:UnInstall
If Exist %RP%\AVLDR.PE ATTRIB -S -H -R %RP%\AVLDR.PE && Del /Q /F %RP%\AVLDR.PE >NUL
If Exist %RP%\PELDR ATTRIB -S -H -R %RP%\PELDR && Del /Q /F %RP%\PELDR >NUL
If Exist %RP%\WINNT.SIF ATTRIB -S -H -R %RP%\WINNT.SIF && Del /Q /F %RP%\WINNT.SIF >NUL
If Exist %RP%\WINPE.IMG ATTRIB -S -H -R %RP%\WINPE.IMG && Del /Q /F %RP%\WINPE.IMG >NUL
If Exist %RP%\外置程序 RD %RP%\外置程序 /S /Q>NUL 2>NUL

Attrib %RP%\BOOT.INI -S -H -R
If Exist %RP%\BOOT.BAK (
        Attrib %RP%\BOOT.BAK -S -H -R
        TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
) Else (
        Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
        TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
)
Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL
Attrib %RP%\BOOT.INI +S +H +R
Title %Prog%——卸载完成

If %Choi%Choi==1Choi (Echo.&&Echo　　　　　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL&&Goto Start)
Echo.&&Echo　　　　　　　　卸载完成，请按任意键退出 。。。
PAUSE>NUL
Exit

:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo 　　　　　　│　[1] 安装WinPE到C盘，并添加选择项至启动菜单　│
Echo 　　　　　　│　[Q] 退出安装　　　　　　　　　　　　　　　　│
Echo %L4%
Echo %L5%
Echo %L6%

Set Choice=
Set /P Choice=　　　　　　　请选择要进行的操作 (1/Q) ，然后按回车：
If %Choice%Choice==Choice Goto Start
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' GOTO Install
If /I '%Choice%'=='q' EXIT
Goto Start

:Install
Title %Prog%——安装 WinPE
If Exist %RP%\WINNT.SIF Del /Q /F %RP%\WINNT.SIF >NUL
Echo.
Echo　　　　　　　　正在复制文件，请稍候 。。。
Copy AVLDR.PE %RP%\ /Y >NUL
Copy PELDR %RP%\ /Y >NUL
Copy WINNT.SIF %RP%\ /Y >NUL
Expand ..\WINPE.IM_ C:\WINPE.IMG >NUL
ATTRIB -S -H -R %RP%\BOOT.INI
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK
Copy %RP%\BOOT.INI %RP%\BOOT.BAK >NUL
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
Echo C:\AVLDR.PE = "老九 WinPE 后备应急系统">>%RP%\BOOT.INI
XCOPY ..\外置程序 /E %RP%\外置程序\ /Y /R>NUL 2>NUL

ATTRIB +S +H +R %RP%\BOOT.INI
ATTRIB +S +H +R %RP%\AVLDR.PE
ATTRIB +S +H +R %RP%\PELDR
ATTRIB +S +H +R %RP%\WINNT.SIF
ATTRIB +S +H +R %RP%\WINPE.IMG
ATTRIB +S +H +R %RP%\外置程序 /S /D
ATTRIB +S +H +R %RP%\外置程序\*.* /S /D
Goto :SUCCESS

:NoSys
Echo 　　　　　　　好像您的机器中没有安装操作系统哦
Echo 　　　　　　　请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE >NUL
Exit

:SUCCESS
Title %Prog%——安装完成
Echo.
Echo 　　　　　　　已经成功将镜像 WINPE.IM_ 安装到您的 %RP% 盘。
Echo.
Echo 　　　　　　　系统分区中的 BOOT.INI 备份为 BOOT.BAK。
Echo.
Echo 　　　　　　　如果您需要将外挂程序放置到非系统分区，
Echo 　　　　　　　直接将 外置程序 文件夹剪切到目标分区根目录即可
Echo.
Echo 　　　　　　　请按任意键退出 。。。
PAUSE >NUL
Exit