四、“WIM编辑助手.CMD”的内容如下：
@echo off
PUSHD %~dp0 &SET TP=%~dp0
if not exist imagex.exe color 4f&echo 检查当前文件夹中有无Imagex工具....&goto stop
title 修改WIM文件生成ISO文件工具
cls &echo.&echo 【%~n0%】使用说明
echo ==================================================
echo.&echo ★备份系统
echo 运行【%~nx0%】，输入备份盘符和保存盘符。
echo 以WIM格式备份指定盘的Windows系统(PE中)。
echo.&echo ★生成WIM文件
echo 将【文件夹】拖到【%~nx0%】文件上。
echo 直接将该文件夹打包成WIM文件。
echo.&
echo ★解压WIM文件或生成ISO文件
echo 将【*.wim】文件拖到【%~nx0%】文件上。
echo 选择[1]将*.wim文件解压到*-load文件夹中。
echo 选择[2]根据*.wim文件生成ISO文件。
echo.&echo ==================================================
if "%~n1"=="" goto :bakwim
rem 判断是文件夹还是文件
Set dirfull=%~1
cd /d "%dirfull%" 2>nul&&set DirF=1 ||set DirF=0
cd /d "%TP%"
if "%DirF%"=="1" goto makewim
if not "%DirF%"=="0" goto makewim
if /i not "%~x1"==".wim" color 4f&echo 本工具只可以编辑.WIM文件,而不是%~x1文件....&goto stop
echo 功能选择: 1--解压.wim文件
echo 2--生成.iso文件 q--退出
echo ==================================================
echo. & set /p cice= 请输入选择(1,2,q,默认:1)
if /i "%cice%"=="2" goto makeiso
if /i "%cice%"=="q" exit /b
rem 解压WIM文件
set cho=
echo. & set /p cho= 请输入盘符(如D:等，默认%~dpn1-load)：
if /i "%Cho%"=="q" exit /b
IF NOT "%Cho%"=="" SET Cho=%Cho:~0,2%
IF "%Cho%"=="" SET Cho=%~dpn1-load
if not exist "%Cho%" SET Cho=%~dpn1-load
if /i "%Cho%\"=="%~dpn1-load\" (if exist "%~dpn1-load\" rd /s /q "%~dpn1-load\"
md "%~dpn1-load" )
echo 正在解开 %~dpnx1 到 %Cho% 文件夹
imagex /apply "%~dpnx1" 1 "%Cho%"
echo %~dpnx1 成功解压%Cho%\文件夹&goto stop
:makeiso
if exist iso\bootmgr (if exist iso\boot\bcd (
if exist iso\boot\boot.sdi (if exist iso\boot\etfsboot.com (if exist iso\boot\oscdimg.exe (set ervtst2=1)))))
if not "%ervtst2%"=="1" color 4f&echo 运行环境检测失败，请检查有无ISO文件夹....&goto stop
copy /b /y "%~dpnx1" iso\boot\boot.wim >nul
"%tp%\iso\boot\oscdimg.exe" -b"%tp%\iso\boot\etfsboot.com" -h -n -m -o -lwin7pe -t10/12/2014,10:00:00 "%tp%\iso" "%~dpn1.ISO"
del /q /f iso\boot\boot.wim >nul
echo 已经完成 %~dpn1.iso 的制作&goto stop
:makewim
echo 正在最大压缩打包 %~dpnx1 为 %~dpnx1.wim (添加可启动标记).....
imagex /capture "%~dnpx1" "%~dnpx1.WIM" "PE内核文件" "Win7PE By tlj" /compress Maximum /boot /verify
echo 可启动 %~dpnx1.wim 文件制作成功&goto stop
:bakwim
echo.&set /p cc= 确定要备份系统(Y/N,默认N)：
if /i not "%cc%"=="y" exit
set cc=
echo.&set /p cc= 请输入备份盘符(默认C:)：
IF NOT "%cc%"=="" SET cc=%cc:~0,2%\
IF "%cc%"=="" SET cc=C:\
set dd=
echo.&set /p dd= 请输入保存盘符(默认D:)：
IF NOT "%dd%"=="" SET dd=%dd:~0,2%\
IF "%dd%"=="" SET dd=D:\
IF /i "%cc%"=="%dd%" echo.&echo 备份盘与保存盘不能同盘!!!&goto bakwim
set tt=%~T0%
set dd=%dd%%tt:~0,10%%cc:~0,1%.wim
echo.&set /p dd= 确定要备份%cc%盘,保存为%dd%
imagex /capture %cc% %dd% "PE内核文件" "Win7PE By tlj" /compress Maximum /boot /verify
echo 可启动 %dd% 文件制作成功
:stop
set actp=%systemroot:~0,1%
if /i not "%actp%"=="x" ping -n 5 127.0.0.1 >nul &exit /b
echo.&set /p aa= 按任意意退出...
exit /b
