[严重分享１０.９更新PE、windows通用]100%免配的PXE网启服务器CMD（DHCP、TFTPD32）

歌理

1、严重声明：本人绝不是什么大侠，充其量是个爱好者
2、这个CMD就是CMD命令，不是什么编程语言

wlue

原帖由 歌理 于 2009-9-30 20:02 发表
1、严重声明：本人绝不是什么大侠，充其量是个爱好者
2、这个CMD就是CMD命令，不是什么编程语言

谢谢歌理大侠，你出手真快，不必谦虚！
你的新CMD真是太好了！
今天等不上你，根据我的情况，我自己在摸索半天，刚才终于也实现了我在25#的要求：

@echo off
PUSHD %~dp0
SET TP=%CD%
SET DP=%TP:~0,-7%
rem ==========以下此行为启动引导文件，请自行修改＝＝＝＝＝＝＝
set bootfile=PXELINUX.0
rem ==========================================================
dhcp4nt.exe -remove
set BaseDirectory=%DP%
rem if not %tp:~-1%==\ set BaseDirectory=%TP%\

我采用笨办法，截取路径字符串，虽然实现了，但方法太笨，现在有你的更专业的方法太好了，我原来的方法可以丢掉了！
另外上边红字的一行到底有什么用，我把它注释掉，好像也不影响使用！

建议将你的免配置脚本放首页，让更多的人分享！（这个比PE下的配置更实用，因为PE系统下多数都由作者配置好了）

jalousie

支持下，暂时没网启需要

wlue

原帖由 歌理 于 2009-9-30 19:55 发表
WINDOWS 网启服务器免配CMD
说明：1、请将本CMD 与 启动文件%bootfile%  放于同一目录
      　2、DHCP4NT服务程序可以放于本CMD目录下的任意子目录，其启动文件名必须是：DHCP4NT.exe
........
%tp%\dhcp4nt.exe -install
%tp%\dhcpsrv.cpl
EXIT
.....

反馈一点小问题，这个批处理很好，只是执行完不会自动关闭DOS窗口，在红字这一行前面加上　start %tp%\dhcpsrv.cpl　后问题解决！

歌理

WINDOWS 网启服务器免配CMD
这个是真正的免配，可任意绿色移植。


rem WINDOWS网启服务端.CMD
@echo off
PUSHD %~dp0
SET TP=%CD%
rem ==========以下此行为启动引导文件，请自行修改,启动文件与本cmd同分区即可＝＝＝＝＝＝＝
set bootfile=PXEgrldr.0
rem ==========================================================

if not exist %TP%\dhcp4nt.exe echo 当前目录下找不到文件：DHCP4NT.EXE &&pause &&exit

echo 正在自动搜索启动文件，可能需要一些时间，请稍等。。。
set BaseDirectory=
set  bootdrver=%~d0
for /f "usebackq" %%i in (`dir "%bootdrver%\%bootfile%" /s/b`) do set BaseDirectory=%%~dpi
if %BaseDirectory%.==. echo 在 %bootdrver%盘上 找不到启动文件：%bootfile%  &&pause

%TP%\dhcp4nt.exe -remove
setlocal
set/a a=-2
for /f "usebackq tokens=2 delims=:" %%i in (`ipconfig`) do (
set b=%%i
call :getip
)

