设为首页收藏本站
开启辅助访问 切换到宽版

无忧启动论坛

 找回密码
 注册
搜索
无忧启动论坛»论坛 › ::启动制作:: › 综合讨论区 › 请教下局域网问题？
系统gho:最纯净好用系统下载站投放广告、加入VIP会员，请联系 微信:wuyouceo
返回列表 发新帖
查看: 4250|回复: 15
打印 上一主题 下一主题

[求助] 请教下局域网问题？

[复制链接]
mshuyi
跳转到指定楼层
1#
发表于 2018-12-4 08:37:35 | 只看该作者 回帖奖励 |正序浏览 |阅读模式
加入VIP会员，获无忧币，赠积分，送勋章，下载无限制，获论坛最高级会员权限 !
公司有几台电脑，通过运行IP可以相互访问，打开网上邻居，里面相互看不到，其中有2台是XP系统，有3台是WIN7系统，有2台是WIN10系统？
回复

使用道具 举报

推荐
发表于 2018-12-4 11:24:32 来自手机 | 只看该作者
建文件服务器，之前发过一个简陋版。
回复

使用道具 举报

16#
发表于 2018-12-4 17:18:29 | 只看该作者
弄个路由搭文件服务器或者FTP,比共享稳定多了...
回复

使用道具 举报

15#
发表于 2018-12-4 13:38:55 | 只看该作者
使用相同的SMB, 关掉用户的UAC。使用网路TCPIP4高级设置中的NETBIOS名。
回复

使用道具 举报

