[更新376#2825]PECMD2012.1.80.13_Win32_64.多窗口多线程.裸机系统2.3.3.1+18M酷M...

mdyblog · 发表于 2022-7-21 11:56:09

泮安宁发表于 2022-7-21 10:52
m大，这个描述什么意思，是不是不加 -disaltmv参数就可以用Alt键加鼠标拖动窗口，但我测试好像没用，不加 ...

-top -forcenomin -disminb -maxb -discloseb -nosysmenu -nocap -[dis]altmv -size -trap -na]
-------------

-disaltmv 是默认的
用 -altmv ：用Alt键加鼠标拖动窗口

泮安宁 · 发表于 2022-7-21 12:22:12

mdyblog 发表于 2022-7-21 11:56
-top -forcenomin -disminb -maxb -discloseb -nosysmenu -nocap -[dis]altmv -size -trap -na]
------- ...

可以了，但如果鼠标放在了控件上就没法拖动了，只能放在空白窗口上，这个有办法解决吗

826773297 · 发表于 2022-7-21 12:40:56

泮安宁发表于 2022-7-21 12:22
可以了，但如果鼠标放在了控件上就没法拖动了，只能放在空白窗口上，这个有办法解决吗

可以用窗口控件进行拖放

826773297 · 发表于 2022-7-21 12:43:12

泮安宁发表于 2022-7-21 12:22
可以了，但如果鼠标放在了控件上就没法拖动了，只能放在空白窗口上，这个有办法解决吗

不用按alt

mdyblog · 发表于 2022-7-21 12:46:49

泮安宁发表于 2022-7-21 12:22
可以了，但如果鼠标放在了控件上就没法拖动了，只能放在空白窗口上，这个有办法解决吗

最简单的演示代码

泮安宁 · 发表于 2022-7-21 12:48:36

826773297 发表于 2022-7-21 12:43
不用按alt

emmm，就是想按着alt来拖动窗口

泮安宁 · 发表于 2022-7-21 12:52:59

本帖最后由泮安宁于 2022-7-21 12:59 编辑

mdyblog 发表于 2022-7-21 12:46
最简单的演示代码

Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,,,-altmv
ITEM item1,l50t100w200h50,ABC
_END

按着Alt，当鼠标放在ABC按钮上时就不能拖动窗口了，空白地方可以
---------------------------------------------------------------------------------------------------------
最终想把窗口做成透明的
Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,#:,,-altmv
ITEM item1,l50t100w200h50,ABC
_END

这样就不能通过Alt键拖动按钮

mdyblog · 发表于 2022-7-21 13:30:01

本帖最后由 mdyblog 于 2022-7-21 15:01 编辑

泮安宁发表于 2022-7-21 12:52
Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,,,-altmv
ITEM item1,l50t100w200h50, ...

//临时禁用控件，响应AltMove

ENVI^ EnviMode=1
SET ::WM_KEYDOWN=0x0100
SET ::WM_KEYUP=0x0101
SET ::WM_SYSKEYDOWN=0x0104
SET ::WM_SYSKEYUP=0x0105
Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,20,,-altmv
ITEM item1,l50t100w200h50,ABC
SET &bAlt=1
//临时禁用控件，响应AltMove
ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
ENVI @item1.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @item1.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
_END
_SUB ForAltMove
SET bAlt=%1
ENVI @item1.Enable=%1
_END

复制代码

泮安宁 · 发表于 2022-7-21 14:31:27

mdyblog 发表于 2022-7-21 13:30
//临时禁用控件，响应AltMove

可以了，感谢m大

泮安宁 · 发表于 2022-7-21 17:46:53

mdyblog 发表于 2022-7-21 13:30
//临时禁用控件，响应AltMove

如果有多个按钮