for /f "tokens=1-3,4 delims=." %%i in ("%_myip%") do set IP_Pool=%%i.%%j.%%k.100
>%TP%\DHCPsrv.ini echo.[License]
>>%TP%\DHCPsrv.ini echo.Key=BBLZ26803UBBCAT9
>>%TP%\DHCPsrv.ini echo.Name=Free User
>>%TP%\DHCPsrv.ini echo.[DHCPsrv]
>>%TP%\DHCPsrv.ini echo.Profile0=本地连接
>>%TP%\DHCPsrv.ini echo.TFTPDirectory=%BaseDirectory%
>>%TP%\DHCPsrv.ini echo.Multicast=0
>>%TP%\DHCPsrv.ini echo.TFTPEnable=1
>>%TP%\DHCPsrv.ini echo.TFTPPort=69
>>%TP%\DHCPsrv.ini echo.TFTPMode=0
>>%TP%\DHCPsrv.ini echo.Log=0
>>%TP%\DHCPsrv.ini echo.TestIP=1
>>%TP%\DHCPsrv.ini echo.ChangeIP=1
>>%TP%\DHCPsrv.ini echo.EnableMAC=1
rem 有多个网卡时，如不能确定那个网卡，可以将下面此行去掉
>>%TP%\DHCPsrv.ini echo.Include=%_myip%
>>%TP%\DHCPsrv.ini echo.[本地连接]
>>%TP%\DHCPsrv.ini echo.SubnetMask=%_mask%
>>%TP%\DHCPsrv.ini echo.BaseIP=%IP_Pool%
>>%TP%\DHCPsrv.ini echo.Range=101
>>%TP%\DHCPsrv.ini echo.BootFile=%bootfile%
>>%TP%\DHCPsrv.ini echo.GatewayIP=%_Gateway%
>>%TP%\DHCPsrv.ini echo.InterfaceIP=%_myip%
endlocal

%tp%\dhcp4nt.exe -install
start %tp%\dhcpsrv.cpl
EXIT

:getip
set /a a=%a%+1
if %a%==1 set _myip=%b%
if %a%==2 set _mask=%b%
if %a%==3 set _Gateway=%b%
goto :eof

[ 本帖最后由 歌理 于 2009-9-30 22:43 编辑 ]

wlue

强烈支持了，歌理大侠真是精益求精呀！

歌理

rem winPE\WINDOWS通用免配网启服务端.CMD
特点：1、PE\window通用，可在光盘或硬盘运行
          2、本CMD与DHCP同一目录，方便移植，此目录可放在与启动文件同盘的任意子目录
           3、无需启动PE，也能进行远程网启（安装系统或运行PE)

@echo off
PUSHD %~dp0
SET TP=%CD%
rem ==========以下此行为启动引导文件，请自行修改,启动文件与本cmd同分区即可＝＝＝＝＝＝＝
set bootfile=PXEgrldr.0
rem ==========================================================


if not exist %TP%\dhcp4nt.exe echo 当前目录下找不到文件：DHCP4NT.EXE &&pause &&exit

echo 正在自动搜索启动文件，可能需要一些时间，请稍等。。。
set BaseDirectory=
set  bootdrver=%~d0
for /f "usebackq" %%i in (`dir "%bootdrver%\%bootfile%" /s/b`) do set BaseDirectory=%%~dpi
if %BaseDirectory%.==. echo 在 %bootdrver%盘上 找不到启动文件：%bootfile%  &&pause

copy *.* %temp% /y
set tp=%temp%

%TP%\dhcp4nt.exe -remove
setlocal
set/a a=-2
for /f "usebackq tokens=2 delims=:" %%i in (`ipconfig`) do (
set b=%%i
call :getip
)

for /f "tokens=1-3,4 delims=." %%i in ("%_myip%") do set IP_Pool=%%i.%%j.%%k.100
>%TP%\DHCPsrv.ini echo.[License]
>>%TP%\DHCPsrv.ini echo.Key=BBLZ26803UBBCAT9
>>%TP%\DHCPsrv.ini echo.Name=Free User
>>%TP%\DHCPsrv.ini echo.[DHCPsrv]
>>%TP%\DHCPsrv.ini echo.Profile0=本地连接
>>%TP%\DHCPsrv.ini echo.TFTPDirectory=%BaseDirectory%
>>%TP%\DHCPsrv.ini echo.Multicast=0
>>%TP%\DHCPsrv.ini echo.TFTPEnable=1
>>%TP%\DHCPsrv.ini echo.TFTPPort=69
>>%TP%\DHCPsrv.ini echo.TFTPMode=0
>>%TP%\DHCPsrv.ini echo.Log=0
>>%TP%\DHCPsrv.ini echo.TestIP=1
>>%TP%\DHCPsrv.ini echo.ChangeIP=1
>>%TP%\DHCPsrv.ini echo.EnableMAC=1
rem 有多个网卡时，如不能确定那个网卡，可以将下面此行去掉
>>%TP%\DHCPsrv.ini echo.Include=%_myip%
>>%TP%\DHCPsrv.ini echo.[本地连接]
>>%TP%\DHCPsrv.ini echo.SubnetMask=%_mask%
>>%TP%\DHCPsrv.ini echo.BaseIP=%IP_Pool%
>>%TP%\DHCPsrv.ini echo.Range=101
>>%TP%\DHCPsrv.ini echo.BootFile=%bootfile%
>>%TP%\DHCPsrv.ini echo.GatewayIP=%_Gateway%
>>%TP%\DHCPsrv.ini echo.InterfaceIP=%_myip%
endlocal

