准备基于 fbinst 进行再开发，请各位提供帮助

freesoft00 · 发表于 2013-12-10 10:45:16

http://code.google.com/p/grubutils/source/browse/#
试试

2011yaya2007777 · 发表于 2013-12-10 11:25:57

下载了，谢谢

讯极天度 · 发表于 2013-12-10 23:29:16

mygamexxx 发表于 2013-12-10 08:26
开了两个页面，一个能进去，但等待时间比较长，一个最后显示“无法显示此页”。

进不去就借助GAE，肯定是可以的

20100660 · 发表于 2013-12-11 22:29:40

好消息………………………

20121223445667 · 发表于 2013-12-12 21:01:52

后排膜拜大神！

2011yumeiren · 发表于 2013-12-14 10:24:16

难道是打酱油的！

天使的魔翼 · 发表于 2013-12-17 16:03:30

我来座等测试吧，这个星期完了后，我可以着手测试相关内容，05年至今的电脑都有，几乎涵盖了HP、DELL、IBM、联想等，笔记本有四种：IBM、HP、DELL、三星。新的电脑马上到手主要是DELL和东芝，都可以拿来练手的，随便拆，随便改，用坏了直接换货的。

不点 · 发表于 2013-12-17 18:32:26

看到有 “天使的魔翼” 这样有条件的测试者，令人鼓舞。不过，我听说有很多新电脑已经不再支持 BIOS 了（只支持 EFI），因此这会让你的测试直接 “泡汤”。你还是尽量多准备一些旧电脑吧。我们是要保证在旧电脑上有较高的成功率，争取达到不折不扣的 100% 成功率。新电脑是不敢保证的。一方面，新电脑有可能不支持 BIOS，另一方面，即使支持 BIOS，它也可能针对 grub4dos 以及 fbinst 进行新的攻击，这样，我们就不敢保证支持新电脑了。

rgiskard · 发表于 2013-12-18 18:46:35

fbinst兼容性必须增强啊，优盘启动测试必备！！

不点 · 发表于 2013-12-23 23:23:10

初步尝试，开始写代码了。目前的 MBR 扇区代码的主框架已经完成。但后续的工作仍然是很繁琐的。

目前暴露出的问题主要是，MBR 里面的代码空间太少了。

MBR 要放个 BPB，这占用 0x60 个字节。

MBR 还得有分区表，这也要占用 0x48 个字节。

两者合起来占用 0xA8 个字节。

剩下的空间只有 0x158 个字节了。

就是说，512 字节当中，有三分之一的空间被 BPB 和分区表占用，剩下的三分之二，空间太小、太紧张。

因此，有很多概念都得简化。比如说，原来打算要智能地分辨出内嵌的究竟是 grldr 还是 ntldr，现在照顾不了 ntldr 了，只对 grldr 给以直接的支持，而 ntldr 的启动则需要用户用 hack 的手段实现，即，用户自己把 ntldr 的代码进行重新包装，以便让系统能够启动它。

这个 MBR 代码会探测出正确的 H 和 S 值，最后，加载位于物理扇区号 190 开始的 1152 个扇区（也就是 576K）。加载的目的地址是 0x7E00，也就是紧跟 0x7C00 之后的那个扇区位置。加载完成后，控制将跳转到 0000:7E00 去执行。

为什么是 576K 呢？这是最大可能的加载长度，如果再大，就有可能与常规内存顶部的 EBDA 相冲突了。我们假定这 576K 是 grldr 文件的内容。其实，任何代码都可以放在这里，不一定非得是 grldr。

由于 grldr 的内置菜单可以是 LZMA 压缩格式并且带有字库，因此，grldr 的体积可能会很大，用户有可能制作出一个很大的 grldr 文件。而加载一个 576K 的大文件，基本可以满足这方面的需要了。

简言之，这个单扇区的 MBR 代码，在完成 CHS 探测之后，立即加载内嵌的 GRLDR 文件。探测 CHS 的过程类似于 fbinst 的做法，需要 8M 的空间。

月光海洋 · 发表于 2013-12-24 09:07:46

每天都来关注有没有进展…项目开始了就好…

2011hjcjie · 发表于 2013-12-24 15:29:53

期待更好的工具诞生，支持！

不点 · 发表于 2013-12-25 20:56:24

现在能够在开始的时候打印出 DL 的值了。目前是采用直接写屏显示信息，不采用 BIOS 的 INT10 视频功能调用。

打印 DL 的值之后，等待 3 秒钟，以便用户确实能够看见它。

仔细想想，其实，能够打印出信息，这一点是很重要的。别小看它，这不是一件可以忽略的小事。假如没有信息显示，则当失败情况出现时，用户无法了解其失败的根源，也无法给开发者提供有用的描述。

至于说打印的内容，倒不是很重要。随便打印一个内容便可，只要能够让用户明白，我们的 MBR 代码确实已经成功从 BIOS 那里获得了控制权便可。究竟是获得控制权了？还是没有获得？这是清楚明白的，而不至于模棱两可、说不清楚。走一步是一步，做好记号，让开发、探索的过程透明。

这就像嫦娥登月，开始的时候，先确定能够绕行，然后再尝试落下去。落下去之后，再看看那里有什么新情况。每一步都要扎实可靠。

先前的 fbinst 就做了很好的工作，提供了很多有价值的信息，成为我们进一步发展的良好开端。

这次改进的一个方面，就是要在正式的版本中嵌入调试信息。如果正式版中缺乏必要的、关键的调试信息，那就不方便用户报告问题。

