禁止ATI自启动

cuicongyuan

用的 wimboot 大大（他在本坛有另外一个ID，忘了）PE，我用ATI2018替换这个 PE 的 ATI2017new 后，ATI 自启动。
PE 里有个“配置.bat”。
问题：如何在“配置.bat”里修改或添加指令，禁止ATI自启动？

cuicongyuan

原 PE 里的 “配置.bat” ：

@echo off
call :link "osk.exe %Programs%\附件工具\屏幕键盘"
call :link "diskmgmt.msc %Programs%\管理工具\磁盘管理"
call :link "devmgmt.msc %Programs%\管理工具\设备管理器"
call :link "pecmd.exe %Programs%\重启桌面,pecmd.exe,kill explorer.exe"
call :link "Imdisk.cpl %Programs%\虚拟磁盘\Imdisk,control.exe,Imdisk.cpl"
call :link "7zFM.exe %Programs%\解压软件\7-Zip"
call :link "Notepad2.exe %Programs%\文字处理\Notepad2" "Notepad2.exe %QuickLaunch%\User Pinned\StartMenu\Notepad2"
call :link "PENetwork.exe %Programs%\网络连接\PENetwork" "PENetwork.exe %QuickLaunch%\User Pinned\StartMenu\PENetwork"
call :link "chrome.exe %Programs%\网络浏览\Chrome"
call :link "ThunderMini.exe %Programs%\网络下载\ThunderMini"
call :link "TrueImage.exe %Programs%\备份还原\ATI" "TrueImage.exe %Desktop%\ATI"
call :link "imagew64.exe %Programs%\备份还原\Image for Windows" "imagew64.exe %Desktop%\Image for Windows"
call :link "CGI.ico %Programs%\备份还原\CGI,%~dp0CGI\CGI.wcz," "CGI.ico %Desktop%\CGI,%~dp0CGI\CGI.wcz,"
call :link "Ghost64.exe %Programs%\备份还原\Ghost" "Ghost64.exe %Desktop%\Ghost"
call :link "DiskGenius.exe %Programs%\磁盘分区\DiskGenius" "DiskGenius.exe %Desktop%\DiskGenius"
call :link "PartAssist.exe %Programs%\磁盘分区\PartAssist" "PartAssist.exe %Desktop%\PartAssist"
call :link "Booticex64.exe %Programs%\磁盘分区\Bootice" "Booticex64.exe %Desktop%\Bootice"
call :link "HDTunePro.exe %Programs%\设备检测\HDTunePro" "HDTunePro.exe %Desktop%\HDTunePro"
call :link "DisplayX.exe %Programs%\设备检测\DisplayX" "DisplayX.exe %Desktop%\DisplayX"
call :link "GImageX.exe %Programs%\镜像处理\GImageX" "GImageX.exe %Desktop%\GImageX"
call :link "WinSnap.exe %Programs%\图像处理\WinSnap"
call :link "Imagine64.exe %Programs%\图像处理\Imagine"
call :link "WinNTSetup_x64.exe %Programs%\系统安装\WinNTSetup" "WinNTSetup_x64.exe %Desktop%\WinNTSetup"
call :link "RegWorkshop.exe %Programs%\系统修改\RegWorkshop" "RegWorkshop.exe %Desktop%\RegWorkshop"
call :link "Ntbootautofix.exe %Programs%\系统修改\Ntbootautofix" "Ntbootautofix.exe %Desktop%\Ntbootautofix"
call :link "NTPWEdit.exe %Programs%\系统修改\NTPWEdit" "NTPWEdit.exe %Desktop%\NTPWEdit"
call :link "Dism++x64.exe %Programs%\系统优化\Dism++" "Dism++x64.exe %Desktop%\Dism++"
call :hotk "Winsnap.exe F11"
for /f %%a in ('mountvol ^| find ":\"') do (
    for %%b in ("%%aSources\*64*.iso" "%%aSources\PE*64*.wim") do (start pecmd.exe link "%Desktop%\%%~nb","%%~b")
    for /d %%b in ("%%aSources\*64*") do (
        for %%c in ("%%~b\*.reg") do (start regedit.exe /s "%%~c")
        for %%c in ("%%~b\*.ini") do (start pecmd.exe load "%%~c")
        for %%c in ("%%~b\*.cmd" "%%~b\*.bat") do (start pecmd.exe exec !"%%~c")
        for %%c in ("%%~b\*.7z") do ("%~dp07-Zip\7z.exe" x "%%~c" -y -o"%~dp0")
        for %%c in ("%%~b\*.wim") do (pecmd.exe exec !"%~dp0操作.bat" "%%~c")
    )
)
for %%a in ("%~dp0*.reg" "%~dp0*.ini" "%~dp0*.cmd" "%~dp0*.bat") do (if not "%%~fa"=="%~0" call :exec "%%~a")
call :exec install.reg install.bat "Imagine64.exe /assocext /regcontextmenu"
call :pint chrome.exe ThunderMini.exe osk.exe
for %%a in ("%Programs%" "%Programs%\Administrative Tools" "%Programs%\StartUp") do (if exist %%a attrib.exe +h %%a)
exit
:link
:pint
:hotk
:exec
for %%a in (%*) do (
    if exist "%%~a" (
        call %0start "%%~a"
    ) else for /f "tokens=1*" %%b in ("%%~a") do (
        if exist "%%~b" (
            call %0start "%%~b" "%%~c"
        ) else for /r "%~dp0" %%i in (%%b) do (
            if exist "%%~i" (
                call %0start "%%~i" "%%~c"
            )
        )
    )
)
goto :eof