%tp%\dhcp4nt.exe -install
start %tp%\dhcpsrv.cpl
EXIT

:getip
set /a a=%a%+1
if %a%==1 set _myip=%b%
if %a%==2 set _mask=%b%
if %a%==3 set _Gateway=%b%
goto :eof

[ 本帖最后由 歌理 于 2009-10-2 12:41 编辑 ]

pseudo

◆关于网启服务器，建议做成pe/windows两用、单文件绿色免配置形式，我在此帖提及此形式：

一种U启、网启两用，内置外置自由的部署
楼主的cmd，经过数次改进，已经接近这种形式了。

◆关于网启pe，建议支持“直接pxe”特性及“自由部署”：
直接PXE
一种U启、网启两用，内置外置自由的部署

◆关于pe，提倡一种理念：
版本合一，一个顶多个


又，有个地方不大明白：
楼主这样设置

for /f "tokens=1-3,4 delims=." %%i in ("%_myip%") do set IP_Pool=%%i.%%j.%%k.100

>>%TP%\DHCPsrv.ini echo.BaseIP=%IP_Pool%
>>%TP%\DHCPsrv.ini echo.Range=101

当%_myip%包含于ip池时，服务器的ip是否有被分配给客户机而产生冲突的可能？

liya33

提供下软件啊..中文的？？

tdq868xin

pseudo大大也在搞这个类似的，呵呵，学习！

pseudo

楼上的“一拖五"已经集成了0pe的pe/windows两用、单文件绿色免配置的服务器，
不过由于你把pe的文件藏入ud了，服务器显然不能提供pe文件的下载，成为多余的东西。

tdq868xin

原帖由 pseudo 于 2009-10-2 16:26 发表
楼上的“一拖五"已经集成了0pe的pe/windows两用、单文件绿色免配置的服务器，
不过由于你把pe的文件藏入ud了，服务器显然不能提供pe文件的下载，成为多余的东西。

P大，我已经下载更新成0923版的了，不过合盘我重新在做，做完之后再上传。

33445566

歌理兄能否分别上传PE、Windows下的100%免配的PXE服务器DHCP、TFTPD32（里面配置好CMD）

歌理

原帖由 pseudo 于 2009-10-2 15:19 发表
◆关于网启服务器，建议做成pe/windows两用、单文件绿色免配置形式，我在此帖提及此形式：

一种U启、网启两用，内置外置自由的部署
楼主的cmd，经过数次改进，已经接近这种形式了。


◆关于网启pe，建议 ...

IP池地址否冲突，这么简单的问题任何DHCP自然会考虑到，这个与配置无关！

歌理

原帖由 33445566 于 2009-10-2 20:08 发表
歌理兄能否分别上传PE、Windows下的100%免配的PXE服务器DHCP、TFTPD32（里面配置好CMD）

不知道是出于什么目的

0011

原帖由 歌理 于 2009-10-2 20:28 发表


不知道是出于什么目的

呵呵，方便我等菜鸟拿来就用啊

33445566

PXE启动文件一般是pxelinux.0和grldr，能否在批处理中加入自动查找pxelinux.0、grldr文件，有则配置为启动文件，无则提示输入启动文件名。　

shn

原理不懂，只想要现成的，和0011一样的想法，歌理能否连软件一起给上传了

歌理

原帖由 shn 于 2009-10-3 09:29 发表
原理不懂，只想要现成的，和0011一样的想法，歌理能否连软件一起给上传了

不是不可以，问题是这个软件本论坛上一大把，你搜索一下就能下载，自己动手一下难道对你会有害吗？

wlue

