删除第N个某字符后面的所有字符

2012xb21cn · 发表于 2018-6-28 09:55:13

本帖最后由 2012xb21cn 于 2018-6-28 10:16 编辑

1245.5545.4784264-5455.65455
结果：
1245.5545.4784264-5455

需求：提取最后一个.前面的所有字符串，或删除最后一个.后面所有字符串
(　.的个数不定）

麻烦高手帮忙！！！

holley2008 · 发表于 2018-6-28 14:45:48

2012xb21cn 发表于 2018-6-28 13:56
刚好凑巧分隔符是.，如果是其它字符就不行了

一样类似可以set定义.代替其它分隔符效果最明显不需要for或findstr查找半天。

chiannet · 发表于 2018-6-29 08:53:37

本帖最后由 chiannet 于 2018-6-29 09:09 编辑

holley2008 发表于 2018-6-29 07:06
获取的是第一个.后面的字符串，，，我想要的是获取第一个.前面的字符串
用for比较简单

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET A1=左&SET A2=右&SET B1=前&SET B2=后
:N
CLS
ECHO.&ECHO.
ECHO.&ECHO.
SET /P FS=输入定位符号并回车：
REM 定位符号，赋值给FS，本批处理只能处理长度为1的单字符。
IF "%FS%"=="" (ECHO.&ECHO 输入无效，请重新输入！
PAUSE >NUL && CLS && GOTO N) ELSE (SET FS=%FS:~0,1%)
SET "TP=%~DP0"
REM 原始.TXT所在路径名，赋值给TP，以“\”结尾。
IF NOT EXIST "%TP%原始.TXT" (ECHO.&ECHO 未发现"%TP%原始.TXT"
PAUSE >NUL && CLS && EXIT)
:M
CLS
SET AX=&SET BX=
ECHO.&ECHO.
ECHO.&ECHO 按需求变换“原始.TXT”中每行字符串
ECHO.&ECHO.
ECHO.&ECHO 1、取得最%A1%“%FS%”之%B1%的字符
ECHO.&ECHO 2、取得最%A1%“%FS%”之%B2%的字符
ECHO.&ECHO 3、取得最%A2%“%FS%”之%B1%的字符
ECHO.&ECHO 4、取得最%A2%“%FS%”之%B2%的字符
ECHO.&ECHO 5、退出
ECHO.&ECHO.
SET /P AB=输入代码并回车：
IF NOT "%AB%"=="" SET AB=%AB:~0,1%
IF "%AB%"=="1" (SET AX=%A1%&SET BX=%B1%)
IF "%AB%"=="2" (SET AX=%A1%&SET BX=%B2%)
IF "%AB%"=="3" (SET AX=%A2%&SET BX=%B1%)
IF "%AB%"=="4" (SET AX=%A2%&SET BX=%B2%)
IF "%AB%"=="5" EXIT
IF "%AX%"=="" (ECHO.&ECHO 输入无效，请重新输入！
PAUSE >NUL && CLS && GOTO M)
SET PT="%TP%最%AX%定位符之%BX%的字符.TXT"
DEL %PT% /F >NUL 2>NUL
FOR /F "DELIMS=" %%I IN ('TYPE "%TP%原始.TXT"') DO CALL :L "%%I"
IF EXIST %PT% (CLS&ECHO.&ECHO %PT% 已创建。&ECHO.&ECHO.&PAUSE)
GOTO M
:L
SET "B=%~1"
IF "%AB%"=="1" (IF "%B:~0,1%"=="%FS%" (SET "RE=有一个“%FS%”位于此行首位。"&GOTO E))
IF "%AB%"=="4" (IF "%B:~-1%"=="%FS%" (SET "RE=有一个“%FS%”位于此行末尾。"&GOTO E))
SET RE=此行找不到指定的定位符号"%FS%"！
SET /A N=1
SET "A=%~1"
:R
SET /A NN=%N%-1
IF "%AB%"=="4" (SET "B=!A:~-%N%!"
SET "D=!B:~0,1!"
IF "!D!"=="%FS%" (SET "RE=!A:~-%NN%!"&GOTO E)
IF "!B!"=="%A%" GOTO E)
IF "%AB%"=="3" (SET D=%B:~-1,1%
SET B=!B:~0,-1!
IF "!D!"=="%FS%" (SET "RE=!B!"&GOTO E))
IF "%AB%"=="2" (SET D=%B:~0,1%
SET B=!B:~1,100000!
IF "!D!"=="%FS%" (SET "RE=!B!"&GOTO E))
IF "%AB%"=="1" (SET "B=!A:~0,%N%!"
SET "D=!B:~-1!"
IF "!D!"=="%FS%" (SET "RE=!A:~0,%NN%!"&GOTO E)
IF "!B!"=="%A%" GOTO E)
SET /A N=%N%+1
IF %AB% GTR 1 (IF %AB% LSS 4 (IF "%B%"=="" GOTO E))
GOTO R
:E
IF %AB% GTR 1 (IF %AB% LSS 4 (IF "%RE%"=="" SET "RE=有且仅有一个“%FS%”位于此行最%BX%位。"))
ECHO %RE%>>%PT%
GOTO :EOF

复制代码

baby1277 · 发表于 2025-4-4 10:48:14

本帖最后由 baby1277 于 2025-4-4 10:57 编辑

我的思路是用for定位最后一个.的位置然后用set截取。
@echo off
setlocal enabledelayedexpansion
set ip=1245.5545.4784264-5455.65455
for /l %%i in (1 1 9) do if "!ip:~-%%i,1!"=="." set n=%%i&&goto ok
:ok
echo !ip:~0,-%n%!
endlocal
pause

wwss707 · 发表于 2025-4-1 15:42:42

学习下

tanglf · 发表于 2024-2-25 09:02:59

技术贴！
收藏了

yyz2191958 · 发表于 2023-1-14 17:58:30

不错学习到不少

aliabc-999 · 发表于 2023-1-14 15:33:45

感谢大神分享！！！

ZMLoveLH · 发表于 2023-1-14 14:26:09

看了这个帖子里牛人的解答，我觉得我的水平还不够，多学习学习啊

likeyouli · 发表于 2023-1-8 11:51:12

用正则表达式最方便，首尾匹配，
最后一个不是. 而是其他符号甚至空格都可以：\D\d+$
这样获取的是最后一个符号及后边的数字，如果需要前边的内容，将这替换为空即可

likeyouli · 发表于 2022-9-1 14:38:13

本帖最后由 likeyouli 于 2022-9-4 16:33 编辑

接上个帖子，改进下，没有这个符号 . 时，提示“没有这个符号”
=IF(ISERROR(LEFT(A1,FIND("louzhuhaoren",SUBSTITUTE(A1,".","louzhuhaoren",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-1)),"没有这个符号",LEFT(A1,FIND("louzhuhaoren",SUBSTITUTE(A1,".","louzhuhaoren",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-1))

likeyouli · 发表于 2022-9-1 11:43:29

本帖最后由 likeyouli 于 2022-9-1 11:47 编辑

老帖子，很有意义，也顶下，
顺便说下我的答案，假如1245.5545.4784264-5455.65455在excel中是A1单元格，
提取最后一个.前面的所有字符串： =LEFT(A1,FIND("louzhuhaoren",SUBSTITUTE(A1,".","louzhuhaoren",LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-1) 无论有多少个. 无论长度多少均可以，但没有.时会报错

newswan · 发表于 2018-7-1 14:22:25

对于不定长，把分隔符转成空格，字符串作为函数参数，用 shift 依次处理

set A=1245.5545.4784264-5455.65455
set A=%A:.= %
call :f %A%
goto :end

:f
do

shift 1
loop

goto :eof

dos时代菜鸟 · 发表于 2018-6-29 09:29:11

本帖最后由 dos时代菜鸟于 2018-6-29 10:54 编辑

chiannet 发表于 2018-6-29 08:53

一个豆豆的事情，搞得大家都很会逗了。哈哈哈

chiannet · 发表于 2018-6-29 09:02:18

闲得那个痛才搞这样的代码

9zhmke · 发表于 2018-6-29 08:45:50

是在重新做OFFICE了吗？你可以把具体任务放上来，大家一起帮你调试。

holley2008 · 发表于 2018-6-29 07:06:17

dos时代菜鸟发表于 2018-6-28 22:10
从前往后剔除第一个 . 前面的部分
两个方法，自己选。

获取的是第一个.后面的字符串，，，我想要的是获取第一个.前面的字符串
用for比较简单

for /f "tokens=1 delims=." %%a in ("%str%") do echo %%a

复制代码

但想靠set分割来做有点抓瞎...

dos时代菜鸟 · 发表于 2018-6-28 22:14:51

slore 发表于 2018-6-28 21:24

如果原字符串中含有 \ 就会产生误解。

dos时代菜鸟 · 发表于 2018-6-28 22:10:00

本帖最后由 dos时代菜鸟于 2018-6-28 22:19 编辑

从前往后剔除第一个 . 前面的部分
两个方法，自己选。

@echo off
set "lx001=1245.5545.4784264-5455.65455"
:loop
if "%lx001:~0,1%"=="" goto end
if "%lx001:~0,1%"=="." goto end
set lx001=%lx001:~1%
goto loop
:end
echo “%lx001:~1%”
pause

复制代码

@echo off
for /f "tokens=1,* delims=." %%a in ("1245.5545.4784264-5455.65455") do (echo "%%b")
pause

复制代码

slore · 发表于 2018-6-28 21:24:35

@echo off
set a=1245.5545.4784264-5455.65455
set a1=X:\%a:.=\%
for /f %%i in ("%a1%") do set a1=%%~pi
set a1=%a1:\=.%
set a1=%a1:~1,-1%
echo %a1%
pause

复制代码

slore · 发表于 2018-6-28 21:18:25

@echo off
set a=1245.5545.4784264-5455.65455
set dp_tmp=X:\%a:.=\%
call :DOTPATH %dp_tmp%
echo %RET_PATH%
pause
goto :EOF
:DOTPATH
set RET_PATH=%~dp1
set RET_PATH=%RET_PATH:\=.%
set RET_PATH=%RET_PATH:~3,-1%
goto :EOF

复制代码

holley2008 · 发表于 2018-6-28 18:47:13

本帖最后由 holley2008 于 2018-6-28 18:51 编辑

@echo off&setlocal enabledelayedexpansion
set str=1245.5545.4784264-5455.65455
:start
set first=%str:~0,1%
set last=%str:~-1,1%
set str=%str:~0,-1%
set strf=%str:~1,-1%
IF "%last%"=="." (goto end )
IF "%first%"=="." (goto end )
goto start
:end
echo "%str%"
echo "%strf%"
pause>nul

复制代码

应该可以。回家途中，回去再试试…
手机编辑巨麻烦

holley2008 · 发表于 2018-6-28 18:13:50

chiannet 发表于 2018-6-28 16:00
这个并不太好，比如以下字符串

16F的通用性确实好很多！

@echo off&setlocal enabledelayedexpansion
set str=1245.5545.4784264-5455.65455
:start
set last=%str:~-1,1%
set str=%str:~0,-1%
IF "%last%"=="." (goto end )
goto start
:end
echo "%str%"
pause>nul

复制代码

但突然发神经，想获取第一个.号前面的字符串呢？
脑阔大！！！

2012xb21cn · 发表于 2018-6-28 17:26:19

chiannet 发表于 2018-6-28 17:05
修改一下上面代码的原始.txt及转化后.txt的路径

多谢C大，换其它字符都测试成功

chiannet · 发表于 2018-6-28 17:05:05

修改一下上面代码的原始.txt及转化后.txt的路径

chiannet · 发表于 2018-6-28 17:03:54

2012xb21cn 发表于 2018-6-28 16:06
那如何批量从文件中读取修改呢（每行都是类似数据）？试着改了下总不成功

@ECHO OFF
del "%~DP0转化后.TXT" /F >NUL 2>NUL
FOR /F "delims=" %%I IN ('type "%~DP0原始.txt"') DO CALL :L "%%I"
EXIT
:L
SET "B=%~1"
SET RE=此行找不到”.“
:R
SET D=%B:~-1,1%
SET B=%B:~0,-1%
IF "%D%"=="." (SET "RE=%B%"&&GOTO :E)
IF "%B%"=="" GOTO :E
GOTO R
:E
ECHO %RE% >>"%~DP0转化后.TXT"
GOTO :EOF

复制代码

2012xb21cn · 发表于 2018-6-28 16:06:27

chiannet 发表于 2018-6-28 16:00
这个并不太好，比如以下字符串

那如何批量从文件中读取修改呢（每行都是类似数据）？试着改了下总不成功

chiannet · 发表于 2018-6-28 16:00:44

本帖最后由 chiannet 于 2018-6-28 16:02 编辑

2012xb21cn 发表于 2018-6-28 15:01
赞，这个思路不错

这个并不太好，比如以下字符串

1245.55,45.478,4264-5455.65,4.55

复制代码

如果要以","为分隔符，截取最右","之前的字符，如果把","替换为"."，再按文件名来整，显然会得错误结果。其实16楼的比较精炼了。

稍微改一下，还可以实现获取最左"."后的字符串等。

2012xb21cn · 发表于 2018-6-28 15:01:40

holley2008 发表于 2018-6-28 14:45
一样类似可以set定义.代替其它分隔符效果最明显不需要for或findstr查找半天。

赞，这个思路不错

xzf680 · 发表于 2018-6-28 14:02:04

### 友情提示：本脚本由 Au3.REHelper 于 2018/06/28 14:01 自动生成，不保证其正确性，请自行测试 ###
Local $sSource = '1245.5545.4784264-5455.65455'
;~MsgBox(0, '源字符串', $sSource)
Local $sSRERe = StringRegExpReplace($sSource, '(.*?)(.\w+), '$1')
MsgBox(0, '替换结果', $sSRERe)

复制代码

2012xb21cn · 发表于 2018-6-28 13:56:44

holley2008 发表于 2018-6-28 13:47
你想多了...
直接把其当做一个文件名

刚好凑巧分隔符是.，如果是其它字符就不行了

		自动登录	找回密码
密码			注册

[求助] 删除第N个某字符后面的所有字符

点评

点评

点评

评分

评分

评分

评分

浏览过的版块