无忧启动论坛

 找回密码
 注册
搜索
系统gho:最纯净好用系统下载站广告联系 微信:wuyouceo QQ:184822951
查看: 1730|回复: 4
打印 上一主题 下一主题

[已解决]请求老九大侠能否将你的xpehelp.exe写成批处理的形式!

[复制链接]
跳转到指定楼层
1#
发表于 2007-12-30 11:55:47 | 只看该作者 回帖奖励 |正序浏览 |阅读模式
如题,请求老九大侠能否将你的xpehelp.exe写成批处理的形式!
主要是安装pe和卸载pe的程式,说明文档就不用了。
因为我想用批处理安装和卸载.im_格式的硬盘pe,先谢谢了,祝大家新年快乐!

[ 本帖最后由 火焙鱼 于 2007-12-30 11:56 PM 编辑 ]
5#
 楼主| 发表于 2007-12-30 19:59:44 | 只看该作者
原帖由 lxl1638 于 2007-12-30 12:37 PM 发表
老毛桃有,你找他。
但说明,用CMD来处理BOOT.INI文件容易出错,特别是设置了属性和权限的BOOT.INI等文件。

谢谢老九大侠的指点,不过在fat32分区中,应该就没什么权限吧,我硬盘全是fat32的。
如果是ntfs格式是不是要允许当前帐户有修改boot.ini的权限?
回复

使用道具 举报

4#
 楼主| 发表于 2007-12-30 19:46:37 | 只看该作者
感谢兄弟mackyliu (风流才子) !
俺搜到你的帖子http://bbs.wuyou.net/forum.php?mod=viewthread&tid=90474
最喜欢那个不复制外置程序的安装程式,非常感谢!
回复

使用道具 举报

3#
发表于 2007-12-30 15:06:22 | 只看该作者
本人不是写过了吗?
@Echo Off
color 0A
Set Prog=老九的 WinPE 专用安装工具
Set L1=           ╭─────────────╮
Set L2=      ╭────┤%Prog% ├────╮
Set L3=      │    ╰─────────────╯    │
Set L4=      │==============================================│
Set L5=      │ By:风流才子 程序代码参考了老毛桃的安装工具 │
Set L6=      ╰───────────────────────╯

Title %Prog%
Set RP=RP
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
If %RP%==RP Goto NoSys
If Exist %RP%\PELDR Goto :EXISTPE
If Exist %RP%\AVLDR.PE Goto :EXISTPE
FIND /I "C:\AVLDR.PE" %RP%\BOOT.INI >NUL
If %Errorlevel%==0 Goto :EXISTPE
Goto Start

:EXISTPE
CLS
Title %Prog%——卸载
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo       │ 检测到您机器中已经安装了 WinPE,您要卸载吗? │
Echo       │ [1] 卸载原有的 WinPE,并重新安装 WinPE   │
Echo       │ [2] 卸载原有的 WinPE,并删除原有的 WinPE  │
Echo       │ [Q] 退出安装                │
Echo %L4%
Echo %L5%
Echo %L6%

Echo.
Set Choice=
Set /P Choice=       请选择要进行的操作 (1/2/Q) ,然后按回车:
If %Choice%Choice==Choice Goto :EXISTPE
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' SET Choi=1&&GOTO :UnInstall
If /I '%Choice%'=='2' GOTO :UnInstall
If /I '%Choice%'=='Q' EXIT
Goto :EXISTPE

:UnInstall
If Exist %RP%\AVLDR.PE ATTRIB -S -H -R %RP%\AVLDR.PE && Del /Q /F %RP%\AVLDR.PE >NUL
If Exist %RP%\PELDR ATTRIB -S -H -R %RP%\PELDR && Del /Q /F %RP%\PELDR >NUL
If Exist %RP%\WINNT.SIF ATTRIB -S -H -R %RP%\WINNT.SIF && Del /Q /F %RP%\WINNT.SIF >NUL
If Exist %RP%\WINPE.IMG ATTRIB -S -H -R %RP%\WINPE.IMG && Del /Q /F %RP%\WINPE.IMG >NUL
If Exist %RP%\外置程序 RD %RP%\外置程序 /S /Q>NUL