阿非
13#
发表于 2018-12-4 11:22:55 | 只看该作者
  1. @echo off
  2. color 2f
  3. mode con cols=50 lines=30
  4. title  OKShare  【制作：wnsdt】
  5. ver | findstr "6.">nul && set bulid=nt6 && goto sc_yhbl
  6. ver | findstr "10.">nul && set bulid=nt10 && goto sc_yhbl
  7. set bulid=nt5
  8. :sc_yhbl
  9. reg query "HKCU\Environment" /v temp >nul 2>nul||set "usertemp=%USERPROFILE%" && goto sc_top
  10. set usertemp=%temp%\
  11. :sc_top
  12. cls
  13. del /q %temp%\info.txt>nul 2>nul
  14. :sc_menu
  15. echo.&echo.&echo.
  16. echo             局域网共享一键修复 18.5.8
  17. echo.
  18. echo    --------------------------------------------
  19. echo.&echo.&echo.
  20. echo               1、查看网络信息
  21. echo.
  22. echo               2、简单共享（无密码）
  23. echo.
  24. echo               3、密码共享
  25. echo.
  26. echo               4、共享和权限管理
  27. echo.
  28. echo               5、权限设置指南（图文）
  29. echo.
  30. echo               6、打印机共享指南（图文）
  31. echo.
  32. echo               7、更新与反馈
  33. echo.&echo.&echo.&echo.&echo.
  34. set select=
  35. set str1=1234567
  36. set /p select= 输入数字，按回车:
  37. if not defined select goto sc_wrong
  38. echo %select%|findstr "[%str1%]">nul||goto sc_wrong
  39. if %select%==1 (goto sc_info)
  40. if %select%==2 (goto sc_zd)
  41. if %select%==3 (goto sc_sd)
  42. if %select%==4 (goto sc_gl)
  43. if %select%==5 (goto sc_help)
  44. if %select%==6 (goto sc_print)
  45. if %select%==7 (goto sc_update)
  46. :sc_wrong
  47. mshta vbscript:msgbox("只能输入1-7的数字",64,"提示")(window.close)
  48. goto sc_top
  49. :sc_info
  50. cls
  51. echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
  52. echo                  正在处理信息....
  53. if %bulid%==nt5 (goto sc_nt5) else (goto sc_nt6)
  54. :sc_nt5
  55. (echo.
  56. echo.)>>%usertemp%info.txt
  57. ping www.baidu.com -n 1 >nul || echo              互联网状态：       [ 离线 ]>>%usertemp%info.txt && goto sc_ver_nt5
  58. echo              互联网状态：       [ 在线 ]>>%usertemp%info.txt
  59. :sc_ver_nt5
  60. (echo ----------------------------------------------------------
  61. echo.)>>%usertemp%info.txt
  62. for /f "skip=1 tokens=2-4 delims=, " %%a in ('wmic os get caption') do (
  63. if exist %windir%\SysWOW64 echo         系统版本：       %%a %%b %%c  64位>>%usertemp%info.txt & goto sc_ver_nt5_next
  64. echo         系统版本：       %%a %%b %%c  32位>>%usertemp%info.txt
  65. )
  66. :sc_ver_nt5_next
  67. (echo.
  68. echo         计算机名：            %COMPUTERNAME%
  69. echo.)>>%usertemp%info.txt
  70. for /f "tokens=2 delims= " %%a in ('net config workstation^|findstr /c:"工作站域"') do echo         工作组：              %%a>>%usertemp%info.txt & goto sc_info_nt5
  71. :sc_info_nt5
  72. (echo.
  73. echo         当前用户：            %USERNAME%
  74. echo.)>>%usertemp%info.txt
  75. for /f "delims=" %%a in ('date /t') do echo         本机日期：            %%a>>%usertemp%info.txt
  76. echo.>>%usertemp%info.txt
  77. for /f "delims=" %%a in ('time /t') do echo         本机时间：            %%a>>%usertemp%info.txt
  78. echo ---------------------------------------------------------->>%usertemp%info.txt
  79. goto sc_info_more
  80. :sc_nt6
  81. (echo.
  82. echo.)>>%usertemp%info.txt
  83. ping www.baidu.com -n 1 >nul || echo          互联网状态：       [ 离线 ]>>%usertemp%info.txt && goto sc_ver_nt6
  84. echo          互联网状态：       [ 在线 ]>>%usertemp%info.txt
  85. :sc_ver_nt6
  86. (echo --------------------------------------------------
  87. echo.)>>%usertemp%info.txt
  88. for /f "skip=1 tokens=2-5 delims=?, " %%a in ('wmic os get caption') do (
  89. if exist %windir%\SysWOW64 echo    系统版本：      %%a %%b %%c %%d 64位>>%usertemp%info.txt & goto sc_ver_nt6_next
  90. echo    系统版本：       %%a %%b %%c %%d 32位>>%usertemp%info.txt
  91. )
  92. :sc_ver_nt6_next
  93. (echo.
  94. echo    计算机名：            %COMPUTERNAME%
  95. echo.)>>%usertemp%info.txt
  96. for /f "tokens=2 delims= " %%a in ('net config workstation^|findstr /c:"工作站域"') do echo    工作组：              %%a>>%usertemp%info.txt
  97. (echo.
  98. echo    当前用户：            %USERNAME%
  99. echo.)>>%usertemp%info.txt
  100. for /f "delims=" %%a in ('date /t') do echo    本机日期：            %%a>>%usertemp%info.txt
  101. echo.>>%usertemp%info.txt
  102. for /f "delims=" %%a in ('time /t') do echo    本机时间：            %%a>>%usertemp%info.txt
  103. echo -------------------------------------------------->>%usertemp%info.txt
  104. :sc_info_more
  105. if %bulid%==nt5 ipconfig /all|findstr /v /c:"Windows IP Configuration"|findstr /v /c:"Host Name"|findstr /v /c:"Primary Dns Suffix"|findstr /v /c:"Node Type"|findstr /v /c:"IP Routing Enabled"|findstr /v /c:"WINS Proxy Enabled">>%usertemp%info.txt && goto sc_info_next
  106. ipconfig /all|findstr /v /c:"Windows IP 配置"|findstr /v /c:"主机名"|findstr /v /c:"主 DNS 后缀"|findstr /v /c:"节点类型"|findstr /v /c:"IP 路由已启用"|findstr /v /c:"WINS 代理已启用">>%usertemp%info.txt
  107. :sc_info_next
  108. start /w notepad %temp%\info.txt
  109. del /q %temp%\info.txt>nul 2>nul
  110. goto sc_top
  111. :sc_zd
  112. call :sc_qxfix
  113. cls
  114. echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
  115. echo                    开始修复......
  116. net user guest /active:yes>nul 2>nul
  117. net user guest "">nul 2>nul
  118. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x1 /f>nul 2>nul
  119. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v LimitBlankPasswordUse /t REG_DWORD /d 0x0 /f>nul 2>nul
  120. goto sc_main
  121. :sc_sd
  122. call :sc_qxfix
  123. cls
  124. echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
  125. echo                    开始修复......
  126. net user guest /active:no>nul 2>nul
  127. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x0 /f>nul 2>nul
  128. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v NtlmMinClientSec /t REG_DWORD /d 0x0 /f>nul 2>nul
  129. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v NtlmMinServerSec /t REG_DWORD /d 0x0 /f>nul 2>nul
  130. goto sc_main
  131. :sc_main
  132. sc config LanmanWorkstation start= auto>nul 2>nul
  133. sc config LanmanServer start= auto>nul 2>nul
  134. sc config Winmgmt start= auto>nul 2>nul
  135. sc config RpcSs start= auto>nul 2>nul
  136. sc config Netman start= auto>nul 2>nul
  137. sc config RasMan start= demand>nul 2>nul
  138. sc config SSDPSRV start= auto>nul 2>nul
  139. sc config BFE start= auto>nul 2>nul
  140. sc config ALG start= demand>nul 2>nul
  141. sc config SharedAccess start= auto>nul 2>nul
  142. net start SharedAccess /y>nul 2>nul
  143. sc config Browser start= auto>nul 2>nul
  144. net start Browser /y>nul 2>nul
  145. sc config Dnscache start= auto>nul 2>nul
  146. net start Dnscache /y>nul 2>nul
  147. sc config Dhcp start= auto>nul 2>nul
  148. net start Dhcp /y>nul 2>nul
  149. sc config lmhosts start= auto>nul 2>nul
  150. net start lmhosts /y>nul 2>nul
  151. sc config Spooler start= auto>nul 2>nul
  152. net start Spooler /y>nul 2>nul
  153. sc config upnphost start= demand>nul 2>nul
  154. net start upnphost /y>nul 2>nul
  155. reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\Netlogon" /v Start|findstr "0x4">nul 2>nul && sc config Netlogon start= demand>nul 2>nul
  156. reg add "HKLM\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v TransportBindName /t REG_SZ /d \Device\ /f>nul 2>nul
  157. reg delete "HKLM\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v SMB1 /F>nul 2>nul
  158. reg delete "HKLM\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v SMB2 /F>nul 2>nul
  159. reg delete "HKLM\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v SMBDeviceEnabled /F>nul 2>nul
  160. sc config netbt start= system>nul 2>nul
  161. net start netbt>nul 2>nul
  162. if %bulid%==nt5 (goto sc_sernt5) else (goto sc_sernt6)
  163. :sc_sernt5
  164. sc config PlugPlay start= auto>nul 2>nul
  165. sc config TapiSrv start= auto>nul 2>nul
  166. sc config Nla start= auto>nul 2>nul
  167. net start Nla /y>nul 2>nul
  168. netsh firewall set opmode mode=disable>nul 2>nul
  169. goto sc_main2_etc
  170. :sc_sernt6
  171. sc config DcomLaunch start= auto>nul 2>nul
  172. sc config RpcEptMapper start= auto>nul 2>nul
  173. sc config SamSs start= auto>nul 2>nul
  174. sc config nsi start= auto>nul 2>nul
  175. sc config SstpSvc start= demand>nul 2>nul
  176. sc config MpsSvc start= auto>nul 2>nul
  177. net start MpsSvc /y>nul 2>nul
  178. sc config NlaSvc start= auto>nul 2>nul
  179. sc config netprofm start= auto>nul 2>nul
  180. sc config fdPHost start= auto>nul 2>nul
  181. net start fdPHost /y>nul 2>nul
  182. sc config FDResPub start= auto>nul 2>nul
  183. net start FDResPub /y>nul 2>nul
  184. sc config HomeGroupListener start= auto>nul 2>nul
  185. sc config WMPNetworkSvc start= auto>nul 2>nul
  186. net start WMPNetworkSvc /y>nul 2>nul
  187. sc config HomeGroupProvider start= auto>nul 2>nul
  188. net start HomeGroupProvider /y>nul 2>nul
  189. netsh advfirewall set allprofiles state off>nul 2>nul
  190. :sc_main2_etc
  191. (echo [Unicode]
  192. echo Unicode=yes
  193. echo [Version]
  194. echo signature="$CHICAGO$"
  195. echo Revision=1
  196. echo [Privilege Rights]
  197. echo sedenynetworklogonright =
  198. echo senetworklogonright = Everyone,Administrators,Users,Power Users,Backup Operators,guest)>>%usertemp%zcl.inf
  199. secedit /configure /db %usertemp%zcl.sdb /cfg %usertemp%zcl.inf /log %usertemp%zcl.log /quiet
  200. del /q %usertemp%zcl.*>nul 2>nul
  201. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa\MSV1_0" /v LmCompatibilityLevel /t REG_DWORD /d 0x1 /f>nul 2>nul
  202. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v restrictanonymous /t REG_DWORD /d 0x0 /f>nul 2>nul
  203. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v restrictanonymoussam /t REG_DWORD /d 0x0 /f>nul 2>nul
  204. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v everyoneincludesanonymous /t REG_DWORD /d 0x1 /f>nul 2>nul
  205. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v NoLmHash /t REG_DWORD /d 0x0 /f>nul 2>nul
  206. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v AutoShareServer /t REG_DWORD /d 0x1 /f>nul 2>nul
  207. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v AutoShareWks /t REG_DWORD /d 0x1 /f>nul 2>nul
  208. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v restrictnullsessaccess /t REG_DWORD /d 0x0 /f>nul 2>nul
  209. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Browser\Parameters" /v MaintainServerList /t REG_SZ /d Auto /f>nul 2>nul
  210. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Browser\Parameters" /v IsDomainMaster /t REG_SZ /d FALSE /f>nul 2>nul
  211. for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters\Interfaces" /s /e /f "0x2"^|findstr "\Tcpip_"') do reg add "%%a" /v NetbiosOptions /t REG_DWORD /d 0x0 /f>nul 2>nul
  212. reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v EnableLMHOSTS|findstr "0x0">nul 2>nul && reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\NetBT\Parameters" /v EnableLMHOSTS /t REG_DWORD /d 0x1 /f>nul 2>nul
  213. reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\RemoteComputer\NameSpace\{D6277990-4C6A-11CF-8D87-00AA0060F5BF}" /f>nul 2>nul
  214. net use * /del /y>nul 2>nul
  215. net config server /hidden:no>nul 2>nul
  216. net share ipc$>nul 2>nul
  217. if %bulid%==nt10 powershell -NonInteractive "Enable-WindowsOptionalFeature -Online -FeatureName SMB1Protocol">nul 2>nul && reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\LanmanWorkstation\Parameters" /v AllowInsecureGuestAuth /t REG_DWORD /d 0x1 /f>nul 2>nul
  218. goto sc_tip
  219. :sc_gl
  220. cls
  221. reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest|findstr "0x1">nul 2>nul||goto classic
  222. reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x0 /f>nul 2>nul
  223. set jlb=y
  224. :classic
  225. echo.&echo.&echo.&echo.
  226. echo          功能：管理本机共享，修改共享权限
  227. echo   ----------------------------------------------
  228. echo.&echo.&echo.&echo.&echo.
  229. echo                    【使用说明】
  230. echo.&echo.
  231. echo        点左侧“共享”可查看本机所有共享；
  232. echo.
  233. echo        右键点左侧“共享”可“新建共享”；
  234. echo.
  235. echo        右键点右侧共享可“停止共享”（能多选）；
  236. echo.
  237. echo        右键点右侧共享选“属性”可修改权限；
  238. echo.&echo.&echo.&echo.&echo.&echo.&echo.
  239. fsmgmt.msc
  240. if %jlb%==y reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 0x1 /f>nul 2>nul
  241. goto sc_top
  242. :sc_tip
  243. cls
  244. echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
  245. echo                    修复已完成！！！
  246. mshta vbscript:msgbox("请手动重启计算机",64,"提示")(window.close)
  247. exit
  248. :sc_help
  249. cls
  250. start "%ProgramFiles%\Internet Explorer\iexplore.exe" "https://zhuanlan.zhihu.com/p/24285252"
  251. goto sc_top
  252. :sc_print
  253. cls
  254. start "%ProgramFiles%\Internet Explorer\iexplore.exe" "https://zhuanlan.zhihu.com/p/24187152"
  255. goto sc_top
  256. :sc_update
  257. cls
  258. start "%ProgramFiles%\Internet Explorer\iexplore.exe" "https://zhuanlan.zhihu.com/p/24178142"
  259. goto sc_top
  260. goto :eof
  261. :sc_qxfix
  262. cls
  263. echo.&echo.&echo.
  264. echo                     【使用说明】
  265. echo    --------------------------------------------
  266. echo.
  267. echo          复制共享文件夹的地址栏路径到下方
  268. echo.
  269. echo           如果只共享打印机，按回车键跳过
  270. echo.&echo.&echo.&echo.&echo.&echo.&echo.
  271. echo 粘贴路径，按回车:
  272. echo.&echo.
  273. set /p lj=
  274. for %%a in ("%lj%") do set name=%%~na
  275. net share "%name%"="%lj%">nul 2>nul
  276. if %bulid%==nt5 cacls "%lj%" /t /e /p everyone:f >nul 2>nul && goto :eof
  277. icacls "%lj%" /grant everyone:(oi)(ci)f>nul 2>nul
  278. goto :eof
