添加pe到硬盘

hilsonma · 发表于 2025-3-10 13:49:10

分享一个批处理：添加pe到硬盘

@echo off
title 添加PE到硬盘
setlocal ENABLEDELAYEDEXPANSION
if %1.==. (set src=pe\boot.wim) else set src=%1
set drv=c
pushd %~dp0
:do
cls
echo.
echo 即将把 %src% 复制到 %drv%:\pe.wim 并添加引导
echo.
echo 1.确认执行 2.修改目标盘符 3.退出
echo.
set n=1
set /p n=请输入选项并回车：
goto:do%n%
:do2
echo.&set /p drv=请输入PE添加到的盘符：
goto:do
:do1
if exist s: mountvol s: /d
mountvol s: /s && (call :uefi) || call :bios
call :chksdi
call :chkwim
call :bcd
echo 请按任意键结束...
pause>nul
exit
:uefi
set bd=s
set sdi=\EFI\boot.sdi
exit /b
:bios
set bd=c
set sdi=\boot\boot.sdi
exit /b
:chksdi
if not exist %bd%:%sdi% (
if exist C:\Windows\Boot\DVD\EFI\boot.sdi (
set sdi1=C:\Windows\Boot\DVD\EFI\boot.sdi
) else (
if exist pe\boot.sdi (
set sdi1=pe\boot.sdi
) else (
echo.&set /p sdi1=请将boot.sdi文件拖放到本窗口后按回车键：
)
)
copy !sdi1! %bd%:%sdi%
)
exit /b
:chkwim
if not exist %drv%:\pe.wim (
if exist %src% (
set wim=%src%
) else (
echo.&set /p wim=请将pe的wim文件拖放到本窗口后按回车键：
)
echo 复制 !wim! 到 %drv%:\pe.wim
copy !wim! %drv%:\pe.wim
)
exit /b
:bcd
if not exist %drv%:\pe.wim goto:error
if not exist %bd%:%sdi% goto:error
echo 添加菜单引导项
set desc="Win PE"
set wim=[%drv%:]\pe.wim
for /f "tokens=2 delims={}" %%a in ('bcdedit /create /application osloader') do set id={%%a}
bcdedit /set %id% description %desc%
bcdedit /set %id% device ramdisk="%wim%,{ramdiskoptions}"
bcdedit /set %id% osdevice ramdisk="%wim%,{ramdiskoptions}"
bcdedit /set %id% systemroot \Windows
bcdedit /set %id% detecthal 1
bcdedit /set %id% winpe 1
bcdedit /displayorder %id% /addlast
bcdedit /timeout 3
bcdedit /set {bootmgr} displaybootmenu 1
bcdedit /set {bootmgr} nointegritychecks 1
bcdedit /create {ramdiskoptions}
bcdedit /set {ramdiskoptions} ramdisksdidevice boot
bcdedit /set {ramdiskoptions} ramdisksdipath %sdi%
exit /b
:error
::cls
echo.
echo 复制文件失败，请手动复制文件 pe.wim 和 boot.sdi 到 %drv%:\pe.wim 和 %bd%:%sdi% 后按任意键继续...
pause>nul
goto:bcd

复制代码

添加PE到硬盘.7z (1.05 KB, 下载次数: 128)

handsome_xiang · 发表于 2025-3-10 13:58:30

谢谢共享！

youxia1220 · 发表于 2025-3-10 15:00:09

谢谢分享

it323 · 发表于 2025-3-10 15:10:38

感谢分享！

122996388 · 发表于 2025-3-10 15:13:04

怎么使用的？？

yc2428 · 发表于 2025-3-10 15:13:29

谢谢分享

小灰兔 · 发表于 2025-3-10 15:19:04

感谢楼主分享

wwwlhp · 发表于 2025-3-10 15:26:04

多谢楼主分享！！！

y迎旭 · 发表于 2025-3-10 15:53:58

感谢分享！

yzydys · 发表于 2025-3-10 16:37:18

下载试用，谢谢分享。

2010sya · 发表于 2025-3-10 16:38:56

122996388 发表于 2025-3-10 15:13
怎么使用的？？

应该是“pe\boot.wim”这个位置就可以。。。

hilsonma · 发表于 2025-3-10 16:45:21

本帖最后由 hilsonma 于 2025-3-10 21:21 编辑

2010sya 发表于 2025-3-10 16:38
应该是“pe\boot.wim”这个位置就可以。。。

不是
我这个批本来自身文件夹中还有个pe文件夹，里面有boot.wim，所以就默认了这样的wim文件
如果批所在文件夹中没有 pe\boot.wim 会提示拖放一个别的wim文件来进行的，什么位置的都可以，只要找到wim文件拖放到批处理窗口，在批处理窗口按Enter键就可以了，批脚本会将它复制成 c:\pe.wim 然后添加菜单项
请参考第4行和第57-63行

如果不想将pe.wim放在c盘，就可以选2修改成别的盘，比如efi分区或d盘等。
之所以默认c盘是因为c盘比较容易成功，不用担心efi分区没有足够空间，也不用担心d盘是逻辑分区出现启动问题。
如果efi分区空间够的话我建议放在efi分区。

进士小站 · 发表于 2025-3-10 17:01:48

感谢分享收下了

2011lanz · 发表于 2025-3-10 17:05:48

收下了，谢谢大佬分享！

jh198354 · 发表于 2025-3-10 17:20:43

谢谢分享！！！

jho · 发表于 2025-3-10 17:23:23

感谢分享！！！

jnwin123 · 发表于 2025-3-10 17:31:46

本帖最后由 jnwin123 于 2025-3-10 17:32 编辑

用工具右右键直接安装PE到本地硬盘更简单

Jcz777 · 发表于 2025-3-10 18:16:22

WIT挂pe挺方便的。

少马石 · 发表于 2025-3-10 18:16:49

大佬能不能做个gui界面的，方便操作

abxy · 发表于 2025-3-10 19:10:25

谢谢分享！！

hilsonma · 发表于 2025-3-10 19:37:45

少马石发表于 2025-3-10 18:16
大佬能不能做个gui界面的，方便操作

我不懂做gui界面。

lyrgcy · 发表于 2025-3-10 20:09:43

微PE那个安装好，可以设置密码,我都是安装了，再替换PE文件

wjzj · 发表于 2025-3-10 20:35:56

这贴也要收藏，感谢分享。

2010zihan · 发表于 2025-3-10 22:01:26

必要时很有用。

呆萌鼠 · 发表于 2025-3-11 08:22:23

非常不错，十分感谢分享！

wang1126 · 发表于 2025-3-11 08:50:25

谢谢楼主分享

yzydys · 发表于 2025-3-12 15:47:06

给力！感谢楼主分享

l191128 · 发表于 2025-3-12 16:03:19

感谢分享

hilsonma · 发表于 2025-3-13 11:05:39

本帖最后由 hilsonma 于 2025-3-13 11:06 编辑

122996388 发表于 2025-3-10 15:13
怎么使用的？？

将想要添加的pe的wim文件拖放到批处理上来执行
批处理会将这个wim文件复制成 c:\pe.wim 并添加启动项到bcd菜单

默认第1个选项，直接按Enter键不需要输入1就会执行
如果不想放到c盘而想放到其他盘，就选2来修改盘符放到其他盘

fegr · 发表于 2025-3-13 15:07:34

谢谢分享

		自动登录	找回密码
密码			注册

[分享] 添加pe到硬盘

点评

点评

点评

点评