快速安装VHD系统的批处理

baby1277 · 发表于 2025-2-24 22:05:39

本帖最后由 baby1277 于 2025-3-5 14:03 编辑

帮助新手快速安装VHD系统，傻瓜式操作比WinNTSetup更简单。

不需要掌握系统启动和VHD系统相关知识，支持Win7-Win11 32位和64位系统。

只需将系统映像文件拖进来按回车键，把所有繁琐的步骤交给批处理来完成。

简单的测试下没有发现问题，若有问题或者建议跟帖留言。

@echo off
title (快速安装VHD系统 By baby1277 2025.3.5)
:: 拖拽操作支持
set wim=%~1
if defined wim goto wimok
:vhdset
cls&echo.
if defined cuo echo.&echo 安装遇到了问题，不支持的系统映像。&echo.
echo 请将Wim或者Esd映像文件拖拽进来后按回车键
echo.
set /p wim=
:wimok
:: 检查映像文件路径正确性
for /f "delims=" %%i in ('echo %wim%') do (
if /i not "%%~xi"==".wim" if /i not "%%~xi"==".esd" goto vhdset
if not exist "%%~fi" goto vhdset
set wim2=%%~fi
set wimN=%%~ni
)
:: 判断映像文件的系统版本来设置VHD磁盘格式
for /f "tokens=2-4" %%i in ('dism /get-wiminfo /wimfile:"%wim2%"^|find "名称"') do (
if %%j equ 7 set nx=.vhd&goto nxok
if %%j equ 8 set nx=.vhdx&goto nxok
if %%j equ 8.1 set nx=.vhdx&goto nxok
if %%j equ 10 set nx=.vhdx&goto nxok
if %%j equ 11 set nx=.vhdx&goto nxok
echo %%i%%j%%k|find /i "win7">nul&&set nx=.vhd&goto nxok
echo %%i%%j%%k|find /i "windows7">nul&&set nx=.vhd&goto nxok
for %%a in (8 8.1 10 11) do echo "%%i%%j%%k"|find /i "win%%a">nul&&set nx=.vhdx&goto nxok
for %%b in (8 8.1 10 11) do echo "%%i%%j%%k"|find /i "windows%%b">nul&&set nx=.vhdx&goto nxok
)
echo "%wimN%"|find /i "win7">nul&&set nx=.vhd&goto nxok
echo "%wimN%"|find /i "windows7">nul&&set nx=.vhd&goto nxok
for %%i in (8 8.1 10 11) do echo "%wimN%"|find /i "win%%i">nul&&set nx=.vhdx&goto nxok
for %%i in (8 8.1 10 11) do echo "%wimN%"|find /i "windows%%i">nul&&set nx=.vhdx
:nxok
if not defined nx set cuo=0&goto vhdset
:: 设置VHD文件位置
set "vhdPath=%~d0\WinVHD_%random:~-2%%nx%"
:: 获取Wim/Esd映像文件索引
for /f "tokens=1-4" %%i in ('dism /get-wiminfo /wimfile:"%wim2%"') do (
if "%%i"=="索引:" set mod=%%j
if /i "%%l"=="Ultimate" set ver2=旗舰版&goto ver1
if /i "%%l"=="Enterprise" set ver2=企业版&goto ver1
if "%%l"=="企业版" set ver2=企业版&goto ver1
if /i "%%l"=="lot" set ver2=lot企业版&goto ver1
if "%nx%"==".vhdx" if /i "%%l"=="Pro" set ver2=专业版&goto ver1
if "%nx%"==".vhdx" if /i "%%l"=="Professional" set ver2=专业版&goto ver1
if "%nx%"==".vhdx" if "%%l"=="专业版" set ver2=专业版&goto ver1
)
:ver1
if not defined mod set cuo=0&goto vhdset
:: 设置VHD磁盘卷标
set vhdname=WindowsVHD
:: 设置VHD文件大小
set vhdSize=60
set /a vhdSize2=vhdSize*1024
:: 显示Wim/Esd文件系统版本和索引
echo.&echo 映像：%wim2% 支持安装VHD系统的版本&echo.
setlocal enabledelayedexpansion
for /f "skip=4 delims=" %%i in ('dism /get-wiminfo /wimfile:"%wim2%"^|find /i /v "home"^|find /v "家庭"') do (
for /f "delims=" %%a in ('echo %%i^|find "索引"') do set mod3=%%a
for /f "delims=" %%b in ('echo %%i^|find "名称"') do set mod4=%%b
if defined mod4 if "%nx%"==".vhd" echo !mod4!|find /i "pro">nul&&set mod4=
if defined mod4 if "%nx%"==".vhd" echo !mod4!|find "专业版">nul&&set mod4=
if defined mod4 echo !mod3! !mod4!&set mod3=&set mod4=
)
setlocal disabledelayedexpansion
:: 显示VHD系统安装参数
echo.&echo =================VHD系统参数=================
echo.
echo VHD磁盘卷标：%vhdname%
echo.
echo VHD文件位置：%vhdPath%
echo.
echo VHD文件大小：%vhdSize% GB
echo.
echo Wim/Esd位置：%wim2%
echo.
echo Wim/Esd索引：%mod% %ver2%
echo.
echo 请确认以上VHD参数没有问题可以直接按回车键继续
echo.
set /p mod2=如需要安装其他版本则输入对应索引号按回车键继续：
if defined mod2 set mod=%mod2%
:: 创建并加载VHD磁盘
for %%i in (R S T U V W Y Z) do if not exist %%i: set pan=%%i
(echo create vdisk file="%vhdPath%" maximum=%vhdSize2% type=expandable&^
echo Select vdisk file="%vhdPath%"&^
echo attach vdisk&^
echo create partition primary&^
echo format quick fs=ntfs label="%vhdname%"&^
echo assign letter=%pan%:&^
echo exit)|diskpart
:: 应用系统镜像到VHD磁盘
dism /apply-image /imagefile:"%wim2%" /index:%mod% /applydir:%pan%:\
:: 配置引导记录
bcdboot %pan%:\Windows /l zh-ch
if %errorlevel% equ 0 set vhdSetup=ok
if not defined vhdSetup goto cuo2
:: 安装成功设置引导程序
bcdedit /timeout 3
bcdedit /set {bootmgr} Locale zh-cn
:: 部署自动应答文件
set yinda=%pan%:\Windows\Panther\unattend.xml
if exist %yinda% goto cuo2
md %pan%:\Windows\Panther
if exist %pan%:\Windows\Syswow64 (set sysbit=amd64) else set sysbit=x86
echo ^<?xml version='1.0' encoding='utf-8'?^>>%yinda%
echo ^<unattend xmlns="urn:schemas-microsoft-com:unattend"^>>>%yinda%
echo ^<settings pass="oobeSystem"^>>>%yinda%
echo ^<component name="Microsoft-Windows-Shell-Setup" processorArchitecture="%sysbit%" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"^>>>%yinda%
echo ^<AutoLogon^>>>%yinda%
echo ^<Enabled^>true^</Enabled^>>>%yinda%
echo ^<Username^>Administrator^</Username^>>>%yinda%
echo ^</AutoLogon^>>>%yinda%
echo ^<OOBE^>>>%yinda%
echo ^<SkipMachineOOBE^>true^</SkipMachineOOBE^>>>%yinda%
echo ^</OOBE^>>>%yinda%
echo ^</component^>>>%yinda%
echo ^</settings^>>>%yinda%
echo ^</unattend^>>>%yinda%
:: 安装失败返回
:cuo2
(echo select vdisk file="%vhdPath%"&echo detach vdisk)|diskpart
if defined vhdSetup Shutdown -r -f -t 0&exit
del /f /q "%wim2%"
set cuo=0&goto vhdset