复制代码

评分

参与人数 1无忧币 +5 收起 理由
sx3k + 5 很给力!

查看全部评分

回复

使用道具 举报

阿非
12#
发表于 2018-12-4 11:21:40 | 只看该作者
https://zhuanlan.zhihu.com/p/24178142
回复

使用道具 举报

mshuyi
11#
 楼主| 发表于 2018-12-4 11:01:37 | 只看该作者
qh6420933 发表于 2018-12-4 10:44
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=409132
用这个工具试试

试一试看行不行，谢谢
回复

使用道具 举报

mshuyi
10#
 楼主| 发表于 2018-12-4 10:57:53 | 只看该作者
窄口牛 发表于 2018-12-4 09:02
批处理搞个文件服务器，别纠结它了

请教下批处理怎么编辑，谢谢
回复

使用道具 举报

mshuyi
9#
 楼主| 发表于 2018-12-4 10:57:46 | 只看该作者
窄口牛 发表于 2018-12-4 09:02
批处理搞个文件服务器，别纠结它了

请教下批处理怎么编辑，谢谢
回复

使用道具 举报

mshuyi
8#
 楼主| 发表于 2018-12-4 10:57:17 | 只看该作者
窄口牛 发表于 2018-12-4 09:02
批处理搞个文件服务器，别纠结它了