ENVI^ EnviMode=1
SET  ::WM_KEYDOWN=0x0100
SET  ::WM_KEYUP=0x0101
SET  ::WM_SYSKEYDOWN=0x0104
SET  ::WM_SYSKEYUP=0x0105

Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,20,,-altmv
   ITEM item1,l50t100w200h50,ABC
   ITEM item2,l50t150w200h50,ABC
   SET &bAlt=1
   //临时禁用控件，响应AltMove
   ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
   ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
   ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
   ENVI @item1.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
   ENVI @item1.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
_END

_SUB  ForAltMove
SET bAlt=%1
ENVI @item1.Enable=%1
_END

这样item1一直都是不可用状态，这个怎么解决

mdyblog · 发表于 2022-7-21 18:44:01

泮安宁发表于 2022-7-21 17:46
如果有多个按钮

ENVI^ EnviMode=1

ENVI^ EnviMode=1
SET ::WM_KEYDOWN=0x0100
SET ::WM_KEYUP=0x0101
SET ::WM_SYSKEYDOWN=0x0104
SET ::WM_SYSKEYUP=0x0105
SET ::VK_ALT=0x12
Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,20,,-altmv
ITEM item1,l50t100w200h50,ABC
ITEM item2,l50t160w200h50,ABC
SET &SubCtr=item1 item2
SET &bAlt=1
//临时禁用控件，响应AltMove
TIME -t:1 ,0,CALL * RegAltMove
_END
_SUB ForAltMove
SET bAlt=%1
FORX * %&SubCtr%,&&Ctr, ENVI @%&Ctr%.Enable=%1
_END
_SUB RegAltMove *
ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
FORX * %&SubCtr%,&&Ctr,
{* ^ENVI @%&Ctr%.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
^ENVI @%&Ctr%.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
}
_END

复制代码

泮安宁 · 发表于 2022-7-21 19:04:45

mdyblog 发表于 2022-7-21 18:44

好的

mdyblog · 发表于 2022-7-21 19:27:04

泮安宁发表于 2022-7-21 19:04
好的

ENVI^ EnviMode=1
SET ::WM_KEYDOWN=0x0100
SET ::WM_KEYUP=0x0101
SET ::WM_SYSKEYDOWN=0x0104
SET ::WM_SYSKEYUP=0x0105
SET ::VK_ALT=0x12
CALC #&&iALT=%&VK_ALT% + 1
Windows1
_SUB Windows1,W360H440,WinCMD功能演示,,,20,,-altmv
ITEM item1,l50t100w200h50,ABC
ITEM item2,l50t160w200h50,ABC
SET &SubCtr=item1 item2
SET &V0=
SET &bAlt=1
//临时禁用控件，响应AltMove
TIME -t:1 ,0,CALL * RegAltMove
_END
_SUB ForAltMove
@IFEX #%~1=%bAlt%, EXIT
WAIT -scanall &&V
FIND *&V0=&V, EXIT _SUB
SET-copy V0=&V
MSTR &&VAlt=<%iALT%>%&V%
CALC #&VAlt=%VAlt% & 0x80
IFEX #0=%~1, IFEX #%VAlt%<>0x80, EXIT
IFEX #1=%~1, IFEX #%VAlt%=0x80, EXIT
SET bAlt=%1
FORX * %&SubCtr%,&&Ctr, ENVI @%&Ctr%.Enable=%1
_END
_SUB RegAltMove *
ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
FORX * %&SubCtr%,&&Ctr,
{* ^ENVI @%&Ctr%.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
^ENVI @%&Ctr%.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
}
_END

复制代码

泮安宁 · 发表于 2022-7-21 19:47:40

mdyblog 发表于 2022-7-21 19:27

感谢m大

mdyblog · 发表于 2022-7-21 23:36:39

mdyblog 发表于 2022-7-21 19:27