用户遇到问题，不一定有时间、有精力来寻找专门的调试版，甚至也不一定会使用调试版。正式版往往随某个第三方的发行版一起发行，而调试版往往是被忽略的。最终用户因为有了高手们制作的傻瓜化的正式版而很快 “适应” 了，故而甚至他们自己不知道怎么使用调试版。这种情况就造成了调试版与正式版的脱节。

因此，在正式版里面嵌入调试信息，不再单独发行调试版，这是一个很重要的改进。

在道理上澄清这一认识之后，还存在着 “实际可行性” 的问题。

其实这在技术上是有难度的，不容易在狭小的空间里面嵌入很多调试信息。

目前做到了以下几点：

1、打印初始的 DL 信息，并等待 3 秒。

2、用 CHS 模式读逻辑扇区0，从而得知隐藏的扇区数。

3、判断是否支持 LBA 模式。如果支持 LBA 模式，则接下来就使用 LBA 模式来读盘。

4、如果不支持 LBA 模式，则探测 CHS 参数，并用 CHS 模式读盘。

5、可以读取连续多个（比如说1152个）扇区到内存 0x7E00 并递交控制权。

6、在保持 1152 个扇区不记录物理扇区号的情况下，依旧能够完成几何参数的探测。

7、读盘出现失败时，能够显示 “disk fail” 信息。

虽然实现了以上这些功能，但是，0x1A8 字节的代码空间也用光了。而且，这个代码已经进行了充分的优化，很难再通过技术性的手段来节约空间了。然而，这个 “首扇区” 里面的调试信息太少，需要继续塞入其他几个比较关键的调试信息。那就得取消某些功能了。以下两个功能在原则上是可以考虑取消的：

1、取消 LBA 支持功能，这能够节约不少空间。首扇区可以考虑取消 LBA 支持功能，留待第二阶段的次级扇区对这一功能进行增补。
2、取消 1152 个空白扇区的设置，这样会让探测的逻辑更简单，也能够切实减少占用 “首扇区” 里面的宝贵空间。

如果首扇区的打印信息很重要，而且信息又比较多，那可能就得把上述两个功能都取消。目前打算先取消 1152 个空白扇区，然后试试看可否加入足够的调试信息。

不点 · 发表于 2013-12-25 21:34:01

我把楼上所说的阶段性的代码贴出来，一方面是作为一个备份来防止代码丢失，另一方面也许有人对此感兴趣，那就可以帮助开发完善了。目前这个代码还没有取消楼上在结尾处所谈到的 “拥有 1152 空白扇区” 的功能。

这个代码编译完成后，已经抵达偏移 0x1B7 了，也就是说，连一个字节的剩余空间都没有了。从偏移 0x1B8 开始，那是大家熟悉的微软磁盘签名以及分区表。

