|
|
本帖最后由 土豆蓝 于 2023-2-23 09:24 编辑
我的养老模式：
虚拟内存盘C：完全镜像40G延时启动关联镜像SYSTEM.vdf/SYSTEM1.vdf保存需手动
虚拟内存盘U：完全镜像10G延时启动关联镜像USER.vdf关机自动保存
虚拟内存盘Z：无镜像1T无保存
各虚拟内存盘的作用：
C：系统盘，SYSTEM.vdf和SYSTEM1.vdf都是延时启动的，如果当前系统关联镜像SYSTEM.vdf那么手动保存会将C盘变化保存到SYSTEM1.vdf，重启则自动进入SYSTEM1.vdf关联的镜像系统，反之也一样，这两个镜像互为备份。为什么做两个vdf置换保存呢？是因为延时模式的C盘要稳妥的保存完整数据需要用primo自带的保存，先注销在保存，但是这样会把垃圾保存进去，我有点洁癖，对C盘的变化使用GoodSync软件同步，它的排除过滤功能不同步那些指定的垃圾文件。恰好GoodSync也有命令行，所以整个手动保存过程可以写成一个批处理，只在安装新的软件时手动保存，常年无维护
U：用户数据盘，用来保存我认为有用的数据例如微信、QQ、浏览器、输入法的数据以及各个软件的配置数据，桌面、桌面背景、NTUSER（桌面图标位置等一些用户自定义的数据）、USERCLASS（默认程序的打开方式），大部分是软链到U：的，自动保存。
Z：存放缓存等临时文件例如系统TEMP，浏览器缓存等一些没用但是不停产生的垃圾。重启不保存。
我的本子有128G 内存，但是我还是选择了延时模式，因为我想开机快一点，延时模式开机和正常系统开机速度无异，又因为想要干净的保存一个系统，做了两个C盘的关联镜像，互为备份保存操作后会自动换另一个启动。如果不满意新的保存效果可以直接进入那个未更改的关联镜像系统重新调整。
关于延时模式，它的小文件读取方式是数据块状连续读取，之前在一个USB2.0的16GU盘上跑过延时模式下的系统测试软件开启速度，让我很惊讶的是没有卡顿，但是VHD的WTG基本上卡的动不了，而且延时模式的开机速度很快，延时模式是一种很优秀的模式。
那么这样我就在这个启动快速、备份保命、大部分我想保存的数据都自动保存、我不想保存的数据断电消失、C盘洁净体积可控增长的模式下养老了。
偶尔会上论坛，但是觉得RAMOS也即将作古，随着高速存储的普及，RAMOS终将越来越小众化。我内心涌上一阵悲伤，终究是对自己一段回忆说再见了。
以下是我用的保存P：
----------------------------------------------------------------------------------------------------------
@echo off&setlocal enabledelayedexpansion
rem 定义变量延迟环境，关闭回显
rem 设置置换镜像的路径
set aa=SYSTEM.vdf
set bb=SYSTEM1.vdf
rem 设置系统C盘的ramdisk盘号
set cc=2
rem 设置卷号次序，如1 2 3 4 5...
set volume=1
rem 设置menu.lst中要置换启动的启动项号
set flag0=0
set flag1=1
rem 删除上次生成的GUID.txt
del GUID.txt /f /q
rem 生成新的GUID.txt
for /f "tokens=2 delims={}" %%i in ('mountvol') do (
echo %%i>>GUID.txt
)
rem 从新生成的GUID.txt读取固定卷号的GUID值,并生成路径
for /f "tokens=*" %%i in (GUID.txt) do (
set /a num+=1
if !num! equ %volume% (
set path1=\\?\Volume{%%i}\EFI\grub\menu.lst
set path2=\\?\Volume{%%i}\EFI\grub\biosmenu.lst
)
)
rem 判断当前系统关联镜像,修改启动项+修改关联镜像+挂载置换镜像
"C:\Program Files\Primo Ramdisk\rxprd.exe" view %cc%| findstr %aa% >nul && (
call :ch1
imdisk -a -b 2048b -m A: -f "D:\System Volume Information\SYSTEM1.vdf"
) || (
call :ch0
imdisk -a -b 2048b -m A: -f "D:\System Volume Information\SYSTEM.vdf"
)
rem 保存更改到置换镜像
U:\M\保存\gsync.exe job R-FBWF /sync
Reg save HKLM\system A:\Windows\system32\config\SYSTEM /y
Reg save HKLM\drivers A:\Windows\system32\config\DRIVERS /y
Reg save HKLM\software A:\Windows\system32\config\SOFTWARE /y
Reg save HKU\.DEFAULT A:\Windows\system32\config\DEFAULT /y
Reg save HKLM\SAM A:\Windows\system32\config\SAM /y
Reg save HKLM\SECURITY A:\Windows\system32\config\SECURITY /y
Reg save HKCU U:\M\USRDAT\BAK\NTUSER.DAT /Y
Reg save HKCU\software\classes U:\M\USRDAT\BAK\UsrClass.dat /y
Reg save HKU\S-1-5-19 A:\Windows\ServiceProfiles\LocalService\NTUSER.DAT /y
Reg save HKU\S-1-5-20 A:\Windows\ServiceProfiles\NetworkService\NTUSER.DAT /y
pause
imdisk -D -m A:
exit /b
rem 修改默认启动项为0,关联镜像为SYSTEM.vdf
:ch0
call :bootflags %path1%,%flag1%,%flag0%
call :bootflags %path2%,%flag1%,%flag0%
regedit /s SYSTEM.reg
goto:eof
rem 修改默认启动项为1,关联镜像为SYSTEM1.vdf
:ch1
call :bootflags %path1%,%flag0%,%flag1%
call :bootflags %path2%,%flag0%,%flag1%
regedit /s SYSTEM1.reg
goto:eof
:bootflags
rem 参数是 %0,%1,...%n
rem 读取a.txt所有内容
for /f "eol=* tokens=*" %%i in (%1) do (
rem 设置变量a为每行内容
set a=%%i
rem 如果该行有123，则将其改为456
set "a=!a:default %2=default %3!"
rem 把修改后的全部行存入$
echo !a!>>$)
rem 用$的内容替换原来a.txt内容
move $ %1
goto:eof
-----------------------------------------------------------------------------------------------------------
GoodSync自定义的同步规则
|
评分
-
查看全部评分
|
[复制链接]
IP卡
狗仔卡
发表于 2023-2-22 20:32:29
收藏
支持
反对
提升卡
沉默卡
喧嚣卡
变色卡
千斤顶
显身卡