复制代码

快速安装VHD系统20250305.zip (2.27 KB, 下载次数: 249)

Askyt · 发表于 2025-12-26 21:34:23

试试，谢谢分享

showlin615 · 发表于 2025-12-26 13:49:43

感谢分享

wychun · 发表于 2025-12-26 08:22:26

不错不错，谢谢
分享

ewq11111 · 发表于 2025-12-14 18:11:02

谢谢分享

ewq11111 · 发表于 2025-12-14 18:09:38

谢谢分享

yourfellow · 发表于 2025-12-14 17:51:39

批处理安装，不知道好用不，谢谢

liuyang2025 · 发表于 2025-12-14 10:33:18

支持开源

lekeil · 发表于 2025-12-14 10:20:39

板凳支持

qj_tzy · 发表于 2025-12-8 11:23:51

这个对新手和老手来说，都是福利，下载使用，感谢！

12qaz · 发表于 2025-12-4 13:04:16

感谢分享

john138 · 发表于 2025-11-26 00:26:14

感谢分享

yourfellow · 发表于 2025-11-24 19:26:34

不知道安装的系统有没有优化》

sookj · 发表于 2025-11-24 14:55:19

感谢分享

Paudy · 发表于 2025-11-24 14:27:14

谢谢分享

a272121742 · 发表于 2025-11-13 12:52:34

感谢分享！

xpzzj · 发表于 2025-11-11 09:39:49

多谢分享！

hntjb · 发表于 2025-11-11 08:51:56

谢谢分享，好用收下

yujianshiqiu · 发表于 2025-11-11 07:21:43

感谢分享好东东

Forget_dust · 发表于 2025-11-6 10:32:15

感谢分享

seeimpact153 · 发表于 2025-11-4 16:43:38

感谢分享好东西

siliuqi467 · 发表于 2025-10-31 13:07:13

大佬，封装的系统支持吗？

肉仔 · 发表于 2025-8-26 13:13:32

感谢分享

wqsohu · 发表于 2025-8-26 08:52:09

谢谢分享

神秘的受气包 · 发表于 2025-8-21 11:50:04

谢谢分享

201012121135 · 发表于 2025-8-18 19:50:40

谢谢分享

wqsohu · 发表于 2025-8-8 09:02:15

谢谢分享

feige001 · 发表于 2025-6-13 09:43:21

baby1277 发表于 2025-6-12 10:22
xp就不要想，xp时代uefi都还没有出来。
uefi出来的时候Win7都快停止更新了，所以对uefi的支持兼容性有点 ...

确实是，老老实实用mbr吧，对于单位老电脑也是服了！

baby1277 · 发表于 2025-6-12 10:22:12

feige001 发表于 2025-6-12 08:31
请教下，我的时gpt uefi 引导的win11，为什么安装winxp 和win7 的vhd总是到重启进不了系统？

xp就不要想，xp时代uefi都还没有出来。
uefi出来的时候Win7都快停止更新了，所以对uefi的支持兼容性有点差。
我记得Win7要完美的支持uefi需要打上一个更新补丁，你去IT天空看下这篇帖子。
https://www.itsk.com/thread/427491

或者用第三方引导 XORBOOT 和 GRUB4DOS 都可以启动，只是第三方启动需要拥有
很强的动手能力，比如离线打驱动，编写引导菜单就劝退大多数的网友。

yhage · 发表于 2025-6-12 08:48:09

很不错的批处理，多谢！

201012121135 · 发表于 2025-6-12 08:40:25

谢谢分享

		自动登录	找回密码
密码			注册

[分享] 快速安装VHD系统的批处理

浏览过的版块