公开PE安装到硬盘的批处理代码并求教个问题

TCLSHX

以下是我用的安装通用PE工具箱1.91到硬盘的代码,是从光盘上在WINDOWS下安装到系统分区的, 但我在VPC里却无法在PE环境下运行这个批处理,不知哪位高手能否指点一下,下面代码我已做了部分解释,便于新手学习.....
这段代码已提供卸载或重复安装操作....



@echo off
COLOR 2F
echo.
echo.
echo            ╭⌒╮┅~ ¤　 ╭⌒╮ ╭⌒╮   ⌒╮~                        
echo           ╭⌒╭⌒╮╭⌒╮～╭⌒╮︶︶,　︶︶              
echo           ,︶︶︶︶,''︶~~ ''~︶︶　 ,''    ~~               
echo           ╬╬╱◥███◣╬╬╬╬╬╬╬╬╬╬╬
echo           ╬ ︱田︱田 田 ︱ PE安装卸载小程序　╬
echo           ╬　　　　　　　　　　　　　　　　　╬
echo           ╬╬╬╬╬╬╬╬╬╬╬╬╬╬╬╬╬╬╬
echo.
echo.
Echo 确认要进行PE系统的安装或卸载操作吗.....
PAUSE>NUL
CLS
REM 在各分区中找BOOT.INI系统文件  
Set TC=TC
For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set TC=%%I:
If %TC%==TC Goto 120000
CLS
Echo.
Echo.
Echo 已在%TC%分区中找到BOOT.INI系统文件,此分区可安装PE,是否进行操作,请做选择....
PAUSE>NUL
CLS
REM 若在BOOT.INI中某行找到%TC%\WXPE\PELOAD=字符串,则卸载或重装.
Attrib -S -H -R %TC%\boot.ini
FIND /I "PELOAD=" %TC%\boot.ini >NUL
If %Errorlevel%==0 Goto 3000
:T100
CLS
Echo.
Echo.
Echo 选择1,立即安装PE到%TC%分区
Echo.
Echo 选择2,不安装PE,退出...
Echo.
Echo.
Echo.
Set Cho100=
Set /P Cho100=请选择要进行的操作 (1/2) ，然后回车:
If %Cho100%Cho100==Cho100 Goto T100
If Not '%Cho100%'=='' SET Cho100=%Cho100:~0,1%
If /I '%Cho100%'=='1' GOTO 130000
If /I '%Cho100%'=='2' Attrib +S +H +R %TC%\boot.ini&&Exit
GOTO T100
:130000
CLS
echo.
echo.
echo.
echo 正在安装,请稍后......
Attrib -S -H -R %TC%\boot.ini
REM 把%TC%\WXPE\PELOAD="急救中心"写进%TC%\BOOT.INI
Echo %TC%\WXPE\PELOAD="急救中心" >>%TC%\BOOT.INI
REM 强行覆盖%TC%盘PELDR(即强行复制)
XCOPY PELDR %TC% /Y /R>NUL
REM 强行建%TC%\PETools目录,并复制..\PETools中类容到其中,也即强行覆盖%TC%\PETools
XCOPY ..\PETools /E %TC%\PETools\ /Y /R>NUL
REM 强行建%TC%\WXPE目录,并复制LDRXPE到其中
XCOPY LDRXPE /E %TC%\WXPE\ /Y /R>NUL
REM 因%TC%盘已存在刚建好的WXPE目录,可复制其它文件到其中
COPY PELOAD %TC%\WXPE /Y>NUL
COPY ..\WXPE\WINPE.IS_ %TC%\WXPE /Y>NUL
COPY ..\WXPE\BFONT.B %TC%\WXPE /Y>NUL
COPY ..\WXPE\NTDET.C %TC%\WXPE /Y>NUL
COPY ..\WXPE\PE.X %TC%\WXPE /Y>NUL
REM 隐藏文件
Attrib +S +H +R %TC%\boot.ini
Attrib +S +H +R %TC%\PELDR
REM 隐藏目录
Attrib +S +H +R %TC%\PETools /S /D
Attrib +S +H +R %TC%\WXPE /S /D
CLS
echo.
echo.
echo.
Echo PE系统安装成功.....
PAUSE>NUL
Exit
:3000
CLS
echo.
echo.
echo.
echo %TC%\系统分区已安装了PE系统......
Echo.
Echo.
Echo 选择1,重新安装PE到%TC%分区
Echo.
Echo 选择2,不重装PE,退出...
Echo.
Echo 选择3,卸载PE...
Echo.
Echo.
Echo.
Set Cho100=
Set /P Cho100=请选择要进行的操作 (1/2) ，然后回车:
If %Cho100%Cho100==Cho100 Goto 3000
If Not '%Cho100%'=='' SET Cho100=%Cho100:~0,1%
If /I '%Cho100%'=='1' GOTO 10000
If /I '%Cho100%'=='2' Attrib +S +H +R %TC%\boot.ini&&Exit
If /I '%Cho100%'=='3' GOTO 20000
GOTO 3000
:10000
REM 若在BOOT.INI中某行找到%TC%\WXPE\PELOAD=字符串,则删除此行.
Attrib -S -H -R %TC%\boot.ini
for /f "delims=" %%i in ('findstr /i /v / PELOAD= %TC%\BOOT.INI') do (
    echo %%i>>%TC%\temp.txt
)
DEL %TC%\BOOT.INI /Q>NUL
COPY %TC%\temp.txt %TC%\BOOT.INI /Y>NUL
DEL %TC%\temp.txt /Q>NUL
GOTO 130000
REM 卸载PE
:20000
REM 强行删除目录(包括隐藏目录和文件)
RD %TC%\WXPE /S /Q>NUL
RD %TC%\PETools /S /Q>NUL
Attrib -S -H -R %TC%\boot.ini
Attrib -S -H -R %TC%\PELDR
REM 若在BOOT.INI中某行找到%TC%\WXPE\PELOAD=字符串,则删除此行.
Attrib -S -H -R %TC%\boot.ini
for /f "delims=" %%i in ('findstr /i /v / PELOAD= %TC%\BOOT.INI') do (
    echo %%i>>%TC%\temp.txt
)
DEL %TC%\BOOT.INI /Q>NUL
COPY %TC%\temp.txt %TC%\BOOT.INI /Y>NUL
DEL %TC%\temp.txt /Q>NUL
DEL %TC%\PELDR /Q>NUL
Attrib +S +H +R %TC%\boot.ini
CLS
echo.
echo.
echo.
Echo PE系统成功卸载.....
PAUSE>NUL
Exit
:120000
CLS
Echo.
Echo.
Echo.
Echo 没有发现系统文件,无法安装.....
PAUSE>NUL  
Exit



有几年没到无忧发帖了,现在高手如云啊,厉害...........

[ 本帖最后由 TCLSHX 于 2009-10-7 13:36 编辑 ]