.text
.code16
start:
jmp 1f
. = start + 0x02
.byte 0x90
. = start + 0x03
.ascii "MSWIN4.1"
. = start + 0x0B
.word 0x200
. = start + 0x0D
/* Sectors per cluster. Valid values are 1, 2, 4, 8, 16, 32, 64 and 128.
* But a cluster size larger than 32K should not occur.
*/
.byte 0x01 // sectors per cluster, should be changed by installer
. = start + 0x0E
.word 0x0001 // reserved sectors, should be changed by installer
. = start + 0x10
.byte 0x02 // number of FATs
. = start + 0x11
.word 0 // FAT12/16 root dir entries. Must be 0
. = start + 0x13
.word 0 // FAT12/16 total sectors. Must be 0
. = start + 0x15
.byte 0xF8 // media descriptor
. = start + 0x16
.word 0 // FAT12/16 sectors per FAT. Must be 0
. = start + 0x18
.word 0x3f // sectors per track
. = start + 0x1A
.word 0xff // number of heads
. = start + 0x1C
.long 0 // hidden sectors, should be changed by installer
. = start + 0x20
.long 0 // total sectors, should be changed by installer
. = start + 0x24
.long 0 // sectors per FAT, should be changed by installer
. = start + 0x28
.word 0 // current active FAT
. = start + 0x2A
.word 0 // FAT32 revision number
. = start + 0x2C
.long 0 // root dir starting cluster
. = start + 0x30
.word 0 // file system information sector number
. = start + 0x32
.word 6 // boot record backup sector number
. = start + 0x34
.long 0 // reserved
.long 0 // reserved
.long 0 // reserved
. = start + 0x40
.byte 0x80 // drive number
. = start + 0x41
.byte 0
. = start + 0x42
/* Signature (must be 28h or 29h to be recognised by NT). */
.byte 0x29 // extended boot signature for FAT12/FAT16
. = start + 0x43
.long 0x0AC4AF63 // volume serial number
. = start + 0x47
.ascii "NO NAME " // volume label, 11 bytes
. = start + 0x52
.ascii "FAT32 " // filesystem ID, 8 bytes
. = start + 0x5A
.word 0 // reserved
.word 0 // reserved
.word 0 // reserved
. = start + 0x60
1:
xorw %di, %di
movw %di, %ds /* constant DS=0 */
movw $0x7C00, %bp /* constant BP=0x7C00 */
movw %di, %ss /* constant SS=0 */
movw %bp, %sp
movb %dl, 0x40(%bp) /* assume BIOS pass correct drive number. */
/* Got control! Print DL on the screen. */
movw $0xB800, %bx
movw %bx, %es
xchgw %ax, %dx /* DX -> AX */
/* Undocumented AAM instruction Opcode: D4 imm8 */
.byte 0xD4, 0x10 // AH= AL / 16, AL= AL % 16
addw $0x3030, %ax
xchgw %ax, %dx
movb %dh, %al
movb $0x9F, %ah # back/fore ground=bright blue/white
cld
stosw /* DI=2 */
xchgw %ax, %dx
movb $0x9F, %ah # back/fore ground=bright blue/white
stosw /* DI=4 */
/* sleep 3 seconds */
movw $55, %cx /* 55 / 18.2 = 3 seconds */
1:
movl 0x46c, %eax /* get old timer counter */
sti /* enable interrupt for int8 timer */
cmpl 0x46c, %eax /* timer counter changed by int8 ? */
je 1b /* user will report it if it hangs here */
loop 1b /* no change, wait a timer interrupt */
/* DI=4 */
//movw $4, %di /* try 4 times on read failure */
movw %di, 0x18(%bp) /* set a known value 4: sectors per track */
movw %di, 0x1a(%bp) /* set a known value 4: number of heads */
pushw $0x0201 //--- /* BP-2 point to int13/AX: read 1 sector */
/* read C/H/S=0/0/1 to 0000:7E00 */
xorw %ax, %ax
movw %ax, %es
movw $0x7E00, %bx
pushw %es //---
pushw %bx //--- /* BP-6 point to 0x00007E00 on stack */
movw $1, %cx /* read 1 sector */
call readDisk /* CX=1, DX=0 */
pushw 0x0E(%bx) //--- /* save sector serial number at BP-8 */
movb $0x41, %ah
movw $0x55AA, %bx
call int13
jc 1f /* no ebios */
subw $0xAA55, %bx
jnz 1f /* no ebios */
//testb $1, %cl
//jz 1f
.byte 0xD0, 0xD9 // RCR CL,1; D0 C9 ROR CL,1 also OK
jnc 1f /* no ebios */
movb $0x42, -1(%bp) /* LBA supported */
geometry_OK:
/* read GRLDR to 0000:7E00 */
/* calculate grldr starting sector number */
/* grldr serial number = (0x28 + 126 + 255*63 - 190) */
movw -8(%bp), %ax
subw $(0x28 + 126 + (255*63) - 190), %ax
//cdq /* EDX=0 */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
//xorl %ecx, %ecx
movw $1152, %cx /* read 576K grldr */
call readDisk /* CX=1152, DX=0 */
movb 0x40(%bp), %dl
movb $0xFF, %dh
pushw %dx
//ljmp $0, $0x7E00
pushw %ds /* DS=0 */
pushw %bx /* BX=0x7E00 */
lret
1:
/* no LBA */
/* XXX: should confirm 0x18(%bp)=63, 0x1A(%bp)=255 */
/* read C/H/S=0/1/1 to 0000:7E00 */
//xorl %eax, %eax
movw %di, %ax /* AX=4, start sector number */
//cdq /* EDX=0 */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
movw $1, %cx /* read 1 sector */
call readDisk /* CX=1, DX=0 */
movw -8(%bp), %ax
subw 0x0E(%bx), %ax /* the real sectors per track */
pushw %ax //--- /* save it at BP-10 */
pushw %dx //--- /* initial 0 at BP-12 */
//movb %al, 0x18(%bp) /* update it! */
/* read C/H/S=1/0/1 to 0000:7E00 */
movw $21, %cx
xorw %ax, %ax
1:
addw $(4*4), %ax /* 16=sectors per cylinder */
movw -10(%bp), %dx
addw %dx, -12(%bp)
pushw %cx
pushw %ax
//cdq /* EDX=0 */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
//xorl %ecx, %ecx
movw %di, %cx /* read 4 sectors */
call readDisk /* CX=4, DX=0 */
movw 0x0E(%bx), %ax
movw %ax, %cx
decw %ax
cmpw 0x20E(%bx), %ax
jne 2f
decw %ax
cmpw 0x40E(%bx), %ax
jne 2f
decw %ax
cmpw 0x60E(%bx), %ax
jne 2f
movw -8(%bp), %ax
subw %cx, %ax /* sectors in cylinders */
divw -12(%bp) /* rem=DX, should be 0 */
/* quo=AX, number of heads */
/* XXX: if DX != 0, here should halt! */
movw %ax, 0x1A(%bp) /* update number of heads! */
movb -12(%bp), %al
movb %al, 0x18(%bp) /* update sectors per track! */
jmp geometry_OK /* ready to load GRLDR */
2:
popw %ax
popw %cx
loop 1b
1:
hlt
jmp 1b
/* Read sectors from disk, using LBA or CHS
* input: AX = 16-bit LBA sector number, and AX <= 0x7FFF
* CX = number of sectors to read
* ES:BX = destination buffer
* SS = DS
* BP+0x18 -> sectors per track
* BP+0x1A -> number of heads
* BP+0x40 -> drive number
*
* output: No return on error
* BX not changed
* CX not changed
* ES = ES + 0x20 * CX
* AX = AX + CX
* DX = 0
* ZF = 0
* CF = 0
*/
readDisk:
cwd /* DX=0 */
2:
pushaw
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %ax /* lo 16bit of sector number */
pushw %es /* buffer segment */
pushw %bx /* buffer offset */
pushw $1 /* 1 sector to read */
pushw $16 /* size of this parameter block */
cmpb $0x42, -1(%bp) /* LBA supported */
je 1f /* LBA mode */
/* CHS mode */
divw 0x18(%bp) /* rem=DX */
/* quo=AX */
/* DH=0 */
incw %dx /* DL=sector number */
xchgw %dx, %cx /* CH=0, CL=sector number */
cwd /* DX=0 */
divw 0x1A(%bp) /* rem=DX */
/* quo=AX, cylinder number */
/* DH=0, DL=head number */
xchgb %dl, %dh /* DL=0, DH=head number */
xchgb %al, %ch /* AL=0, CH=lo 8bit cylinder */
//shlb $6, %ah /* hi 2bit cylinder ... */
//orb %ah, %cl /* ... should be in CL */
shrw $2, %ax /* hi 2bit cylinder ... */
orb %al, %cl /* ... should be in CL */
testb %ah, %ah
jnz disk_error /* cylinder overflow */
1:
movw -2(%bp), %ax /* (E)BIOS read 1 sector */
movw %sp, %si /* DS:SI points to disk address packet */
movb 0x40(%bp), %dl /* drive number */
pushw %es
call int13_retry
popw %bx
//jc disk_error
leaw 0x20(%bx), %bx
movw %bx, %es
popaw /* remove parameter block from stack */
popaw
incw %ax /* next sector, here ZF=0 */
loop 2b
ret
// . = . - (. - readDisk)/68
int13_retry:
//movw $4, %di /* try 4 times on failure */
1:
pushaw
call int13
popaw
jc 2f
ret
2:
pushaw
cbw /* AH=0, reset disk */
//xorw %ax, %ax /* reset disk */
call int13
popaw
decw %di
jnz 1b
disk_error:
movw $(msg_DiskReadError - start + 0x7c00), %si
//boot_error:
/* prints string DS:SI (modifies AX BX SI) */
1:
lodsb (%si), %al /* get token */
//xorw %bx, %bx /* video page 0 */
movb $0x0e, %ah /* print it */
int $0x10 /* via TTY mode */
cmpb $0, %al /* end of string? */
jne 1b /* until done */
1: jmp 1b
int13:
pushw %ds
pushw %es
// pushw %bx /* int13/ah=41h use BX, so do not save. */
// pushw %dx /* drive number already saved in memory. */
pushw %si
pushw %di
pushw %bp
stc
int $0x13
sti
popw %bp
popw %di
popw %si
// popw %dx
// popw %bx
popw %es
popw %ds
ret
msg_DiskReadError:
.ascii "disk fail\0"