请歌理大侠最好再编写一个针对TFTPD32（这个软件比haneWIN DHCP Server更简单，绿色版只有两个文件，一个主程序，一个配置文件）的Windows下的免配置好CMD，这样就完美了！

歌理

你们也是够懒的，稍稍改一下就可以了哐
刚好我也是刚做完，放在ＰＥ里，贴给你吧：

ＴＦＴＰＤ３２for WINDOWS\WINPE通用免配批处理ＣＭＤ
@echo off
PUSHD %~dp0
SET TP=%CD%
rem ==========以下此行为启动引导文件，请自行修改＝＝＝＝＝＝＝
set bootfile=PXEgrldr.0
rem ==========================================================

if not exist %TP%\TFTPD32.EXE echo 当前目录下找不到文件：TFTPD32.EXE &&pause &&exit

echo 正在自动搜索启动文件，可能需要一些时间，请稍等。。。
set BaseDirectory=
set  bootdrver=%~d0
if exist %bootdrver%\%bootfile% set BaseDirectory=%bootdrver%\&&goto copyfile
for /f "usebackq" %%i in (`dir "%bootdrver%\%bootfile%" /s/b`) do set BaseDirectory=%%~dpi
if %BaseDirectory%.==. echo 在 %bootdrver%盘上 找不到启动文件：%bootfile%  &&pause

:copyfile
copy TFTPD*.*.* %temp% /y >nul
set TP=%temp%
PECMD FIND DHCP4NT.EXE,KILL DHCP4NT.EXE

set/a a=-2
for /f "usebackq tokens=2 delims=:" %%i in (`ipconfig`) do (
set b=%%i
call :getip
)
for /f "tokens=1-3,4 delims=." %%i in ("%_myip%") do set/a IP_Pool=100*256*256*256+%%k*256*256+%%j*256+%%i
for /f "tokens=1-3,4 delims=." %%i in ("%_mask%") do set/a mask=%%l*256*256*256+%%k*256*256+%%j*256+%%i
for /f "tokens=1-3,4 delims=." %%i in ("%_Gateway%") do set/a Gateway=%%l*256*256*256+%%k*256*256+%%j*256+%%i

>%TP%\TFTPD32.INI echo.[TFTPD32]
>>%TP%\TFTPD32.INI echo.
>>%TP%\TFTPD32.INI echo.Console Password=tftpd32
>>%TP%\TFTPD32.INI echo.TftpPort=69
>>%TP%\TFTPD32.INI echo.Negociate=1
>>%TP%\TFTPD32.INI echo.ShowProgressBar=1
>>%TP%\TFTPD32.INI echo.Timeout=3
>>%TP%\TFTPD32.INI echo.MaxRetransmit=6
>>%TP%\TFTPD32.INI echo.SecurityLevel=1
>>%TP%\TFTPD32.INI echo.UnixStrings=1
>>%TP%\TFTPD32.INI echo.Services=47
>>%TP%\TFTPD32.INI echo.PersistantLeases=1
>>%TP%\TFTPD32.INI echo.DHCP Ping=1
>>%TP%\TFTPD32.INI echo.Max Simultaneous Transfers=100
>>%TP%\TFTPD32.INI echo.BaseDirectory=%BaseDirectory%

>>%TP%\TFTPD32.INI echo.[DHCP]
>>%TP%\TFTPD32.INI echo.IP_Pool=%IP_Pool%
>>%TP%\TFTPD32.INI echo.PoolSize=100
>>%TP%\TFTPD32.INI echo.Gateway=%Gateway%
>>%TP%\TFTPD32.INI echo.Mask=%mask%
rem >>%TP%\TFTPD32.INI echo.DNS=%Gateway%
>>%TP%\TFTPD32.INI echo.BootFile=%bootfile%

start %TP%\TFTPD32.EXE
if not exist x:\*.* goto windows

PECMD.EXE LINK !%%DESKTOP%%\TFTPD32网络启动服务端,%TP%\TFTPD32.EXE
PECMD.EXE LINK !%%Programs%%\网络启动服务器\TFTPD32网络启动服务端,%TP%\TFTPD32.EXE
PECMD FILE "%%DESKTOP%%\开启HaneWin网络启动服务端.*"
PECMD FILE "%%DESKTOP%%\开启TFTPD32网络启动服务端.*"
rem 删除共享名PEroot,建立共享名为Peroot共享资源为%BaseDirectory%
PECMD EXEC CMD /C "net share PEROOT /d"
PECMD EXEC CMD /C "net share PEROOT=%BaseDirectory% /unlimited"

