怎么取字符串中的一部分?

cjzzz

如:    下面的字符串.   
MSHist012006062420060625

我要取得  后面的部分 2006062420060625

有办法吗?

cjzzz

晕..  都没人帮我 ,

自己找到办法了.   


set var=MSHist012006062420060625
echo %var:~8%

cjzzz

set histpath=D:\History
set histreg=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\5.0\Cache\Extensible Cache

dir /a:d /b "%histpath%\History.IE5" > %temp%\Mshist01.txt

for /f %%i in (%temp%\Mshist01.txt) do (
  reg add "%histreg%\%%i" /v CacheLimit /t REG_DWORD /d 8192 /f >nul
  reg add "%histreg%\%%i" /v CacheOptions /t REG_DWORD /d 11 /f >nul
  reg add "%histreg%\%%i" /v CacheRepair /t REG_DWORD /d 0 /f >nul
  reg add "%histreg%\%%i" /v CachePath /t REG_EXPAND_SZ /d %histpath%\History.IE5\%%i\ /f >nul

  set cpfix=%%i
  if "%cpfix%" == "" echo 怎么会不见了???

  rem reg add "%histreg%\%%i" /v CachePrefix /t REG_SZ /d ":%cpfix:~8,16%: " /f >nul

)

set cpfix=
set histreg=
set histpath=

  set cpfix=%%i
  if "%cpfix%" == "" echo 怎么会不见了???

  这变量怎么没有了?

namejm

　　当在for语句中用set cpfix=%%i语句之后，如果要引用变量cpfix，就得启用变量延迟，要修改的地方有两处：

　　1.在for语句之前加上语句setlocal enabledelayedexpansion；
　　2.把if "%cpfix%" == "" 改为if "!cpfix!" == ""