复制代码

7112650 · 发表于 2013-12-26 10:43:40

巨大的好消息，十分具有穿透力。期待的很。

不点 · 发表于 2013-12-27 02:09:02

这次去掉了 1152 个空白扇区，增加了调试输出信息。

. = start + 0x60
1:
xorw %di, %di
movw %di, %ds /* constant DS=0 */
movw $0x7C00, %bp /* constant BP=0x7C00 */
movw %di, %ss /* constant SS=0 */
movw %bp, %sp
movb %dl, 0x40(%bp) /* assume BIOS pass correct drive number. */
/* Got control! */
/* print DX */
xchgw %ax, %dx /* store DX into AX */
call print_hex # BX changed
/* print serial number of this sector */
movw 0x0E(%bp), %ax
call print_hex # BX changed
/* sleep 3 seconds */
sti /* enable interrupt for int8 timer */
movw $55, %cx /* 55 / 18.2 = 3 seconds */
2:
movw 0x46c, %ax /* get new ticks */
cmpw %ax, %bx /* changed? */
je 2b /* no, continue to wait */
/* ticks changed by int8 */
xchgw %ax, %bx /* update ticks */
loop 2b
/* CX=0 */
pushw $0x0201 //--- /* BP-2 point to int13/AX: read 1 sector */
/* read C/H/S=0/0/1 to 0000:7E00 */
/* Generally, it is safe enough. */
xorw %ax, %ax
movw %ax, %es
movw $0x7E00, %bx
pushw %es //---
pushw %bx //--- /* BP-6 point to 0x00007E00 on stack */
incw %cx /* read 1 sector */
call readDisk /* CX=1, DX=0 */
incw %cx /* CX=2 */
movw %cx, 0x18(%bp) /* interim sectors per track */
movw %cx, 0x1a(%bp) /* interim number of heads */
movw 0x0E(%bx), %si # mbr0
/* print serial number of mbr0 */
movw %si, %ax
call print_hex # BX changed
/* check LBA support */
/* This can also be considered safe. */
movb $0x41, %ah
movw $0x55AA, %bx
call int13
jc 1f /* no ebios */
cmpw $0xAA55, %bx
jnz 1f /* no ebios */
//testb $1, %cl
//jz 1f
.byte 0xD0, 0xD9 # RCR CL,1; D0 C9 ROR CL,1 also OK
jnc 1f /* no ebios */
movb $0x42, -1(%bp) /* LBA supported */
/* print "AA55" */
xchgw %ax, %bx /* store BX into AX */
call print_hex # BX changed
jmp geometry_OK /* ready to load GRLDR */
1:
/* CHS mode. Must determine geometry. */
/* read C/H/S=0/1/1 to 0000:7E00 */
movw $2, %ax /* AX=2, interim sectors per track */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
movw $1, %cx /* read 1 sector */
call readDisk # AX=3, CX=1, DX=0
movw %si, %ax # mbr0
subw 0x0E(%bx), %ax /* real sectors per track */
jbe disk_error /* installation problem? */
movw %ax, 0x18(%bp) /* update sectors per track! */
/* print real sectors per track */
call print_hex # BX changed
cmpw $63, %ax
ja disk_error /* installation problem? */
/* read C/H/S=1/0/1 to 0000:7E00 */
shlw $1, %ax /* AX=interim sectors per cylinder */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
//movw $1, %cx /* read 1 sector */
call readDisk # AX=5, CX=1, DX=0
movw %si, %ax # mbr0
subw 0x0E(%bx), %ax /* real sectors per cylinder */
jbe disk_error /* installation problem? */
/* DX=0 */
divw 0x18(%bp) /* rem=DX, should be 0 */
/* quo=AX, number of heads */
/* if DX != 0, stop! */
testw %dx, %dx
jnz disk_error /* installation problem? */
movw %ax, 0x1A(%bp) /* update number of heads! */
/* print real number of heads */
call print_hex # BX changed
cmpw $0xFF, %ax
ja disk_error /* installation problem? */
geometry_OK:
/* read GRLDR to 0000:7E00 */
/* calculate grldr starting sector number */
/* grldr serial number = (0x21 + 126 + 255*63 - 190) */
movw %si, %ax # mbr0
subw $(0x21 + 126 + (255*63) - 190), %ax
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
movw $1152, %cx /* read 576K grldr */
call readDisk /* CX=1152, DX=0 */
movb 0x40(%bp), %dl
movb $0xFF, %dh
pushw %dx
//ljmp $0, $0x7E00
pushw %ds /* DS=0 */
pushw %bx /* BX=0x7E00 */
lret
/* Read sectors from disk, using LBA or CHS
* input: AX = 16-bit LBA sector number
* CX = number of sectors to read
* AX + CX <= 0x8000
* ES:BX = destination buffer
* SS = DS
* BP-0x02 -> function call number for AX
* BP+0x18 -> sectors per track
* BP+0x1A -> number of heads
* BP+0x40 -> drive number
*
* output: No return on error
* BX not changed
* CX not changed
* ES = ES + 0x20 * CX
* AX = AX + CX
* DX = 0
* ZF = 0
* CF = 0
*/
readDisk:
cwd /* DX=0 */
2:
pushaw
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %ax /* lo 16bit of sector number */
pushw %es /* buffer segment */
pushw %bx /* buffer offset */
pushw $1 /* 1 sector to read */
pushw $16 /* size of this parameter block */
cmpb $0x42, -1(%bp) /* LBA supported */
je 1f /* LBA mode */
/* CHS mode */
divw 0x18(%bp) /* rem=DX */
/* quo=AX */
/* DH=0 */
incw %dx /* DL=sector number */
xchgw %dx, %cx /* CH=0, CL=sector number */
cwd /* DX=0 */
divw 0x1A(%bp) /* rem=DX */
/* quo=AX, cylinder number */
/* DH=0, DL=head number */
xchgb %dl, %dh /* DL=0, DH=head number */
xchgb %al, %ch /* AL=0, CH=lo 8bit cylinder */
//shlb $6, %ah /* hi 2bit cylinder ... */
//orb %ah, %cl /* ... should be in CL */
shrw $2, %ax /* hi 2bit cylinder ... */
orb %al, %cl /* ... should be in CL */
testb %ah, %ah
jnz disk_error /* cylinder overflow */
1:
movw -2(%bp), %ax /* (E)BIOS read 1 sector */
movw %sp, %si /* DS:SI points to disk address packet */
//movb 0x40(%bp), %dl /* drive number */
pushw %es
call int13_retry
popw %bx
//jc disk_error
leaw 0x20(%bx), %bx
movw %bx, %es
popaw /* remove parameter block from stack */
popaw
incw %ax /* next sector, here ZF=0 */
loop 2b
ret
// . = . - (. - readDisk)/68
int13_retry:
movw $3, %di /* try 3 times on failure */
1:
pushaw
call int13
popaw
jc 2f
ret
2:
pushaw
cbw /* AH=0, reset disk */
//xorw %ax, %ax /* reset disk */
call int13
popaw
decw %di
jnz 1b
disk_error:
//movw $0xDEAD, %ax
movw $0xACCE, %ax # disk access error
call print_hex # BX changed
1: jmp 1b
int13:
pushw %ds
pushw %es
// pushw %bx /* int13/ah=41h use BX, so do not save. */
// pushw %dx /* drive number already saved in memory. */
pushw %si
pushw %di
pushw %bp
stc
movb 0x40(%bp), %dl /* drive number */
int $0x13
sti
popw %bp
popw %di
popw %si
// popw %dx
// popw %bx
popw %es
popw %ds
ret
print_hex:
# input AX = value to print
# DI = video text offset
#
# output ES = 0xB800
# DF = 0
# DI = changed
# BX = changed
pushw $0xB800
popw %es # text mode video memory
cld
pushw %ax
pushw %cx
pushw %bx
movw $4, %cx
xchgw %ax, %bx
1:
rol $4, %bx
movw %bx, %ax
andb $0x0F, %al
cmpb $10, %al
jb 2f
addb $7, %al
2:
addb $0x30, %al
movb $0x9F, %ah # back/fore ground=bright blue/white
stosw
loop 1b
movw $0x2F20, %ax # back/fore ground=green/bright white
stosw
popw %bx
popw %cx
popw %ax
ret

