SystemSafetyMonitor 2.x 系列破解脚本

namejm · 发表于 2007-8-3 23:20:15

　　论坛里应该有很多人在用 System Safety Monitor 这款软件吧？虽然说有免费版可用，但是，在注册版和免费版并存的情况下，很多人潜意识里还是希望能用功能更丰富一点的注册版吧？网络上搜集了一下注册版的破解之法，发现需要动用excel和能在注册表里查找DWORD值的注册表工具(MS自带的注册表管理器不能查找DWORD值)，这也太劳师动众了。尝试着用bat做了个破解脚本，目前运行得十分良好。有兴趣的不妨测试一下。（注：System Safety Monitor 是一款对系统进行全方位监测的系统防火墙工具，它不同于传统意义上的防火墙，它针对操作系统内部的存取管理，因此与任何网络/病毒防火墙都是不相冲突的。现在，免费版本和注册版本同时并存。更多的介绍，可以google之、百度之。官方网站：http://www.syssafety.com/）

@echo off
mode con cols=75 lines=25
title System Safety Monitor 2.x 系列破解程序
setlocal enabledelayedexpansion
:: 原理：
:: 　　SSM授权信息保存在HKLM\SOFTWARE\Classes\CLSID\下
:: 　　这个CLSID值是随机生成的，每个机器的版本不一样。
:: 　　这个CLSID值只有一个默认值，是DWORD类型的数据，记录安装日期和1900/01/01之间的天数差
:: (注意：1900/01/02是1900/01/01的第二天，这个天数差就是2，而不是1，可用excel来计算)
:: 　　找到这个CLSID值以后，直接删除这个CLSID值便可(MS自带的注册表编辑器不能查找DWORD值)
:: 本程序通过计算安装文件的创建日期和1900/01/01之间的天数差来寻找CLSID值
:: 因此，请尽量在安装完程序之后立即运行本程序，以便生成正确的注册表文件
:: 当然，只要安装文件的创建日期不被篡改，任意时候运行本程序都能正确破解
:: 　　经验证，对2.2.604～2.4.0.618都有效
:: Code by JM 2007-7-9 其中，10进制转16进制的代码源于DOS联盟0401
rem ======== 计算程序安装日期是 1900-1-1 的第几天 ========
:: 提取程序安装日期
:: 因为主程序 SysSafe.exe 的创建日期是固定的，不能反映程序的安装日期
:: 所以，以卸载程序uninstSSM.exe的创建日期为准
if not exist uninstSSM.exe (
mode con cols=50 lines=8
echo.&echo.&echo 请把本程序放在SSM安装目录下运行
echo.&echo 按任意键退出...
pause>nul&exit
)
find /i "SystemSafetyMonitor 2x 破解文件" 破解文件.reg>nul 2>nul&&(
mode con cols=65 lines=8
echo.&echo.&echo 已经在当前目录下生成了破解文件，再次生成有可能导致注册表错误
echo.&echo 按任意键退出...
pause>nul&exit
)
echo.&echo 正在生成破解文件，请稍候...
for /f "tokens=1-3 delims=- " %%i in ('dir /tc uninstSSM.exe^|findstr "\-.*:"') do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100, y=%%i
)
:: 把年份转化为天数
for /l %%i in (1901,1,%sy%) do (
set /a leap="^!(%%i %% 4) & ^!(^!(%%i %% 100)) | ^!(%%i %% 400)"
set /a y_days=y_days+365+leap
)
:: 把月份转换为天数
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
set num=0
set str=31 %max% 31 30 31 30 31 31 30 31 30 31
for %%i in (%str%) do (
set /a num+=1
if !num! lss %sm% set /a m_days+=%%i
)
:: 如果安装时为闰年的话，会多算1天，所以要调整
if %leap% equ 1 (
set /a days=y_days+m_days+sd
) else set /a days=y_days+m_days+sd+1
rem ======== 把天数转化为16进制的注册表REG_DWORD值 ========
set d=0
for %%i in (0 1 2 3 4 5 6 7 8 9 A B C D E F) do (
set d!d!=%%i
set/a d+=1
)
set scanf=%days%
:d2h
set/a tscanf=%scanf%"&"15
set/a scanf">>="4
set hex=!d%tscanf%!!hex!
if %scanf% neq 0 goto d2h
echo.&echo ====================================================================
echo 破解原理：
echo.&echo 删除HKLM\SOFTWARE\Classes\CLSID\下DWORD值^(16进制^)为
echo 安装日期与 1900-1-1 天数差的注册表项，
echo 每删除一次，就可以再延期30天。
echo ====================================================================
echo 经过分析，SSM安装日期为 %sy%-%sm%-%sd%
echo 是 1900-1-1 的第 %days% 天
echo %days% 的 16 进制值为 0x%hex%
rem ======== 删除REG_DWORD值为 0x%hex% 的注册表项 ========
:: 之所以不写入临时文件夹，是为了避免在for语句中使用 usebackq 带来麻烦
reg query HKLM\SOFTWARE\Classes\CLSID /s 2>nul >c:\list.txt
for /f "delims=:" %%i in ('findstr /enirc:"REG_DW0x%hex%" c:\list.txt') do set /a line=%%i-2
:: 当用本脚本生成的reg破解SSM之后，若reg文件不慎丢失,
:: 再次生成破解文件将不能准确定位要破解的注册表项
if not defined line (
echo.&echo 无法定位破解项，重新安装SSM后可能会得到解决
echo 按任意键退出...
del /q c:\list.txt
pause>nul
exit
)
for /f "skip=%line% delims=" %%i in (c:\list.txt) do (
(
echo Windows Registry Editor Version 5.00
echo.&echo ; 本reg文件是 SystemSafetyMonitor 2x 破解文件
echo ; 每删除以下键值一次，就可以在当前日期的基础上再延长30天使用期限
echo ; 理论上，可以无限期延长授权期限
echo ; 注意：此破解文件只适用于当前机器！
echo.&echo [-%%i]
)>破解文件.reg
echo ====================================================================
echo 已经在当前目录下生成：破解文件.reg
echo 每导入一次该注册表文件即可延长30天的使用期限
echo ====================================================================
echo 注意：
echo.&echo ① 此破解文件只适用于当前机器；
echo ② 当用reg文件破解之后，再运行本程序生成的破解文件将会删除错误的
echo 键值，请勿在破解之后再次生成破解文件；
echo.&echo 按任意键退出...
del /q c:\list.txt
pause>nul&exit
)

