|
|
11-05 建议看“新版“Vista启动项中安装与卸载grub4dos项目的批处理”【10-22更新】
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=112291&highlight= ”
已包括此帖安装部分内容，且有卸载。
10-22 更新
－－－－－－－－－－－－－－－－－－－－－－－
把grub4dos装入Vista启动项（非MBR）的批处理。
把grub4dos装入Vista启动项，比装入MBR相对来说要安全。对于vista系统，不能通过fdisk /mbr来恢复mbr，这样会造成vista无法启动。
关于手动把grub4dos装入Vista的启动项的方法，网上有一些介绍。比起winxp修改Boot.ini来，操作要麻烦不少。
主要就是操作过程中要产生一个ID号【形式如:b88a2da4-0a4e-11dc-813a-00e04c75ef59】,需要手动输入3次，实在是麻烦。因此看到手动操作的方法后，由于不适合自动处理，也就没想在gghost里加入装入vista启动项的选项，对vista系统只是采用装入MBR的办法。过了好长时间，也没见到网上有自动安装的办法。于是就想能不能用批处理来自动完成整个装入操作。看了批处理就知道，只要想到了，处理起来其实很简单，没有任何技术含量。
下面的批处理是从本人的“GGhost备份恢复工具”中简化而来的，自动完成。供需要者参考。
=========================================
@echo off
rem by lianjiang
cls
echo.
echo 请以管理员身份运行。
echo.
pause
set gname=GRUB for DOS
set vid=
set timeout=5
bcdedit >bcdtemp.txt
type bcdtemp.txt | find "\grldr.mbr" >nul && echo. && echo BCD启动项中已有grub4dos的项目，无需再安装。&& pause && goto exit
bcdedit /export "Bcd_Backup" >nul
bcdedit /create /d "%gname%" /application bootsector >vid.ini
for,/f,"tokens=2 delims={",%%i,In (vid.ini) Do (
set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,In ("%vida%") Do (
set vid={%%i}
)
echo %vid%>vid.ini
bcdedit /set %vid% device partition=%systemdrive% >nul
bcdedit /set %vid% path \grldr.mbr >nul
bcdedit /displayorder %vid% /addlast >nul
bcdedit /timeout %timeout% >nul
if exist grldr.mbr copy grldr.mbr %systemdrive%\ /y && goto exit
echo.
echo 稍后请自行把grldr.mbr拷贝到%systemdrive%\根目录
echo.
pause
:exit
del bcdtemp.txt >nul
=========================================
参考资料：
利用NT的启动管理器引导GRLDR.MBR （时空论坛bean）
经过适当的修改，GRLDR.MBR可以直接由NT的启动管理器来引导，
在2000/XP/2003下，在boot.ini的最后加上一行：
C:\GRLDR.MBR="Boot GRLDR.MBR"
在Vista下，可以使用bcdedit，方法在fujianabc的贴子里有介绍，摘录如下:
md a:\boot 创建a:\boot文件夹
bcdedit /createstore a:\boot\bcd 新建一个bcd文件
bcdedit /store a:\boot\bcd -create {bootmgr} /d "Boot Manager" 新建一个用bootmgr加载的启动项
bcdedit /store a:\boot\bcd /create /d "bootsect" /application bootsector 此项目用bootmgr加载一个bootsector项
执行上面命令后返回一个{ID}，然后执行
bcdedit /store a:\boot\bcd /set {ID} device boot 设置启动设备
bcdedit /store a:\boot\bcd /set {ID} path \grldr.mbr 设置启动扇区路径和文件名
bcdedit /store a:\boot\bcd /displayorder {ID} /addlast 加入以上设置项目
当然，你还需要把附件中的grldr.mbr文件拷贝到C:\下。
如果引导正常，GRLDR.MBR运行，它会在硬盘上所有的FAT16/FAT32/NTFS/EXT2分区的根目录寻找并
装载GRLDR，其效果就和把GRLDR.MBR安装到MBR里一样。
[ 本帖最后由 lianjiang 于 2009-11-17 08:40 编辑 ] |
|
IP卡
狗仔卡
发表于 2007-5-24 20:48:42
收藏
支持
反对
提升卡
沉默卡
喧嚣卡
变色卡
千斤顶
显身卡
楼主