复制代码

天使的魔翼 · 发表于 2013-12-27 15:56:52

　　今天中午花了近一小时时间来学习上述两段代码，由于已经很多年没有继续学习这方面的知识，所以学习起来很吃力；让人感觉不点大师花了很大的精力对代码进行设计，目前正在利用一台本本搭建编译环境，由于工作原因，时间有限，只有利用休息时间进行了。

　　再谈点不成熟的想法吧，当初开发WEE的时候，我一直在想有什么实用吗？到最后chenall大大开发出自用的“基于grub4dos的硬盘工具箱”，引导程序WEE+GRUB4DOS，我想不点大师可以考虑直接取消一些高级手工调试功能，或者类似于WEE一样，保留一些基本命令就行了；采取G4D现在发展模式，基本+模块+调用；
　　再说一下关于调试部分，可以进一步深化，可以借鉴一些U盘检测工具的做法，在虚拟环境下对U盘进行调试，最方便的做法是：U盘启动到DOS下，运行批处理切换至G4D环境，调用FBINST环境，使用模块化检测U盘是否能适应启动，然后保存至TXT文本，供开发人员检查。
　　以上一些想法有些地方不是很成熟，只不过提出一个概念：
　　　　　　

不点 · 发表于 2013-12-27 23:01:57

又做了一些优化的工作，节约了几个字节。现在比较满意了。