复制代码

netwinxp · 发表于 2007-8-3 23:26:25

我一般都用裸奔，有空可以试用看看

namejm · 发表于 2007-8-11 18:37:07

　　这个帖子发了那么久，一直没见什么评价，先顶上来再说——看来，用SSM的人还很少啊。

netwinxp · 发表于 2007-8-12 12:25:03

监控、防火墙之类的软件我一般都不用，不过还是顶一把，看有没有人对此有兴趣。

sunkiss · 发表于 2007-8-12 12:57:13

提示: 作者被禁止或删除内容自动屏蔽

whsand · 发表于 2007-12-19 23:08:08

下了，试了一下，很好用，真谢谢楼主。

willsion · 发表于 2007-12-21 09:52:04

看楼主介绍似乎不错。先收藏，防火墙一直使用的是ZA，这个暂时不用。

xianren8222 · 发表于 2008-1-12 20:14:11

呵呵！楼主是炫耀技术，很多年前的喜欢这样干，现在只用诺顿企业版，不用去维护完全傻瓜式的省心省力。只是在万一遇上不知名难以清除的程序才用它隔离一下，用冰刀之类的工具解决一下。觉得楼主纯粹吃饱了撑得！

namejm · 发表于 2008-1-13 13:13:24

　　xianren8222 看来还不怎么了解杀毒软件和系统防火墙之间的差别。没有调查就没有发言权，请不要随意攻击他人吃饱了。至于是否是炫耀技术，留给大家来评判吧。

sanhu35 · 发表于 2008-1-15 20:02:47

我用SSM 已经打了破解补丁不好试等到期了再试下!

		自动登录	找回密码
密码			注册

sunkiss sunkiss 当前离线积分 2402 IP卡狗仔卡	5^# 发表于 2007-8-12 12:57:13 \| 只看该作者提示: 作者被禁止或删除内容自动屏蔽
sunkiss sunkiss 当前离线积分 2402 IP卡狗仔卡
	回复使用道具举报显身卡

SystemSafetyMonitor 2.x 系列破解脚本

回复 #1 namejm 的帖子