ENVI^ EnviMode=1
SET ::WM_KEYDOWN=0x0100
SET ::WM_KEYUP=0x0101
SET ::WM_SYSKEYDOWN=0x0104
SET ::WM_SYSKEYUP=0x0105
SET ::VK_ALT=0x12
Windows1
_SUB Windows1,W360H440,控件上AltMove,,,20,,-altmv
ITEM item1,l50t100w200h50,ABC
ITEM item2,l50t160w200h50,ABC
SET &SubCtr=item1 item2
SET &bAlt=1
//临时禁用控件，响应AltMove
TIME -t:1 ,0,CALL * RegAltMove
_END
_SUB ForAltMove
@IFEX #%~1=%bAlt%, EXIT
WAIT -scan:%&VK_ALT% &&VAlt
CALC #&VAlt=%VAlt% & 0x80
IFEX #0=%~1, IFEX #%VAlt%<>0x80, EXIT
IFEX #1=%~1, IFEX #%VAlt%=0x80, EXIT
SET bAlt=%1
FORX * %&SubCtr%,&&Ctr, ENVI @%&Ctr%.Enable=%1
_END
_SUB RegAltMove *
ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
FORX * %&SubCtr%,&&Ctr,
{* ^ENVI @%&Ctr%.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
^ENVI @%&Ctr%.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
}
_END

复制代码

mdyblog · 发表于 2022-7-22 04:07:44

mdyblog 发表于 2022-7-21 23:36

不变灰版

ENVI^ EnviMode=1
SET ::WM_KEYDOWN=0x0100
SET ::WM_KEYUP=0x0101
SET ::WM_SYSKEYDOWN=0x0104
SET ::WM_SYSKEYUP=0x0105
SET ::VK_ALT=0x12
//临时禁用控件，响应AltMove,不变灰
Windows1
_SUB Windows1,W360H440,控件上AltMove(不变灰),,,20,,-altmv
SWIN -:WinIn:SwinWin1,L0T0W360H440,
SET &bAlt=1
TIME -t:1 ,0,CALL * RegAltMove1
_END
_SUB WinIn,W360H440,
ITEM item1,l50t100w200h50,ABC
ITEM item2,l50t160w200h50,ABC
SET &SubCtr=item1 item2
TIME -t:1 ,0,CALL * RegAltMove
_END
_SUB ForAltMove
@IFEX #%~1=%bAlt%, EXIT
WAIT -scan:%&VK_ALT% &&VAlt
IFEX #0=%~1, IFEX #%VAlt%<0x80, EXIT
IFEX #1=%~1, IFEX #%VAlt%>=0x80, EXIT
SET bAlt=%1
ENVI @SwinWin1.Enable=%1
_END
_SUB RegAltMove1 *
ENVI @this.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
ENVI @this.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
_END
_SUB RegAltMove *
FORX * %&SubCtr%,&&Ctr,
{* ^ENVI @%&Ctr%.MSG=$%WM_KEYDOWN%::&&wp,&&lp, ForAltMove 0
^ENVI @%&Ctr%.MSG=$%WM_SYSKEYDOWN%::&&wp,&&lp, ForAltMove 0
^ENVI @%&Ctr%.MSG=$%WM_SYSKEYUP%::&&wp,&&lp, ForAltMove 1
}
_END

复制代码

泮安宁 · 发表于 2022-7-22 07:20:18

mdyblog 发表于 2022-7-22 04:07
不变灰版

最近发的这两个版本测试都不可以移动呢

shmoss · 发表于 2022-7-22 08:58:01

有7Z压缩进度条的例子吗

mdyblog · 发表于 2022-7-22 09:02:29

泮安宁发表于 2022-7-22 07:20
最近发的这两个版本测试都不可以移动呢

最新 PECMD

mdyblog · 发表于 2022-7-22 09:04:17

本帖最后由 mdyblog 于 2022-7-22 10:13 编辑

shmoss 发表于 2022-7-22 08:58
有7Z压缩进度条的例子吗

示例\7z进度信息.WCS
然后，提取最后一个的有效进度值
SED -ex &&pE=?1,[%NL%]Everything is Ok[%NL%],,&vMSG
IFEX #%pE%>0, SET P=100! TEAM SED -ex &P=1,{.*[%NL%] *}{\d+}{% \d+.*},\2,&vMSG| CALC #P=%P%