怎么搞？
回复

使用道具 举报

7#
发表于 2018-12-4 10:44:39 | 只看该作者
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=409132
用这个工具试试

点评

mshuyi
试一试看行不行，谢谢  详情 回复 发表于 2018-12-4 11:01
回复

使用道具 举报

mshuyi
6#
 楼主| 发表于 2018-12-4 10:23:13 | 只看该作者
叶知秋 发表于 2018-12-4 10:11
看看是不是同一个工作组，不是同一个工作组，是看不到的

是在同一个工作组
回复

使用道具 举报

mshuyi
5#
 楼主| 发表于 2018-12-4 10:22:58 | 只看该作者
熄灭的火焰 发表于 2018-12-4 09:12
computer browser服务开了没，
Workstation服务开了没

都开 了的
回复

使用道具 举报

4#
发表于 2018-12-4 10:11:59 | 只看该作者
看看是不是同一个工作组，不是同一个工作组，是看不到的

点评

mshuyi
是在同一个工作组  详情 回复 发表于 2018-12-4 10:23
回复

使用道具 举报

3#
发表于 2018-12-4 09:12:59 | 只看该作者
computer browser服务开了没，
Workstation服务开了没

点评

mshuyi
都开 了的  详情 回复 发表于 2018-12-4 10:22
回复

使用道具 举报

2#
发表于 2018-12-4 09:02:59 | 只看该作者
批处理搞个文件服务器，别纠结它了

点评

mshuyi
请教下批处理怎么编辑，谢谢  详情 回复 发表于 2018-12-4 10:57
mshuyi
请教下批处理怎么编辑，谢谢  详情 回复 发表于 2018-12-4 10:57
mshuyi
怎么搞？  详情 回复 发表于 2018-12-4 10:57
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|捐助支持|无忧启动 ( 闽ICP备05002490号-1 )

闽公网安备 35020302032614号

GMT+8, 2024-11-27 06:15

Powered by Discuz! X3.3

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表