TinyPXE的缺点与PXE网启服务器推荐

as8686886 · 发表于 2025-2-17 10:11:03

试试这个很好用 MyWebServer 3.8.40 我是pxesrv1.0.0.23cn搭配他非常稳定网络挂载ISO速度也杠杠的

as8686886 · 发表于 2025-2-18 09:38:42

mygamexxx 发表于 2025-2-17 12:40
搞好了，是IP地址的问题。但还是与其他HTTP服务器有区别，出错。应该是MYWEBSERVER的原因（估计它对压缩文 ...

用批处理生成的配置文件你可以参考我的使用起来没一点问题

@echo off
title PXE网络启动系统配置文件生成器
color 2f
setlocal EnableDelayedExpansion
mode con: cols=80 lines=30
echo.&echo PXE网络启动Tiny PXE Server配置文件生成器 By:as8686886
echo.&echo 使用说明：1、此工具仅用于本工具本机首次使用
echo 2、再次使用直接执行pxesrv1.0.0.23cn.exe即可
echo 3、客户机PXE脚本无法运行请使用BAK目录menu.txt文件启动
:main
set n=0
echo.&echo 查询到本机有如下IP地址：
for /f "tokens=16" %%i in ('ipconfig ^|find /i "ipv4"') do (
set /a n=n+1
echo !n!. %%i
)
Set /p c=请选择要使用的IP地址:
if "%c%"=="" goto main
set n=0
for /f "tokens=16" %%i in ('ipconfig ^|find /i "ipv4"') do (
set /a n=n+1
if "%c%"=="!n!" (
set pxeip=%%i
)
)
echo.&echo 你选择的IP是：%pxeip%
echo.
set servername=%COMPUTERNAME%
set /P PASSWORD=请输入当前用户%USERNAME%的密码(客户端共享使用):
REG DELETE HKLM\SOFTWARE\WOW6432Node\iptools /f>nul 2>nul
Reg add "HKLM\SOFTWARE\WOW6432Node\iptools\pxeserver\txtaltfilename" /v "H0" /t REG_SZ /d "boot/menu.txt" /f>nul 2>nul
Reg add "HKLM\SOFTWARE\WOW6432Node\iptools\pxeserver\txtaltfilename" /v "H1" /t REG_SZ /d "BAK/menu.txt" /f>nul 2>nul
echo.&echo 设置本目录下PXE文件夹为共享文件夹……
MD PXE>nul 2>nul
net share PXE /delete /y>nul 2>nul
echo Y|cacls %~dp0PXE /t /p everyone:f>nul 2>nul
REM echo Y|cacls %~dp0\PXE\*.* /t /p everyone:f>nul 2>nul
net share PXE=%~dp0PXE /GRANT:Everyone,FULL>nul 2>nul
Taskkill /im TightVNC远程控制.exe /f /T>nul 2>nul
Taskkill /im pxesrv1.0.0.23cn.exe /f /T>nul 2>nul
taskkill /im MyWebServer.exe /f /T>nul 2>nul
echo.&echo 生成Tiny PXE Server配置文件……
(
echo [arch]
echo 00002=EFI\boot\bootia32.efi
echo 00006=EFI\boot\bootia32.efi
echo 00007=EFI\boot\bootx64.efi
echo 00009=EFI\boot\bootx64.efi
echo [dhcp]
echo root=%CD%\
echo filename=ipxe.pxe
echo altfilename=boot/menu.txt
echo ;altfilename=BAK/menu.txt
echo optextra=175.6.1.1.1.8.1.1
echo httpd=0
echo binl=0
echo start=1
echo tftpd=1
echo proxydhcp=1
echo bind=1
echo smb=0
echo log=0
echo ;opt1=
echo opt3=0.0.0.0
echo opt6=0.0.0.0
echo ;opt28=
echo ;opt15=
echo ;opt17=
echo ;opt54=
echo ;opt67=
echo ;opt66=
echo ;opt43=
echo ;opt252=
echo ;poolstart=
echo host_name=%COMPUTERNAME%
echo share_name=PXE
echo share_username=%USERNAME%
echo share_password=%PASSWORD%
echo poolsize=50
echo dnsd=0
echo opt43=1
echo opt51=3600
echo opt60=PXEClient
echo ;cmd=_test.bat
echo online=_online.cmd
echo offline=_offline.cmd
echo opt54=%pxeip%
echo next-server=%pxeip%
echo opt66=%pxeip%
echo syslog=127.0.0.1
)>%~dp0config.ini
echo.&echo 生成WebServer配置文件……
(
echo [site_0]
echo siteid=0
echo filelist=1
REM echo gziptmpdir=gziptmp
echo http=1
echo SERVERPORT=80
echo sitename=PXE_Server
echo SERVERIP=%pxeip%
echo enableasp=1
echo gzip=0
echo serverpath=%CD%
echo [option]
REM echo gziptmpdir=gziptmp
echo gxh=1
echo autostart=1
echo isapibufsize=64
echo sendtimeout=18000
echo keepconntime=30
echo savelog=0
echo autorun=0
echo logpath=log
echo threadpoolsize=6
echo update=0
echo upflag=1
echo enableconnect=0
echo maxmem=1024
)>%~dp0WebServer\server.ini
echo.&echo 配置文件生成完毕！3秒后自动退出！
echo.&timeout /t 3 /nobreak >nul

复制代码

as8686886 · 发表于 2025-2-18 14:53:04

mygamexxx 发表于 2025-2-18 12:40
看了一下批处理filename=ipxe.pxe，PXE引导文件为ipxe.pxe，使用这个引导文件是没问题的。只有用G4E目前 ...

G4E我没研究，我自己改的目前 GPT和MBR都能用也够用了

		自动登录	找回密码
密码			注册

[分享] TinyPXE的缺点与PXE网启服务器推荐

点评

点评