泮安宁 · 发表于 2022-7-22 09:27:14

mdyblog 发表于 2022-7-22 09:02
最新 PECMD

哦，原来更新了

shmoss · 发表于 2022-7-22 09:30:19

mdyblog 发表于 2022-7-22 09:04
示例\7z进度信息.WCS
然后，提取最后一个的有效进度值

我想显示压缩进度
应该怎么做

shmoss · 发表于 2022-7-22 09:31:47

PBAR这种

826773297 · 发表于 2022-7-22 10:19:20

吃瓜群众问一下，有没有竖向的进度条，pecmd的进度条都是横向的

mdyblog · 发表于 2022-7-22 10:26:15

shmoss 发表于 2022-7-22 09:31
PBAR这种

ENVI^ ForceLocal=1
SET$ &NL=0d 0a
SET &I=1
SET &P=0
SET &vMSG=
SET &PID=0
_SUB ImagexExemsg
CALC I=%I%+1
ENVI @wMsg=%vMSG%
SED -ex &&pE=?1,[%NL%]Everything is Ok[%NL%],,&vMSG
IFEX #%pE%>0, SET P=100! TEAM SED -ex &P=1,{.*[%NL%] *}{\d+}{% \d+.*},\2,&vMSG| CALC #P=%P%
ENVI @wP=%P%
ENVI @Pbar1=%P%;%P%%%
ENVI @this=%P%%% //inx:%I%
_END
WIN1
_SUB WIN1,W687H494,新窗口1, KILL *%PID%
TIME -t:1 T,0,DoIt
LABE -vcenter wP,L7T6W60H20,xxx,,
PBAR Pbar1,L70T6W260H20,0
MEMO wMsg,L07T46W600H400,,,0x40
_END
_SUB DoIt
ENVI @wP=0
ENVI @Pbar1=0
//解压
//EXEC* -pid:&PID -cmd::1000:ImagexExemsg -wait -err+ &vMSG=*"C:\Program Files\7-Zip\7z.exe" -y -bsp1 x P:\PhyOs\WAIGO_Win10(21H2)_8.1_XP_ALL_PE.ISO -oP:\TEMP\T
//压缩
FILE -file P:\PhyOs\T1.7z
EXEC* -pid:&PID -cmd::1000:ImagexExemsg -wait -err+ &vMSG=*"C:\Program Files\7-Zip\7z.exe" -y -bsp1 a P:\PhyOs\T1.7z P:\TEMP\T1\*
SET PID=0 //Clear
SED -ex &&pE=?1,[%NL%]Everything is Ok[%NL%],,&vMSG
IFEX #%pE%>0, TEAM SET P=100| ENVI @wP=%P%;%P%%%| ENVI @this=%P%%% END OK
_END

复制代码

mdyblog · 发表于 2022-7-22 11:01:22

826773297 发表于 2022-7-22 10:19
吃瓜群众问一下，有没有竖向的进度条，pecmd的进度条都是横向的

H>W
PBAR Pbar1,L610T6W20H260,62

826773297 · 发表于 2022-7-22 11:43:54

mdyblog 发表于 2022-7-22 11:01
H>W
PBAR Pbar1,L610T6W20H260,62

改一下大小就行了，回去后试试

527104427 · 发表于 2022-7-22 12:24:22

本帖最后由 527104427 于 2022-7-22 12:37 编辑

826773297 发表于 2022-7-19 21:37
5大这个问题解决了吗，我也遇到了这个问题

我已经放弃挣扎了。本来界面做好了，但发现有些功能实在是实现不了。

527104427 · 发表于 2022-7-22 12:25:06

mdyblog 发表于 2022-7-22 11:01
H>W
PBAR Pbar1,L610T6W20H260,62

		自动登录	找回密码
密码			注册

[更新376#2825]PECMD2012.1.80.13_Win32_64.多窗口多线程.裸机系统2.3.3.1+18M酷M...

浏览过的版块