Attrib %RP%\BOOT.INI -S -H -R
If Exist %RP%\BOOT.BAK (
        Attrib %RP%\BOOT.BAK -S -H -R
        TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
) Else (
        Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
        TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
)
Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL
Attrib %RP%\BOOT.INI +S +H +R
Title %Prog%——卸载完成

If %Choi%Choi==1Choi (Echo.&&Echo        卸载完成,请按任意键准备安装 。。。&&PAUSE>NUL&&Goto Start)
Echo.&&Echo        卸载完成,请按任意键退出 。。。
PAUSE>NUL
Exit

:Start
CLS
Title %Prog%——安装
Echo.
Echo %L1%
Echo %L2%
Echo %L3%
Echo       │ [1] 安装WinPE到C盘,并添加选择项至启动菜单 │
Echo       │ [Q] 退出安装                │
Echo %L4%
Echo %L5%
Echo %L6%

Set Choice=
Set /P Choice=       请选择要进行的操作 (1/Q) ,然后按回车:
If %Choice%Choice==Choice Goto Start
If Not '%Choice%'=='' SET Choice=%Choice:~0,1%
If /I '%Choice%'=='1' GOTO Install
If /I '%Choice%'=='q' EXIT
Goto Start

:Install
Title %Prog%——安装 WinPE
If Exist %RP%\WINNT.SIF Del /Q /F %RP%\WINNT.SIF >NUL
Echo.
Echo        正在复制文件,请稍候 。。。
Copy AVLDR.PE %RP%\ /Y >NUL
Copy PELDR %RP%\ /Y >NUL
Copy WINNT.SIF %RP%\ /Y >NUL
Expand ..\WINPE.IM_ C:\WINPE.IMG >NUL
ATTRIB -S -H -R %RP%\BOOT.INI
If Exist %RP%\BOOT.BAK ATTRIB -S -H -R %RP%\BOOT.BAK
Copy %RP%\BOOT.INI %RP%\BOOT.BAK >NUL
TYPE %RP%\BOOT.BAK|FIND /I /V "C:\AVLDR.PE">%RP%\BOOT.INI
Echo C:\AVLDR.PE = "老九 WinPE 后备应急系统">>%RP%\BOOT.INI

ATTRIB +S +H +R %RP%\BOOT.INI
ATTRIB +S +H +R %RP%\AVLDR.PE
ATTRIB +S +H +R %RP%\PELDR
ATTRIB +S +H +R %RP%\WINNT.SIF
ATTRIB +S +H +R %RP%\WINPE.IMG
Goto :SUCCESS

:NoSys
Echo        好像您的机器中没有安装操作系统哦
Echo        请确认后再执行本安装程序。
Echo.
Echo 请按任意键退出 。。。
PAUSE >NUL
Exit

:SUCCESS
Title %Prog%——安装完成
Echo.
Echo        已经成功将镜像 WINPE.IM_ 安装到您的 %RP% 盘。
Echo.
Echo        系统分区中的 BOOT.INI 备份为 BOOT.BAK。
Echo.
Echo        如果您需要将外挂程序放置到非系统分区,
Echo        直接将 外置程序 文件夹剪切到目标分区根目录即可
Echo.
Echo        请按任意键退出 。。。
PAUSE >NUL
Exit
回复

使用道具 举报

2#
发表于 2007-12-30 12:37:44 | 只看该作者
老毛桃有,你找他。
但说明,用CMD来处理BOOT.INI文件容易出错,特别是设置了属性和权限的BOOT.INI等文件。
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|捐助支持|无忧启动 ( 闽ICP备05002490号-1 )

闽公网安备 35020302032614号

GMT+8, 2024-9-28 12:22

Powered by Discuz! X3.3

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表