FOR的应用递增变量的疑问。

zts59

CSV1.CSV文件是通讯录文件。
内容：

1. 姓名,电子邮件,别名,所属部门,联系电话,性别,职务,编号,备注
   
2. 王xx,EMAIL1@c.cn,,某工作室/a部门,,男,,,
   
3. 欧XX,EMAIL2@c.cn,,某工作室/b部门,,男,,,
   
4. 蓝XX,EMAIL3@c.cn,me@c.cn,某工作室/e部门,8061,女,,,
   
5. 朱XX,EMAIL4@c.cn,test@c.cn,某工作室/f部门,8052,男,it,,
   

复制代码

CSV2VCF.bat
内容：

1. @echo off
   
2. setlocal EnableDelayedExpansion
   
3. rd log /s /q
   
4. md log
   
5. 
   
6. set /a line=1
   
7. 
   
8. for /f  "tokens=1-7 delims=," %%a in (csv1.csv) do (
   
9.         if !line! gtr 1 (
   
10.                 (echo BEGIN:VCARD)       > log\%%a.txt
    
11.                 (VERSION:3.0)                 >> log\%%a.txt
    
12.                 (echo N:;%%a;;;)                 >> log\%%a.txt
    
13.                 (echo FN:%%a)                         >> log\%%a.txt
    
14.                 (echo EMAIL;INTERNET:%%b)         >> log\%%a.txt
    
15.                 (echo ORG:;%%d)                         >> log\%%a.txt
    
16.                 (echo TEL;TYPE=CELL:%%e)         >> log\%%a.txt
    
17.                 (echo TITLE:%%g)                 >> log\%%a.txt
    
18.                 (echo END:VCARD)                 >> log\%%a.txt
    
19.         )
    
20. 
    
21.         set /a line+=1
    
22. 
    
23. )
    
24. ren .\log\*.txt *.vcf
    

复制代码

取前2行数据时 因为第3列“别名”和第5列“联系电话”是空的，导致%%d 取到了第6列“性别”了，这个怎么破

zts59

pznpt 发表于 2014-11-10 22:52
换一种思路：

谢谢，好用呀

pznpt

换一种思路：

1. @echo off
   
2. rd log /s /q 2>nul
   
3. md log
   
4. for /f  "tokens=* skip=1" %%a in (csv1.csv) do (
   
5.         set "str=%%a"
   
6.         setlocal EnableDelayedExpansion
   
7.         for %%b in ("!str:,=","!") do (set /a n+=1 & set "_!n!=%%~b")
   
8.         (
   
9.                 echo BEGIN:VCARD
   
10.                 echo VERSION:3.0
    
11.                 echo N:;!_1!;;;
    
12.                 echo FN:!_1!
    
13.                 echo EMAIL;INTERNET:!_2!
    
14.                 echo ORG:;!_4!
    
15.                 echo TEL;TYPE=CELL:!_5!
    
16.                 echo TITLE:!_7!
    
17.                 echo END:VCARD
    
18.         ) > log\!_1!.vcf
    
19.         endlocal
    
20. )
    
21. pause

复制代码