1152 扇区的外部引导器（GRLDR）是含有物理扇区号记录的，因此，还需要在加载 GRLDR 引导扇区之后，进行一些整理。由于已经加载了 1152 个扇区到 0000:7E00 了，因此，这开头的扇区就要负责这些整理工作了。

开头这个扇区，权且当作 MBR “首扇区” 引导器的第二阶段辅助代码吧。就是说，这 1152 个扇区最开头的扇区，是引导器自己的补充、辅助代码。紧接着的下一个扇区，才是外部引导器的开始。也就是说，外部引导器本身只有 1151 个扇区了。如果将来某个时候有人希望增加辅助代码的功能，增加辅助扇区的个数，那只需要（用户或第三方开发者）自己安排辅助扇区数量、代码以及 grldr 的位置便可。两者的总扇区数是不变的，即，1152 个扇区。

目前，我们的目的仅仅是加载 grldr 而已，因此，一个辅助扇区已经绰绰有余了。辅助扇区的功能虽然简单，但是这个工作还是需要做的，不能省略掉。接下来就准备写辅助扇区的代码了。

. = start + 0x60
1:
xorw %di, %di
movw %di, %ds /* constant DS=0 */
movw $0x7C00, %bp /* constant BP=0x7C00 */
movw %di, %ss /* constant SS=0 */
movw %bp, %sp
/* save DL first */
movb %dl, 0x40(%bp) /* assume BIOS pass correct drive number. */
/* Got control! */
/* print DX */
xchgw %ax, %dx /* store DX into AX */
call print_hex # BX changed
/* print serial number of this sector */
movw 0x0E(%bp), %ax
call print_hex # BX changed
/* sleep 3 seconds */
sti /* enable interrupt for int8 timer */
movw $55, %cx /* 55 / 18.2 = 3 seconds */
2:
movw 0x46c, %ax /* get new ticks */
cmpw %ax, %bx /* changed? */
je 2b /* no, continue to wait */
/* ticks changed by int8 */
xchgw %ax, %bx /* update ticks */
loop 2b
/* CX=0 */
pushw $0x0201 //--- /* BP-2 point to int13/AX: read 1 sector */
/* read C/H/S=0/0/1 to 0000:7E00 */
/* Generally, it is safe enough. */
xorw %ax, %ax
movw %ax, %es
movw $0x7E00, %bx
pushw %es //---
pushw %bx //--- /* BP-6 point to 0x00007E00 on stack */
incw %cx /* read 1 sector */
call readDisk /* CX=1, DX=0 */
pushw %cx /* 1, no POP in LBA branch. See below. */
incw %cx /* CX=2 */
movw %cx, 0x18(%bp) /* interim sectors per track */
movw %cx, 0x1a(%bp) /* interim number of heads */
pushw %cx /* 2, no POP in LBA branch. See below. */
movw 0x0E(%bx), %si # mbr0
/* print serial number of mbr0 */
movw %si, %ax
call print_hex # BX changed
/* check LBA support */
/* This can also be considered safe. */
movb $0x41, %ah
movw $0x55AA, %bx
call int13
jc 1f /* no ebios */
cmpw $0xAA55, %bx
jnz 1f /* no ebios */
//testb $1, %cl
//jz 1f
.byte 0xD0, 0xD9 # RCR CL,1; D0 C9 ROR CL,1 also OK
jnc 1f /* no ebios */
movb $0x42, -1(%bp) /* LBA supported */
/* print "AA55" */
xchgw %ax, %bx /* store BX into AX */
call print_hex # BX changed
/* Keep the pushed 1 and 2 on stack without POPs. There is no harm. */
jmp geometry_OK /* ready to load GRLDR */
1:
/* CHS mode. Must determine geometry. */
/* read C/H/S=0/1/1 to 0000:7E00 */
//movw $2, %ax /* AX=2, interim sectors per track */
popw %ax /* AX=2, interim sectors per track */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
popw %cx /* CX=1, read 1 sector */
call readDisk # AX=3, CX=1, DX=0
movw %si, %ax # mbr0
subw 0x0E(%bx), %ax /* real sectors per track */
jbe boot_error /* installation problem? */
cmpw $63, %ax
ja boot_error /* installation problem? */
movw %ax, 0x18(%bp) /* update sectors per track! */
/* print real sectors per track */
call print_hex # BX changed
/* read C/H/S=1/0/1 to 0000:7E00 */
shlw $1, %ax /* AX=interim sectors per cylinder */
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
//movw $1, %cx /* read 1 sector */
call readDisk # AX=5, CX=1, DX=0
movw %si, %ax # mbr0
subw 0x0E(%bx), %ax /* real sectors per cylinder */
jbe boot_error /* installation problem? */
/* DX=0 */
divw 0x18(%bp) /* rem=DX, should be 0 */
/* quo=AX, number of heads */
/* if DX != 0, stop! */
testw %dx, %dx
jnz boot_error /* installation problem? */
movw %ax, 0x1A(%bp) /* update number of heads! */
/* print real number of heads */
call print_hex # BX changed
testb %ah, %ah
jnz boot_error /* installation problem? */
geometry_OK:
/* read GRLDR to 0000:7E00 */
/* calculate grldr starting sector number */
/* grldr serial number = (0x21 + 126 + 255*63 - 190) */
movw %si, %ax # mbr0
subw $(0x21 + 126 + (255*63) - 190), %ax
lesw -6(%bp), %bx /* ES:BX=0000:7E00 */
movw $1152, %cx /* read 576K grldr */
call readDisk /* CX=1152, DX=0 */
#if 0
/* We can do it later in the second stage. */
movb 0x40(%bp), %dl
movb $0xFF, %dh
pushw %dx
#endif
//ljmp $0, $0x7E00
pushw %ds /* DS=0 */
pushw %bx /* BX=0x7E00 */
lret
int13_retry:
movw $3, %di /* try 3 times on failure */
2:
pushaw
call int13
popaw
jc 1f
ret
1:
pushaw
cbw /* AH=0, reset disk */
call int13
popaw
decw %di
jnz 2b
disk_error:
//movw $0xDEAD, %ax
movw $0xACCE, %ax # disk access error
boot_error:
call print_hex # BX changed
2:
jmp 2b
/* Read sectors from disk, using LBA or CHS
* input: AX = 16-bit LBA sector number
* CX = number of sectors to read
* AX + CX <= 0x8000
* ES:BX = destination buffer
* SS = DS
* BP-0x02 -> function call number for AX
* BP+0x18 -> sectors per track
* BP+0x1A -> number of heads
* BP+0x40 -> drive number
*
* output: No return on error
* BX not changed
* CX not changed
* ES = ES + 0x20 * CX
* AX = AX + CX
* DX = 0
* ZF = 0
* CF = 0
*/
readDisk:
cwd /* DX=0 */
2:
pushaw
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %dx /* 0 */
pushw %ax /* lo 16bit of sector number */
pushw %es /* buffer segment */
pushw %bx /* buffer offset */
pushw $1 /* 1 sector to read */
pushw $16 /* size of this parameter block */
cmpb $0x42, -1(%bp) /* LBA supported */
je 1f /* LBA mode */
/* CHS mode */
divw 0x18(%bp) /* rem=DX */
/* quo=AX */
/* DH=0 */
incw %dx /* DL=sector number */
xchgw %dx, %cx /* CH=0, CL=sector number */
cwd /* DX=0 */
divw 0x1A(%bp) /* rem=DX */
/* quo=AX, cylinder number */
/* DH=0, DL=head number */
xchgb %dl, %dh /* DL=0, DH=head number */
xchgb %al, %ch /* AL=0, CH=lo 8bit cylinder */
#if 1
shrw $2, %ax /* hi 2bit cylinder ... */
orb %al, %cl /* ... should be in CL */
testb %ah, %ah
#else
/* equivalently, this should also work. */
rolw $6, %ax /* hi 2bit cylinder in AH */
orb %ah, %cl /* put into CL */
testb %al, %al
#endif
jnz boot_error /* cylinder overflow */
1:
movw -2(%bp), %ax /* (E)BIOS read 1 sector */
movw %sp, %si /* DS:SI points to disk address packet */
//movb 0x40(%bp), %dl /* drive number */
pushw %es
call int13_retry
popw %bx
//jc disk_error
leaw 0x20(%bx), %bx
movw %bx, %es
popaw /* remove parameter block from stack */
popaw
incw %ax /* next sector, here ZF=0 */
loop 2b
ret
// . = . - (. - readDisk)/68
int13:
pushw %ds
pushw %es
// pushw %bx /* int13/ah=41h use BX, so do not save. */
// pushw %dx /* drive number already saved in memory. */
pushw %si
pushw %di
pushw %bp
stc
movb 0x40(%bp), %dl /* drive number */
int $0x13
sti
popw %bp
popw %di
popw %si
// popw %dx
// popw %bx
popw %es
popw %ds
ret
print_hex:
# input AX = value to print
# DI = video text offset
#
# output ES = 0xB800
# DF = 0
# DI = changed
# BX = changed
pushw $0xB800
popw %es # text mode video memory
cld
pushw %ax
pushw %cx
pushw %bx
movw $4, %cx
xchgw %ax, %bx
2:
rolw $4, %bx
movw %bx, %ax
andb $0x0F, %al
cmpb $10, %al
jb 1f
addb $7, %al
1:
addb $0x30, %al
movb $0x9F, %ah # back/fore ground=bright blue/white
stosw
loop 2b
movw $0x2F20, %ax # back/fore ground=green/bright white
stosw
popw %bx
popw %cx
popw %ax
ret