echo.
echo  已将本机光盘 %BaseDirectory% 共享给远程客户(\\Winpe\PEROOT,用户名:Guest,密码为空）
:windows
echo.
echo.
echo  远程启动网启服务器.启动成功!
pause
EXIT


:getip
set /a a=%a%+1
if %a%==1 set _myip=%b%
if %a%==2 set _mask=%b%
if %a%==3 set _Gateway=%b%
goto :eof

ＤＨＣＰ４ＮＴ　for WINDOWS\WINPE通用免配批处理ＣＭＤ
rem winPE\WINDOWS通用免配网启服务端.CMD
@echo off
PUSHD %~dp0
SET TP=%CD%
rem ==========以下此行为启动引导文件，请自行修改,启动文件与本cmd同分区即可＝＝＝＝＝＝＝
set bootfile=PXEgrldr.0
rem ==========================================================

if not exist %TP%\dhcp4nt.exe echo 当前目录下找不到文件：DHCP4NT.EXE &&pause &&exit

echo 正在自动搜索启动文件，可能需要一些时间，请稍等。。。
set BaseDirectory=
set  bootdrver=%~d0
if exist %bootdrver%\%bootfile% set BaseDirectory=%bootdrver%\&&goto copyfile
for /f "usebackq" %%i in (`dir "%bootdrver%\%bootfile%" /s/b`) do set BaseDirectory=%%~dpi
if %BaseDirectory%.==. echo 在 %bootdrver%盘上 找不到启动文件：%bootfile%  &&pause

:copyfile
copy DHCP*.* %temp% /y >nul
set tp=%temp%

%TP%\dhcp4nt.exe -remove >nul
setlocal
set/a a=-2
for /f "usebackq tokens=2 delims=:" %%i in (`ipconfig`) do (
set b=%%i
call :getip
)

for /f "tokens=1-3,4 delims=." %%i in ("%_myip%") do set IP_Pool=%%i.%%j.%%k.100
>%TP%\DHCPsrv.ini echo.[License]
>>%TP%\DHCPsrv.ini echo.Key=BBLZ26803UBBCAT9
>>%TP%\DHCPsrv.ini echo.Name=Free User
>>%TP%\DHCPsrv.ini echo.[DHCPsrv]
>>%TP%\DHCPsrv.ini echo.Profile0=本地连接
>>%TP%\DHCPsrv.ini echo.TFTPDirectory=%BaseDirectory%
>>%TP%\DHCPsrv.ini echo.Multicast=0
>>%TP%\DHCPsrv.ini echo.TFTPEnable=1
>>%TP%\DHCPsrv.ini echo.TFTPPort=69
>>%TP%\DHCPsrv.ini echo.TFTPMode=0
>>%TP%\DHCPsrv.ini echo.Log=0
>>%TP%\DHCPsrv.ini echo.TestIP=1
>>%TP%\DHCPsrv.ini echo.ChangeIP=1
>>%TP%\DHCPsrv.ini echo.EnableMAC=1
rem 有多个网卡时，如不能确定那个网卡，可以将下面此行去掉
>>%TP%\DHCPsrv.ini echo.Include=%_myip%
>>%TP%\DHCPsrv.ini echo.[本地连接]
>>%TP%\DHCPsrv.ini echo.SubnetMask=%_mask%
>>%TP%\DHCPsrv.ini echo.BaseIP=%IP_Pool%
>>%TP%\DHCPsrv.ini echo.Range=101
>>%TP%\DHCPsrv.ini echo.BootFile=%bootfile%
>>%TP%\DHCPsrv.ini echo.GatewayIP=%_Gateway%
>>%TP%\DHCPsrv.ini echo.InterfaceIP=%_myip%
endlocal

%tp%\dhcp4nt.exe -install >nul
start %tp%\dhcpsrv.cpl

if not exist x:\*.* goto windows
PECMD.EXE LINK !%%DESKTOP%%\HaneWin网启服务端,%tp%\dhcpsrv.cpl,,%tp%\dhcp.ico
PECMD.EXE LINK !%%Programs%%\网络启动服务器\开启HaneWin网络启动服务端,%tp%\dhcp4nt.exe,-install,shell32.dll#96
PECMD.EXE LINK !%%Programs%%\网络启动服务器\关闭HaneWin网络启动服务端,%tp%\dhcp4nt.exe,-remove,shell32.dll#95
PECMD.EXE LINK !%%Programs%%\网络启动服务器\HaneWin网启服务端,%tp%\dhcpsrv.cpl,,%tp%\dhcp.ico

PECMD FILE "%%DESKTOP%%\开启HaneWin网络启动服务端.*"
PECMD FILE "%%DESKTOP%%\TFTPD32网络启动服务端.*"

rem 删除共享名PEroot,建立共享名为Peroot共享资源为%BaseDirectory%
PECMD EXEC CMD /C "net share PEROOT /d"
PECMD EXEC CMD /C "net share PEROOT=%BaseDirectory% /unlimited"
rem PECMD FIND EXPLORER.EXE,KILL EXPLORER.EXE
echo.
echo  已将本机光盘 %BaseDirectory% 共享给远程客户(\\Winpe\PEROOT,用户名:Guest,密码为空）
:windows
echo.
echo.
echo  远程启动网启服务器.启动成功!
pause
EXIT



:getip
set /a a=%a%+1
if %a%==1 set _myip=%b%
if %a%==2 set _mask=%b%
if %a%==3 set _Gateway=%b%
goto :eof


本贴到此为止，保证不再更新！！！！！！！

[ 本帖最后由 歌理 于 2009-10-9 17:11 编辑 ]

zhaohj

一个问题，原来网络上已有DHCP（MS）服务器，怎么配置？
再做一个HANETFTP吧，不要DHCP的。

liya33

有没有详细的教程呀？  随便把这软件上传上来就更好 了

cduser

有成品的ISO下载就好了

coolg

原帖由 歌理 于 2009-10-9 17:05 发表
你们也是够懒的，稍稍改一下就可以了哐
刚好我也是刚做完，放在ＰＥ里，贴给你吧：

ＴＦＴＰＤ３２for WINDOWS\WINPE通用免配批处理ＣＭＤ
@echo off
PUSHD %~dp0
SET TP=%CD%
rem ==========以下此行为 ...

这个配置文件十分好用...
有一问题:
     我想把其他分区共享给客户端,请教如何设置映射
     (我修改N(n>20)次,也没成功,特来求教!!!)

[ 本帖最后由 coolg 于 2009-10-27 18:53 编辑 ]

8696648

谢谢歌理上校，学习一下，谢谢提供，辛苦了。

HY

原帖由 coolg 于 2009-10-27 18:50 发表




这个配置文件十分好用...
有一问题:
     我想把其他分区共享给客户端,请教如何设置映射
     (我修改N(n>20)次,也没成功,特来求教!!!)

如果能实现coolg说的功能就更好了，不知如何搞？

bgwhw

希望楼主能出一个包括应用程序在内的“成品”，在WINPE、WINDOWS下能直接使用的。

歌理

1、将DHCP或TFTPD32文件夹放入分区中，此文件夹除了包含必须的DHCP等文件外，还得有本.CMD
2、将启动文件PXEgrldr.0放入分区根目录！
运行CMD即可。
（仅支持XP，不支持ViSTA\win7)

[ 本帖最后由 歌理 于 2009-11-30 12:54 编辑 ]

coolg

原帖由 歌理 于 2009-11-30 12:50 发表
1、将DHCP或TFTPD32文件夹放入分区中，此文件夹除了包含必须的DHCP等文件外，还得有本.CMD
2、将启动文件PXEgrldr.0放入分区根目录！
运行CMD即可。
（仅支持XP，不支持ViSTA\win7)

谢谢歌理大侠的指点！！！
我用您的配置文件，不用移动文件夹，而是结合别的方法，搞定了任意指定共享目录。。再次表示感谢！！！