关于安装PE到VISTA系统的方法，我来总结一下

uepon

复制文件的我就不说了，主要的问题就是如何给VISTA添加启动菜单。根据lianjiang的那个批处理的启发。
原理：使用Vista系统自带的bcdedit命令。具体的命令可以看它的帮助菜单 bcdedit /?

主要是用批处理实现的，下面是安装批处理（以我的通用PE工具箱为例，要看效果，这里有下载：http://www.ton6.cn/viewthread.php?tid=536&extra=page%3D1）。同时把启动菜单的标识符 ID保存到一个%windir%\pevid.ini文件里，方便修改，这个标识符 ID是自动生成的，不纪录不行，删除启动项的时候必须用这个标识符 ID删除。

@echo off
COLOR f9
set vid=
set timeout=5  //这里等待时间
set gname=通用PE工具箱 //你的启动项
set gname2=\PELOAD  //这里你的引导文件，加上"\"
TITLE 设置通用PE工具箱的Vista引导
bcdedit >temp_bcd.txt
type temp_bcd.txt | find "Windows Boot Manager" >nul && goto bcd_1
goto exit

:bcd_1
bcdedit >temp_bcd.txt
type temp_bcd.txt | find "%gname2%" >nul && goto un_bcd_1
bcdedit   /create /d "%gname%" /application bootsector >%windir%\pevid.ini
for,/f,"tokens=2 delims={",%%i,In (%windir%\pevid.ini) Do (
               set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,In ("%vida%") Do (
               set vid={%%i}
)
echo %vid%>%windir%\pevid.ini
bcdedit   /set %vid% device partition=%systemdrive%   >nul
bcdedit   /set %vid% path %gname2% >nul
bcdedit   /displayorder %vid% /addlast >nul
bcdedit   /timeout   %timeout% >nul
goto exit

:un_bcd_1
for,/f,"tokens=1",%%i,In (%windir%\pevid.ini) Do (
                set vid=%%i
)
bcdedit /delete %vid% /cleanup >nul
del %windir%\pevid.ini
goto bcd_1

:exit
del temp_bcd.txt

下面是卸载程式：

@echo off
COLOR f9
set vid=
set gname2=\PELOAD
TITLE 删除通用PE工具箱的Vista引导
bcdedit >%windir%\temp_bcd.txt
type %windir%\temp_bcd.txt | find "Windows Boot Manager" >nul && goto un_bcd_1
del %windir%\temp_bcd.txt

:un_bcd_1
for,/f,"tokens=1",%%i,In (%windir%\pevid.ini) Do (
                set vid=%%i
)
bcdedit /delete %vid% /cleanup >nul
del %windir%\pevid.ini
del %windir%\temp_bcd.txt
del %windir%\unpeboot.cmd

千里独行

谢谢！直接给个911版的就更好了！

secowu

不错,这个帖子早点出来就好了,找得我好苦...

对了,获得ID的代码是不是可以参照小小强的精简下?

secowu

最好楼主,再顺便修改下毛桃的安装程序里的那个Vista安装...毛桃的那个不地道...

1. 
   
2. :Vista
   
3. Set PEDIR=%RP%\MiniPE
   
4. If Exist %RP%\MAOTAO Goto Err1
   
5. If Exist %PEDIR% Goto Err1
   
6. Echo.&&Echo.
   
7. Echo　　　　正在复制文件，请稍候 。。。
   
8. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
   
9. Set NoLDR=Yes
   
10. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
    
11. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
    
12. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
    

复制代码

加上你的代码,再加上添加额外的文件代码及修改Vista下的卸载程式....

secowu

那些文件在MYINS.DLL里有

uepon

LS给我发一份`我好修改。

uepon

for,/f,"tokens=1 delims=}",%%i,In ("%vida%") Do (
               set vid={%%i}
)
可以改成   set vid={vidi}

secowu

原帖由 uepon 于 2008-2-16 01:34 PM 发表
LS给我发一份`我好修改。

我随便修改了下小小强的,没有认真遵行毛桃的风格

1. 
   
2. @echo off
   
3. SET TP=%~dp0
   
4. SET TP=%TP:~0,-1%
   
5. SET BAKPATH=%SYSTEMDRIVE%\BOOT\BCDBAK.BAK
   
6. SET INFO=WinPe工具箱
   
7. SET MBRP=\NTLDR
   
8. SET LDRP=C:\ZJQPE
   
9. color 2f
   
10. IF NOT EXIST "C:\boot\BCD" (
    
11. cls
    
12. echo.
    
13. echo.
    
14. echo    文件C:\boot\BCD不存在，你没有安装Vista，程序无法继续。
    
15. echo    按任意键退出。。。。。。
    
16. echo.
    
17. pause>nul
    
18. goto end
    
19. )
    
20. cd /d "%TP%"
    
21. 
    
22. :install
    
23. cls
    
24. echo                  安装PE引导环境到Windows Vista
    
25. echo.                  
    
26. echo    ===========================================================
    
27. echo 即将进行安装,按任意键继续
    
28. pause>nul 2>nul
    
29. bcdedit.exe /enum all | find "%MBRP%" && goto installed
    
30. IF NOT EXIST "%BAKPATH%" start /wait bcdedit.exe /export "%BAKPATH%"
    
31. for /f "tokens=2 delims={}" %%i in ('bcdedit.exe /create /d "%INFO%" /application bootsector') do SET CLASSID=%%i
    
32. IF "%CLASSID%"=="" GOTO createerr
    
33. SET CLASSID={%CLASSID%}
    
34. ECHO %CLASSID%>%SYSTEMDRIVE%\BOOT\CLASSID_BK.INI
    
35. bcdedit.exe /set %CLASSID% device boot >nul
    
36. bcdedit.exe /set %CLASSID% path %MBRP% >nul
    
37. bcdedit.exe /displayorder %CLASSID% /addlast >nul
    
38. bcdedit.exe /timeout 3 >nul
    
39. attrib +h +s +r %LDRP% >nul 2>nul
    
40. echo.
    
41. echo    安装完成，按任意键退出。。。。。。
    
42. echo.
    
43. pause>nul 2>nul
    
44. goto end
    
45. 
    
46. :installed
    
47. echo.
    
48. echo    本机已经安装过PE，请先卸载！按任意键进行卸载,关闭退出
    
49. pause>nul
    
50. for /f %%i in (%SYSTEMDRIVE%\BOOT\CLASSID_BK.INI) do set CID=%%i
    
51. bcdedit /delete %CID%
    
52. goto install
    
53. 
    
54. 
    
55. :createerr
    
56. echo.
    
57. echo    创建BCD项错误，安装无法继续！
    
58. echo    按任意键退出。。。。。。
    
59. echo.
    
60. pause>nul
    
61. goto end
    
62. 
    
63. :end
    
64. echo on
    
65. exit
    

复制代码

secowu

原帖由 uepon 于 2008-2-16 01:34 PM 发表
LS给我发一份`我好修改。

这是毛桃的修改版本,里面增加了个再利用选项

就是当PE被安装在U盘里了,还可以继续利用U盘里的PE再进行安装到别的媒体

现在,需要的是修改毛桃那个Vista的安装选项功能了....李大侠来搞吧

1. 
   
2. 
   
3. @Echo Off
   
4. COLOR 2F
   
5. Set Prog=        WinPE 专用安装工具     
   
6. Set L1=　　　　　　╭══════════════════╮
   
7. Set L2=　　　　　　║　　　　　　　　　　　　　　　　　　║
   
8. Set L3=　　　╭══┤　%Prog%　 ├══╮
   
9. Set L4=　　　║　　║　　　　　　　　　　　　　　　　　　║　　║
   
10. Set L5=　　　║　　╰══════════════════╯　　║
    
11. Set L6=　　　║　　　　　　　　　　　　　　　　　　　　　　　　║
    
12. Set L7=　　　╟════════════════════════╢
    
13. Set L8=　　　║　                                            　║
    
14. Set L9=　　　╰────────────────────────╯
    
15. Title %Prog%
    
16. FOR /F "delims=" %%I in (%0) do Set CP=%%~dpI
    
17. Set SetupINIFile=PESetup.INI
    
18. Set PEFile=MiniPE\WinPE.IS_
    
19. Set PEIni=MiniPE\WinPE.INI
    
20. Set LogFile=PEInstall.log
    
21. If Not Exist .\PESETUP.INI Goto Err0
    
22. For /F "tokens=2 delims=^=" %%I In ('FIND /I ^"外置程序包^" .\%SetupINIFile%') DO Set OPFile=MiniPE\%%I
    
23. Set AddATTR=ATTRIB +S +H +R
    
24. Set DelATTR=ATTRIB -S -H -R
    
25. :Start
    
26. CLS
    
27. Title %Prog%——安装
    
28. Echo.
    
29. Echo %L1%
    
30. Echo %L2%
    
31. Echo %L3%
    
32. Echo %L4%
    
33. Echo %L5%
    
34. Echo %L6%
    
35. Echo 　　　║ 　请选择安装方式：　　　　　　　　　　　　　　 ║
    
36. Echo %L6%
    
37. Echo 　　　║　　[1] 普通安装/启动 (硬盘安装)　　　　　　　　║
    
38. Echo 　　　║　　[2] Grub安装/启动 (硬盘安装，支持 MD5 密码) ║
    
39. Echo 　　　║　　[3] Aero安装/启动 (硬盘安装，支持密码)　　　║
    
40. Echo 　　　║　　[4] Grub安装/启动 (U 盘、移动硬盘安装)　　　║
    
41. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
    
42. Echo %L6%
    
43. Echo %L7%
    
44. Echo 　　　║　注意: Aero 安装项只适合系统分区在(HD0,0)分区　║
    
45. Echo %L7%
    
46. Echo %L8%
    
47. Echo %L9%
    
48. Echo.
    
49. Set Choice=
    
50. Set /P Choice=　　　请选择要进行的操作 (1/2/3/4/Q) ，然后按回车：
    
51. If "%Choice%"=="" Goto Start
    
52. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
    
53. If /I "%Choice%"=="1" Goto HD
    
54. If /I "%Choice%"=="2" Goto HD
    
55. If /I "%Choice%"=="3" Goto HD
    
56. If /I "%Choice%"=="4" Goto UD
    
57. If /I "%Choice%"=="Q" Exit
    
58. Goto Start
    
59. :HD
    
60. Set RP=
    
61. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
    
62. If "%RP%"=="" Goto HDRPErr
    
63. Set PEDIR=%RP%\MiniPE&&Set TargetP=硬盘&&Set TxtSp=
    
64. If Exist %PEDIR% Goto Err1
    
65. FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
    
66. If "%Errorlevel%"=="0" Goto Err1
    
67. FIND /I "C:\MiniPE" %RP%\BOOT.INI>NUL 2>NUL
    
68. If "%Errorlevel%"=="0" Goto Err1
    
69. bootcfg /timeout 0 >NUL 2>NUL
    
70. If /I "%Choice%"=="1" Goto Install
    
71. If /I "%Choice%"=="2" Goto GInstall
    
72. If /I "%Choice%"=="3" Goto AInstall
    
73. Goto HD
    
74. :UD
    
75. CLS
    
76. Title %Prog%——U 盘安装
    
77. For /F "skip=2 tokens=*" %%I In ('MYINS\CHECKUSB.EXE') DO SET Us=%%I
    
78. If "%Us%"=="当前可移动磁盘分区：" Goto NoUD
    
79. Echo %Us%&&Echo.
    
80. If "%NoUD%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、未格式化或不是 U 盘分区，请按任意键重新设定。&&Echo.
    
81. Set /P RP=请选择您的 U 盘盘符（不需要冒号，例如 F）：
    
82. Echo.&&Echo.
    
83. If "%RP%"=="" Goto UD
    
84. If Not "%RP%"=="" Set RP=%RP:~0,1%:
    
85. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
    
86. If Not "%Err2%"=="1" Set NoUD=Yes&&Goto UD
    
87. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
    
88. Cd.>%TestFile%
    
89. If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
    
90. FOR /F "delims=" %%I in (%0) do Set TP=%%~dI
    
91. Del %TestFile% /Q>NUL 2>NUL
    
92. for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set rp=%%rp:%%i=%%i%%
    
93. If Not "%RP%"=="" Set RP=%RP:~0,1%:
    
94. if "%TP%"=="%RP%" goto DBU
    
95. Set U=U&&Set PEDIR=%RP%\MiniPE&&Set TargetP= U 盘&&Set TxtSp=
    
96. If Exist %RP%\MAOTAO Goto Err1
    
97. If Exist %PEDIR% Goto Err1
    
98. CLS
    
99. Echo 您选择的 U 盘分区为 %RP%，下面将对您的 U 盘进行格式化并写入引导
    
100. Echo.
     
101. Echo 请严格按照相关工具软件界面中的提示操作，以防出错。请按任意键开始。。。
     
102. PAUSE>NUL
     
103. Start /Wait MYINS\HPUSBFW.EXE
     
104. Start /Wait MYINS\GRUBGUI.EXE
     
105. cls
     
106. echo 请稍候,正在安装中......
     
107. Echo.
     
108. md %rp%\SETUP\MYINS  >NUL 2>NUL
     
109. md %rp%\MINIPE       >NUL 2>NUL
     
110. md %rp%\SETUP\TOOLS  >NUL 2>NUL
     
111. copy myins\aero.sys %rp%\setup\myins     >NUL 2>NUL
     
112. copy myins\checkusb.exe %rp%\setup\myins >NUL 2>NUL
     
113. copy myins\grubgui.exe %rp%\setup\myins  >NUL 2>NUL
     
114. copy myins\grubinst.exe %rp%\setup\myins >NUL 2>NUL
     
115. copy myins\hpusbfw.exe %rp%\setup\myins  >NUL 2>NUL
     
116. copy myins\md5.exe %rp%\setup\myins      >NUL 2>NUL
     
117. copy myins\myins.dll %rp%\setup\myins    >NUL 2>NUL
     
118. copy myins\myins.exe %rp%\setup\myins    >NUL 2>NUL
     
119. copy myins\ntboot.exe %rp%\setup\myins   >NUL 2>NUL
     
120. copy pesetup.ini %rp%\setup              >NUL 2>NUL
     
121. copy pesetup.cmd %rp%\setup              >NUL 2>NUL
     
122. copy tools\BMP2COVE.exe %rp%\setup\tools >NUL 2>NUL
     
123. copy tools\WIMTOOL.EXE %rp%\setup\tools  >NUL 2>NUL
     
124. copy tools\MD5CRYPT.rar %rp%\setup\tools >NUL 2>NUL
     
125. copy tools\WIMFS.exe %rp%\setup\tools    >NUL 2>NUL
     
126. copy tools\WIMGAPI.DLL %rp%\setup\tools  >NUL 2>NUL
     
127. copy tools\WIMGAPI.PAS %rp%\setup\tools  >NUL 2>NUL
     
128. cls
     
129. echo.
     
130. Echo 您的 U 盘已经成功格式化并写入了 Grub 引导，请按任意键继续......
     
131. PAUSE>NUL
     
132. Goto GInstall
     
133. :DBU
     
134. echo ------------------------------------------------------------------
     
135. ECHO 您选择的安装盘符与目标盘符重复，不需要再安装。请选择其它的安装方式
     
136. echo ------------------------------------------------------------------
     
137. pause
     
138. goto start
     
139. :NoUD
     
140. CLS
     
141. Title %Prog%——U 盘安装
     
142. Echo.
     
143. Echo %L1%
     
144. Echo %L2%
     
145. Echo %L3%
     
146. Echo %L4%
     
147. Echo %L5%
     
148. Echo %L6%
     
149. Echo 　　　║ 您的计算机似乎没有安装 U 盘，您想怎么办？　　　║
     
150. Echo %L6%
     
151. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
152. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
153. Echo %L6%
     
154. Echo %L7%
     
155. Echo %L8%
     
156. Echo %L9%
     
157. Echo.
     
158. Set Choice=
     
159. Set /P Choice=　　　请选择要进行的操作 (B/Q) ，然后按回车：
     
160. If "%Choice%"=="" Goto NoUD
     
161. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
162. If /I "%Choice%"=="B" Goto Start
     
163. If /I "%Choice%"=="Q" Exit
     
164. Goto NoUD
     
165. Exit
     
166. :Err0
     
167. Echo 错误：安装配置文件丢失！&&Echo.
     
168. Echo 请确认安装配置文件 %SetupINIFile% 存在或到本程序所在目录执行安装。&&Echo.
     
169. Echo 请按任意键退出安装程序。。。
     
170. PAUSE>NUL
     
171. Exit
     
172. :Err1
     
173. CLS
     
174. Title %Prog%——卸载
     
175. Echo.
     
176. Echo %L1%
     
177. Echo %L2%
     
178. Echo %L3%
     
179. Echo %L4%
     
180. Echo %L5%
     
181. Echo %L6%
     
182. Echo 　　　║ 您的%TargetP%中好像已经安装了 WinPE，您想怎么办？%TxtSp%　║
     
183. Echo %L6%
     
184. Echo 　　　║　　[1] 卸载原有的 WinPE，并且重新安装。　　　　║
     
185. Echo 　　　║　　[2] 卸载原有的 WinPE，并且不再安装。　　　　║
     
186. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
187. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
188. Echo %L6%
     
189. Echo %L7%
     
190. Echo %L8%
     
191. Echo %L9%
     
192. Echo.
     
193. Set Choice=
     
194. Set /P Choice=　　　请选择要进行的操作 (1/2/B/Q) ，然后按回车：
     
195. If "%TargetP%"=="硬盘" Set U=
     
196. If "%Choice%"=="" Goto Err1
     
197. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
198. If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
     
199. If /I "%Choice%"=="2" Goto UnInstall
     
200. If /I "%Choice%"=="B" Goto Start
     
201. If /I "%Choice%"=="Q" Exit
     
202. Goto Err1
     
203. Exit
     
204. :UnInstall
     
205. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
     
206. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
     
207. If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
     
208. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
     
209. If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPD=%%i
     
210. If Not "%U%"=="" Set OPD=%RP%
     
211. If Exist %OPD%\外置程序 RD %OPD%\外置程序 /S /Q>NUL 2>NUL
     
212. If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
     
213. If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
     
214. If Exist %RP%\MiniPE RD %RP%\MiniPE /S /Q>NUL 2>NUL
     
215. %DelATTR% %RP%\BOOT.INI>NUL 2>NUL
     
216. Set TMPINIFile=BOOT_%RANDOM%.INI
     
217. If Exist %RP%\BOOT.BAK (
     
218. %DelATTR% %RP%\BOOT.BAK
     
219. TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
     
220. TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
221. ) Else (
     
222. If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.INI|FIND /I /V "C:\MAOTAO">%RP%\%TMPINIFile%
     
223. If Exist %RP%\%TMPINIFile% TYPE %RP%\%TMPINIFile%|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
224. )
     
225. If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
     
226. If Exist %RP%\%TMPINIFile% %DelATTR% %RP%\%TMPINIFile%&&Del %RP%\%TMPINIFile%>NUL 2>NUL
     
227. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
     
228. Set RP=
     
229. Title %Prog%——卸载完成
     
230. If "%Choi%"=="1" (Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
     
231. Echo.&&Echo.&&Echo　　　　卸载完成，请按任意键退出 。。。
     
232. PAUSE>NUL 2>NUL
     
233. Exit
     
234. :Install
     
235. Title %Prog%——普通安装
     
236. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
237. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
238. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
239. Echo.&&Echo　　　　正在复制文件，请稍候 。。。
     
240. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
     
241. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
     
242. Call :CopyAndSetFiles
     
243. Goto SUCCESS
     
244. :GInstall
     
245. If "%U%"=="" Title %Prog%——Grub安装
     
246. CLS
     
247. Set LDRP=MiniPE\
     
248. Echo 请输入您要设定的密码
     
249. Echo 注意：密码中不许有空格、""、引号等特殊字符
     
250. Echo.
     
251. Set /P Pass1=请输入：
     
252. If "%Pass1%"=="" Goto GInstall
     
253. Echo.&&Echo.
     
254. Echo 请再一次输入您的密码
     
255. Echo.
     
256. Set /P Pass2=请再次输入：
     
257. If "%Pass2%"=="" Goto GInstall
     
258. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
     
259. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
260. >%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
     
261. MYINS\MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
     
262. For /f %%i In ('type %PEDIR%\md5r.txt') do SET MD5Pass=password --md5 %%i
     
263. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
     
264. >>%RP%\MTLDR Echo %MD5Pass%
     
265. >>%RP%\MTLDR Echo fontfile /minipe/muifont.gz
     
266. >>%RP%\MTLDR Echo splashimage /minipe/bj2008.xpm.gz
     
267. >>%RP%\MTLDR Echo.
     
268. >>%RP%\MTLDR Echo title WinPE 迷你维护系统
     
269. >>%RP%\MTLDR Echo %MD5Pass%
     
270. >>%RP%\MTLDR Echo chainloader /minipe/ldrxpe
     
271. >>%RP%\MTLDR Echo.
     
272. >>%RP%\MTLDR Echo title Grub 命令行
     
273. >>%RP%\MTLDR Echo %MD5Pass%
     
274. >>%RP%\MTLDR Echo commandline
     
275. >>%RP%\MTLDR Echo.
     
276. >>%RP%\MTLDR Echo title 从第一硬盘第一分区启动
     
277. >>%RP%\MTLDR Echo root ^(hd0,0^)
     
278. >>%RP%\MTLDR Echo chainloader +1
     
279. >>%RP%\MTLDR Echo.
     
280. >>%RP%\MTLDR Echo title 从第二硬盘第一分区启动
     
281. >>%RP%\MTLDR Echo root ^(hd1,0^)
     
282. >>%RP%\MTLDR Echo chainloader ^(hd1,0^)+1
     
283. >>%RP%\MTLDR Echo.
     
284. >>%RP%\MTLDR Echo title 重新启动计算机
     
285. >>%RP%\MTLDR Echo reboot
     
286. >>%RP%\MTLDR Echo.
     
287. >>%RP%\MTLDR Echo title 关闭计算机
     
288. >>%RP%\MTLDR <nul Set/p=halt
     
289. Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
     
290. cls
     
291. Echo.
     
292. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
     
293. PAUSE>NUL 2>NUL
     
294. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
295. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
296. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR  
     
297. Echo.
     
298. Echo 正在复制文件，请稍候 。。。
     
299. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y >NUL 2>NUL
     
300. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y    >NUL 2>NUL
     
301. If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y   >NUL 2>NUL
     
302. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y  >NUL 2>NUL
     
303. If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin  >NUL 2>NUL
     
304. Call :CopyAndSetFiles
     
305. Goto SUCCESS
     
306. :AInstall
     
307. Title %Prog%——Aero安装
     
308. CLS
     
309. Echo 请输入您要设定的密码
     
310. Echo 注意：密码中不许有空格、""、引号等特殊字符
     
311. Echo.
     
312. Set /P Pass1=请输入：
     
313. If "%Pass1%"=="" Goto AInstall
     
314. Echo.&&Echo.
     
315. Echo 请再一次输入您的密码
     
316. Echo.
     
317. Set /P Pass2=请再次输入：
     
318. If "%Pass2%"=="" Goto AInstall
     
319. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致，请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
     
320. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
     
321. For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
     
322. Ren %PEDIR%\maotao.bin avldr.xpe
     
323. Ren %PEDIR%\maotaoa.bin maotao.bin
     
324. >%PEDIR%\airL.gz <nul Set/p=%Pass2%
     
325. Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
     
326. MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
     
327. cls
     
328. Echo.
     
329. Echo 密码设置完成，请牢记您的密码，并按任意键继续 。。。
     
330. PAUSE>NUL 2>NUL
     
331. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
     
332. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
     
333. Echo.
     
334. Echo 正在复制文件，请稍候 。。。
     
335. MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
     
336. Call :CopyAndSetFiles
     
337. Goto SUCCESS
     
338. :HDRPErr
     
339. CLS
     
340. Set RP=
     
341. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BootMGR Set RP=%%I:&&Set PEDIR=%%I:\MiniPE
     
342. If Not "%RP%"=="" (
     
343. TITLE %Prog%——检测到 Windows Vista 分区
     
344. Set OPT=Vista&&Set OPT0=存在 WinVista 分区&&Set OPT1=[I] 将 WimPE 安装到 Windows Vista 分区。
     
345. ) Else (
     
346. TITLE %Prog%——没有检测到系统分区
     
347. Set OPT=NewHD&&Set OPT0=没有安装过操作系统&&Set OPT1=[I] 全新硬盘，将 WimPE 安装到活动分区。
     
348. )
     
349. Echo.
     
350. Echo %L1%
     
351. Echo %L2%
     
352. Echo %L3%
     
353. Echo %L4%
     
354. Echo %L5%
     
355. Echo %L6%
     
356. Echo 　　　║　好像您的机器中%OPT0%，您想怎么办？║
     
357. Echo %L6%
     
358. Echo 　　　║　　%OPT1%　　║
     
359. Echo 　　　║　　[B] 返回首页，重新选择安装选项。　　　　　　║
     
360. Echo 　　　║　　[Q] 退出安装　　　　　　　　　　　　　　　　║
     
361. Echo %L6%
     
362. Echo 　　　║　注意: 为确保安全，此安装选项可能会卸载不干净！║
     
363. Echo %L7%
     
364. Echo %L8%
     
365. Echo %L9%
     
366. Echo.
     
367. Set Choice=
     
368. Set /P Choice=　　　请选择要进行的操作 (I/B/Q) ，然后按回车：
     
369. If "%Choice%"=="" Goto HDRPErr
     
370. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
     
371. If /I "%Choice%"=="I" If "%OPT%"=="Vista" Goto Vista
     
372. If /I "%Choice%"=="I" If "%OPT%"=="NewHD" Goto NewHD
     
373. If /I "%Choice%"=="B" Goto Start
     
374. If /I "%Choice%"=="Q" Exit
     
375. Goto HDRPErr
     
376. Exit
     
377. :Vista
     
378. Set PEDIR=%RP%\MiniPE
     
379. If Exist %RP%\MAOTAO Goto Err1
     
380. If Exist %PEDIR% Goto Err1
     
381. Echo.&&Echo.
     
382. Echo　　　　正在复制文件，请稍候 。。。
     
383. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
     
384. Set NoLDR=Yes
     
385. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
     
386. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
     
387. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
     
388. Call :CopyAndSetFiles
     
389. Goto SUCCESS
     
390. :NewHD
     
391. CLS
     
392. TITLE %Prog%——在全新硬盘中安装
     
393. If "%NoNewErr%"=="Yes" Echo 错误：您设定的分区 %RP% 不存在、写保护、或未格式化，请按任意键重新设定。&&Echo.
     
394. Echo 请设置您需要安装 WinPE 到哪个分区（注意一定要是活动分区）
     
395. Echo.
     
396. Set /P RP=请输入您需要安装 WinPE 的分区符（不需要冒号，例如 C），然后按回车：
     
397. Echo.&&Echo.
     
398. If "%RP%"=="" Goto NewHD
     
399. If Not "%RP%"=="" Set RP=%RP:~0,1%:
     
400. For /F %%I In ('MYINS\CHECKUSB.EXE %RP%') DO SET Err2=%%I
     
401. If Not Exist %RP% Set NoNewErr=Yes&&Goto NewHD
     
402. Set TestFile=%RP%\MiniPETest_%RANDOM%.MT
     
403. Cd.>%TestFile%
     
404. If Not Exist %TestFile% Set NoNewErr=Yes&&Goto NewHD
     
405. Del %TestFile% /Q>NUL 2>NUL
     
406. Set PEDIR=%RP%\MiniPE
     
407. If Exist %RP%\MAOTAO Goto Err1
     
408. If Exist %PEDIR% Goto Err1
     
409. MyIns\NTBoot.exe %RP% >NUL
     
410. Echo.
     
411. Echo 正在复制文件，请稍候 。。。
     
412. If Exist %RP%\NTLDR %DelATTR% %RP%\NTLDR&&Ren %RP%\NTLDR NTLDR.BAK
     
413. Set NoLDR=Yes
     
414. If "%NoLDR%"=="Yes" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% LDRXPE -r -y>NUL 2>NUL
     
415. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% PE -r -y>NUL 2>NUL
     
416. If "%NoLDR%"=="Yes" Ren %RP%\LDRXPE NTLDR
     
417. Call :CopyAndSetFiles
     
418. Goto SUCCESS
     
419. :CopyAndSetFiles
     
420. If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y >NUL 2>NUL
     
421. If "%U%"=="" For /F %%i In ("%RP%\NTLDR") Do If %%~zi LSS 250000 Set SysVer=2K >NUL 2>NUL
     
422. If "%NoLDR%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y >NUL 2>NUL
     
423. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% NTCOM -r -y>NUL 2>NUL            >NUL 2>NUL
     
424. ::If Not Exist %RP%\NTLDR MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y  >NUL 2>NUL
     
425. echo.
     
426. Copy ..\%PEFile% %PEDIR% /Y /Z
     
427. Copy ..\%OPFile% %PEDIR% /Y /Z
     
428. Copy ..\%PEIni% %PEDIR% /Y  /Z
     
429. If "%U%"=="" If Exist %RP%\BOOT.INI %DelATTR% %RP%\BOOT.INI
     
430. If "%U%"=="" If Exist %RP%\BOOT.INI If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
     
431. If "%U%"=="" If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
     
432. If "%U%"=="" If Exist %RP%\BOOT.INI TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MiniPE">%RP%\BOOT.INI
     
433. If "%U%"=="" If Exist %RP%\BOOT.INI Echo C:\MiniPE\MAOTAO.BIN="WinPE">>%RP%\BOOT.INI
     
434. If /I "%SysVer%"=="2K" (
     
435. %DelATTR% %RP%\NTLDR&&%DelATTR% %RP%\bootfont.bin
     
436. Ren %RP%\NTLDR NTLDR.2K&&Ren %RP%\bootfont.bin bootfont.bin.2K
     
437. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTLDR -r -y>NUL 2>NUL
     
438. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% bootfont.bin -r -y>NUL 2>NUL
     
439. )
     
440. If Exist %RP%\%PEIni% %DelATTR% %RP%\%PEIni%
     
441. TYPE ..\%PEIni%|FIND /I /V "PESetup.EXE">%RP%\%PEIni%
     
442. %AddATTR% %RP%\MiniPE /S /D
     
443. ::%AddATTR% %RP%\MiniPE\*.* /S /D
     
444. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
     
445. If Exist %RP%\%LDRP%LDRXPE %AddATTR% %RP%\%LDRP%LDRXPE
     
446. If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
     
447. If Exist %RP%\nTLDR %AddATTR% %RP%\nTLDR
     
448. If Exist %RP%\mTLDR %AddATTR% %RP%\mTLDR
     
449. Goto :EOF
     
450. :SUCCESS
     
451. Title %Prog%——安装完成
     
452. CLS
     
453. For %%i In (C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do If /I "%RP%"=="%%i:" Set RP=%%i:
     
454. Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
     
455. If "%U%"=="" (
     
456. Echo.
     
457. If Exist %RP%\Boot.INI Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
     
458. )
     
459. Echo.&&Echo.
     
460. Echo 如果您需要将 WinPE 卸载，请重新运行本安装程序。
     
461. Echo.
     
462. Echo 请按任意键退出 。。。
     
463. PAUSE>NUL 2>NUL
     
464. Exit
     

复制代码

secowu

其实修改毛桃的安装程序就只有两个目的

1.扩展安装功能,能将PE安装到移动媒体后可以再次利用安装工具进行安装
2.补充Wimtool组件及工具
3.修改毛桃的Vista安装批处理,让它真正的支持Vista安装
4.要是能够支持写入MBR方式就像是一恢复也是不错的

secowu

试用grldr.mbr的方法看看

--没下载到小小强的PE,听说用的这个方法

musleejs

看得我云里雾里！！！

421062724

uepon你那代码不完善哦>_<有点小问题，卸载模块不用那么复杂。可以再搞简单点

fujianabc

无需这么复杂通过grub来引导setupldr.bin

直接可以从bcd中加载setupldr.bin来启动pe

secowu

原帖由 fujianabc 于 2008-2-16 05:25 PM 发表
无需这么复杂通过grub来引导setupldr.bin

直接可以从bcd中加载setupldr.bin来启动pe

很多年都没这个文件了setupldr.bin,谁提供个?

421062724

pe不都有吗

lights

原帖由 fujianabc 于 2008-2-16 05:25 PM 发表
无需这么复杂通过grub来引导setupldr.bin

直接可以从bcd中加载setupldr.bin来启动pe

如何才能实现从bcd中加载setupldr.bin来启动pe呢?

LOVPE

原帖由 secowu 于 2008-2-16 08:34 PM 发表


很多年都没这个文件了setupldr.bin,谁提供个?

小小强最近的PE里有的

Ansson

原帖由 421062724 于 2008-2-16 04:48 PM 发表
uepon你那代码不完善哦>_

怎么完善？还是写出来吧

secowu

原帖由 LOVPE 于 2008-3-11 08:08 AM 发表


小小强最近的PE里有的

谢谢。。。

nm888

原帖由 secowu 于 2008-2-16 02:06 PM 发表


这是毛桃的修改版本,里面增加了个再利用选项

就是当PE被安装在U盘里了,还可以继续利用U盘里的PE再进行安装到别的媒体

现在,需要的是修改毛桃那个Vista的安装选项功能了....李大侠来搞吧


@Echo  ...

这一句“bootcfg /timeout 0 >NUL 2>NUL”当中有点问题，如果安装到XP系统，就没有启动菜单可选了，直接进入XP，将0改为3就好了。

Medivh

收藏学习。。谢谢楼主分享