复制代码

xyzxp · 发表于 2013-12-27 23:45:04

感谢不点，辛苦了，非常期待！

詹姆斯草 · 发表于 2013-12-28 15:09:31

只能精神上表示支持了，一无技术，二无能力，三无条件，三无人员呵呵。当然有的是些许的兴趣和些许的时间，但愿能早点见到公测的成品，一定好好试用

不点 · 发表于 2013-12-29 05:49:58

这是第一个测试版，主要目的是测试第一扇区代码是否有毛病。

注意，如果测试成功，屏幕的顶部会显示一些 16 进制的数字。最后一个数字如果是 ACED，则表示测试 OK。

请下载附件，并解压，生成 8M 的映像文件。这个文件是用来克隆到 U 盘的。

请使用 dd 以及类似的克隆软件进行操作。

严重警告！请确保不要写入你的本地硬盘！如果你不懂，请放弃操作！
如果误操作导致硬盘分区丢失，则无法恢复。请谨慎！每一步都要小心！

把 8M.mbr 文件按照扇区写入 U 盘的最开头，覆盖掉 U 盘原来的 MBR 以及分区表。这当然就破坏了 U 盘原有的数据。所以，请选择一个废弃了的 U 盘来操作，比如说，这个 U 盘的容量比较小，这样的 “废盘” 正好可以用来测试。