:linkstart
start PECMD.EXE LINK %~2,%1
goto :eof

:pintstart
if not exist "%Temp%\explorer.exe" copy /y pecmd.exe "%Temp%\explorer.exe"
"%Temp%\explorer.exe" PINT %1,TaskBand
if exist "%Temp%\explorer.exe" del /q "%Temp%\explorer.exe"
goto :eof

:hotkstart
start PECMD.EXE HOTK %~2,%1
goto :eof

:execstart
if "%~x1"==".reg" (
    start regedit.exe /s %1
) else if "%~x1"==".inf" (
    start PECMD.EXE DEVI %1
) else if "%~x1"==".ini" (
    start PECMD.EXE LOAD %1
) else (
    start PECMD.EXE EXEC !%1 %~2
)
goto :eof

cuicongyuan

ATI 与下面两条指令有关（上面整行、下面一行里的 install.bat ）：

call :link "TrueImage.exe %Programs%\备份还原\ATI" "TrueImage.exe %Desktop%\ATI"

call :exec install.reg install.bat "Imagine64.exe /assocext /regcontextmenu"

cuicongyuan

补充：原 PE 里的 ATI2017new 不自启动，更换成 ATI2018 后，就自启动。

cbl

cuicongyuan

更正：ATI2018写错了，是ATI2020。
接着补充：
1.原PE里面ATI2017new的文件夹“TrueImage”里的“TrueImage.exe”和“install.bat”两个文件与“配置.bat”指令有关；
2.我把ATI2020的文件夹“TrueImage”里的“TrueImage.bat”文件名改为“install.bat”。
3.删除ATI2017new的文件夹“TrueImage”，把ATI2020的文件夹“TrueImage”替换到PE原位置；
4.“配置.bat”里面的指令没有修改；
5.重新打包。
然后启动到PE，就出现了ATI自启动（原PE的ATI不会出现自启动）。

红毛樱木

cuicongyuan 发表于 2020-3-3 00:05
更正：ATI2018写错了，是ATI2020。
接着补充：
1.原PE里面ATI2017new的文件夹“TrueImage”里的“TrueIma ...

TrueImage.bat

cuicongyuan

红毛樱木 发表于 2020-3-3 00:39
TrueImage.bat

谢谢 红毛樱木 大大！

cuicongyuan

接着补充：
ATI2020 是从其它的 PE 里提取的，在提取的 PE 里不会自启动。

cuicongyuan

已解决：
1. ATI2020的文件夹“TrueImage”里的“TrueImage.bat”文件名保持原文件名不变；
2. “配置.bat”里面的指令不变，只是添加一行指令：call :exec "TrueImage.bat /i"
成功，ATI2020不会自启动。

cuicongyuan

顺便请教坛友们：帖子标题可以修改吗？怎样修改？

狼人72105

kill 杀

lisd70

看看讨论还学到了修改方法

2011goodluckwxl

谢谢，非常不错，我很喜欢这个