注意，这个 8M.mbr 自己含有分区表以及 BPB，请原封不动克隆到你的废弃了的 U 盘上。克隆之后，不要在 Windows 下查看 U 盘内容，因为现阶段还没有安排数据分区。另外也担心 Windows 会写入数据破坏已经建立的扇区结构，所以，克隆以后，不要在资源管理器中查看 U 盘的状况。克隆完了之后，你可以拔掉 U 盘，然后插到某个电脑上进行重启测试。

建议先在虚拟机上测试，消除安全隐患。

cchessbd · 发表于 2013-12-29 09:00:49

本帖最后由 cchessbd 于 2013-12-29 09:02 编辑

关于ud的文件列表，我希望默认采用ANSI格式，而不是UTF-8。
因为用jianliulian的fbinstool回写fba到u盘时，老是采用UTF-8的文件列表。
这样在我接触的两台电脑出错。
不能载入dos启动镜像及pe，居然把2.88m的识别为2000多m了，pe直接没反应。
郁闷了一段时间，因为这个。

其实说这个只是希望不点大师能做好这个。

不点 · 发表于 2013-12-29 21:18:26

本帖最后由不点于 2013-12-29 21:37 编辑

报告一个消息，我的 U 盘测试失败了，根本就死机一个，屏幕上任何信息都没有，应该是没能接到控制权。它要是成功了，那就没劲了。失败了正好有活干，可以折腾了。希望通过折腾，让秘密透露得更多一点。

而原来的 fbinst 当然是能够成功启动的。

它死了，可以用 ctrl+alt+del 重启，重启后机器仍然不正常，会死机。死机时，在有些时候，拔掉 U 盘就可以继续启动。

拔掉 U 盘可以继续走，从这个现象，也可分析，BIOS 没有把控制权传过来，而是 BIOS 自己在 “死读” U 盘。

接下来再做一个试验，让 8M 的扇区全都带有引导代码，这次看看能否接管控制。估计依旧不会接管控制的。

可能性最大的，那就是 BPB 表以及分区表的影响了。

pseudo · 发表于 2013-12-29 22:58:54

不点大人早点休息保重身体
有活干时慢慢折腾
就像章回小说，且听下回分解

假大空 · 发表于 2013-12-30 15:47:55

关注一下。就像P大所说的，保重身体，*下回分解。顺便说下，P大文字功底不错哦。

jack95 · 发表于 2013-12-30 18:22:23

cchessbd 发表于 2013-12-29 09:00
关于ud的文件列表，我希望默认采用ANSI格式，而不是UTF-8。
因为用jianliulian的fbinstool回写fba到u盘时 ...

fbinst 核心代码读取文件件列表本身并不区分ansi或者utf-8，它是根据beyte对比，只有grldr或者查看文件列表才有编码之分。你启动不了应该是其他问题，为什么不提供详细的信息让大家帮你分析，说不定会发现新的bug或者是你自己pe的问题

pseudo · 发表于 2013-12-30 22:47:20

cchessbd 发表于 2013-12-29 09:00
关于ud的文件列表，我希望默认采用ANSI格式，而不是UTF-8。
因为用jianliulian的fbinstool回写fba到u盘时 ...

cchessbd兄久违，你所用fbinsttool版本可能太旧。
用新版重新强格u盘，重新制作fba应可解决问题。
最新版在ansi、utf-8方面未见问题报告。

不点 · 发表于 2013-12-30 22:52:46

章回小说，来个插曲。

今天 Windows 资源管理器要把我的 U 盘格式化。我同意了。用的是 FAT32 格式。完了之后，重启，我想看看微软的代码可否启动成功。结果，无论如何都是死机。反复插拔、反复折腾，达 10 次之多，都是死机，无任何信息显示。这个情况与我的代码很相似（即前面所提到的失败的测试结果）。

确信微软的代码已经不是 U 盘启动的标准了。而 fbinst 无论是用 FAT16 还是 FAT32，都能成功启动。

shan · 发表于 2013-12-31 08:24:56

怎么看不到大家测试回馈？只有不点大师自己在测试吗？有时间测试，只是不了解原理，看不懂代码。菜啊。建议大师把每次测试包放在顶楼，日期标号，以便大家测试。

cchessbd · 发表于 2013-12-31 12:53:24

本帖最后由 cchessbd 于 2013-12-31 13:18 编辑

pseudo 发表于 2013-12-30 22:47
cchessbd兄久违，你所用fbinsttool版本可能太旧。
用新版重新强格u盘，重新制作fba应可解决问题。
最新 ...

多谢p大也来关注，看来我抓到个小的bug，下次有机会上传个图片看看。

但是我要回家确认下，以免出错。

fbinstool版是1.73m大小，世界末日版本。

		自动登录	找回密码
密码			注册

准备基于 fbinst 进行再开发，请各位提供帮助

点评

点评

点评

点评