[2010.11.11]内核仅168M的支持无线网络及影音版WIN7PE(测试)

iwany · 发表于 2010-7-27 23:50:00

原帖由 coolg 于 2010-7-27 23:39 发表

是“来宾共享”，那么是在客户端还是在服务端设置验证？

服务器设置验证，我现在是在XP下作网启服务器。

iwany · 发表于 2010-7-28 00:10:52

现在是在自己的办公电脑用XP启动网启服务器，在技术部有不少局域网线可插上电脑用作网启客户端装机和维护，但不想局域网其他办公电脑共享我的电脑。手动作映射麻烦，想LZ帮忙弄个需验证的共享磁盘映射配置（客户端启动完pe就共享出服务器端的磁盘映射）。

coolg · 发表于 2010-7-28 00:10:52

如果在服务端设置，那么客户端就不能自动映射了

好的，明白你的意思，通过设置密码登录。

[ 本帖最后由 coolg 于 2010-7-28 00:16 编辑 ]

zhaohj · 发表于 2010-7-28 08:02:42

提供SERV_SET.BAT的目的就是让用户自己配置。
在有域的局域网环境，用户名可能需要这样设置：domain/user
set SHARE_USER=domain/user

zhaohj · 发表于 2010-7-28 08:44:44

测试了一下，缺路径，下面语句也错
IF '^%Var0:~0,1%'=='^"' SET Var0=%Var0:~1,-1%

或者改变当前路径：cd /d %tp%

[ 本帖最后由 zhaohj 于 2010-7-28 08:50 编辑 ]

dvd008 · 发表于 2010-7-28 08:49:11

WIM的终结版下了,
IMG,ISO的终结版什么时候有?

coolg · 发表于 2010-7-28 11:26:07

谢谢老大帮忙！我修改了一下，果然好了！

另外请问ZHAO兄：局域网内能不能用密码登录？
我打算用随机密码方法不知可行

coolg · 发表于 2010-7-28 11:27:55

原帖由 dvd008 于 2010-7-28 08:49 发表
WIM的终结版下了,
IMG,ISO的终结版什么时候有?

谢谢D兄，快了，就在这几天，内核基本完成，就是外围一些东西。

zhaohj · 发表于 2010-7-28 11:39:59

原帖由 coolg 于 2010-7-28 11:26 发表
谢谢老大帮忙！我修改了一下，果然好了！

另外请问ZHAO兄：局域网内能不能用密码登录？
我打算用随机密码方法不知可行

局域网内用户登录都是在服务器里设置的，象我这里的域环境，每个人都有用户名和密码。但一般开启guest也就能访问即可。

PE客户端能访问服务器端就可，反过来感觉没有必要。

另外，把PETOOLS链接到开始菜单，这样用户使用比较方便。

[ 本帖最后由 zhaohj 于 2010-7-28 11:41 编辑 ]

iwany · 发表于 2010-7-28 12:59:15

原帖由 zhaohj 于 2010-7-28 08:02 发表
提供SERV_SET.BAT的目的就是让用户自己配置。
在有域的局域网环境，用户名可能需要这样设置：domain/user
set SHARE_USER=domain/user

自己配置了一下，还是不能自动映射磁盘共享，手动是没问题的。

zhaohj · 发表于 2010-7-28 13:55:57

你手动是怎么运行的？不过不建议你使用超级用户账号，不安全啊。

iwany · 发表于 2010-7-28 14:27:18

原帖由 zhaohj 于 2010-7-28 13:55 发表
你手动是怎么运行的？不过不建议你使用超级用户账号，不安全啊。

手动就是在以上自动不成后，直接在PENETCFG网络设置上输入共享目录、用户名和密码做磁盘共享映射。不用超级用户账号可以建别的账号或administrator更名。局域网内其他客户是看不到我服务器共享的文件及磁盘。

zhaohj · 发表于 2010-7-28 17:22:22

大问题没有，P处理可以简化一点

zhaohj · 发表于 2010-7-29 18:21:16

客户端网络支持.cmd ，我修改了一下，我发觉你的有错误，你再看一下

@echo off
PECMD TEXT 正在加载网卡驱动. 请稍候 ......L189 T180 $24
SET Var0=%0
::IF '^%Var0:~0,1%'=='^"' SET Var0=%Var0:~1,-1%
FOR /f "delims=" %%I in ("%Var0%") do Set TP=%%~dpI
SET TP=%TP:~0,-1%
CD /D %TP%
7z.exe x NET_PART.7z -y -aos -o"%WinDir%"
7z.exe x system32.7z -y -aos -o"%WinDir%\system32"
IF EXIST A:\NET.CAB PECMD.EXE DEVI A:\NET.CAB
FOR /F %%i IN ('Dir /B /A-D ^"%TP%\DRIVERS_NET*.CAB^"') DO PECMD.EXE DEVI "%TP%\%%i"
START /Wait %TP%\InfCacheBuild.exe %SystemRoot%
PECMD.EXE UPNP -pnp
NET START EVENTLOG
PECMD.EXE UPNP -pnp -cn WinPE%RANDOM% -wg WORKGROUP
REGSVR32 /S RSAENH.DLL
REGSVR32 /S NETCFGX.DLL
REGSVR32 /S NETSHELL.DLL
REGSVR32 /S NETMAN.DLL
REGSVR32 /S HNETCFG.DLL
PECMD.EXE UPNP -c p -i MS_TCPIP
PECMD.EXE UPNP -c c -i MS_MSCLIENT
PECMD.EXE UPNP -c s -i MS_SERVER
NET START DHCP
::NET START TCPIP
NET START NLA
NET START LMHOSTS
NET START RpcLocator
SET K=HKLM\SYSTEM\CurrentControlSet\Services&&SET W=AutoShareServer&&SET S=AutoShareWks
REG ADD %K%\Lanmanserver\parameters /v %S% /t REG_DWORD /d 0 /f
REG ADD %K%\Lanmanserver\parameters /v %W% /t REG_DWORD /d 0 /f
REG ADD %K%\lanmanworkstation\parameters /v %S% /t REG_DWORD /d 0 /f
REG ADD %K%\lanmanworkstation\parameters /v %W% /t REG_DWORD /d 0 /f
NET START SERVER
DEL /Q %SystemRoot%\INF\*.PNF %SystemRoot%\INF\INFCACHE.1
reg add "HKLM\SYSTEM\CurrentControlSet\Services\afd" /v ImagePath /t REG_EXPAND_SZ /D "%windir%\System32\DRIVERS\afd.sys" /f >nul
PECMD.EXE EXEC @REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /va /f
PECMD.EXE EXEC @REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce /va /f
FOR /F %%i IN ('@reg query "HKLM\SYSTEM\CurrentControlSet\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}" /s^|find /i "\Connection"') DO >nul REG ADD %%i /v ShowIcon /t REG_DWORD /d 1 /f
PECMD.EXE LINK %USERPROFILE%\桌面\PENETCFG网络设置,%SystemRoot%\System32\PENETCFG.exe
::START PENETCFG.EXE
::PECMD.EXE HOME www.baidu.com
net user guest /active:yes
IF EXIST A:\SERV_SET.bat call A:\SERV_SET.bat
IF NOT "%PXE_SERVER%"=="WINPE" GOTO :GETSER
ECHO.|NET USE t: \\WINPE\PEROOT0 /user:guest /persistent:no
GOTO :LINK
:GETSER
echo.
NBTSTAT -N >nul || GOTO :网卡错误
call :映射网络磁盘
goto :END
:获取DHCP服务器IP
wntipcfg /all /batch %temp%\ser_ip.txt
for /f "usebackq tokens=2 delims=:" %%i in (`find /i "DHCP Server" %TEMP%\ser_ip.txt`) do set PXE_SERVER=%%i
set PXE_SERVER=%PXE_SERVER:~1%
goto :EOF

:网卡错误
echo.
ECHO.启动网络时出现一个错误!
echo.
echo.       网卡不能正常初始化,请确认网卡驱动安装正常......
echo.
echo.请安装好网卡驱动后再次运行本程序:       [%~nx0]       ]
echo.
pause
goto :END

:映射网络磁盘
setlocal
IF EXIST A:\SERV_SET.bat call A:\SERV_SET.bat
if not defined PXE_SERVER call :获取DHCP服务器IP
if not defined SHARE_NAME set SHARE_NAME=tftp
if not defined SHARE_USER set SHARE_USER=Guest
if not defined SHARE_PASS set SHARE_PASS=""
::等待网络运行正常.
echo.%time%  等待网络连接并映射网络共享\\%PXE_SERVER%\%SHARE_NAME%为Z:
:wait
if "%n%"=="10" goto :NOSERVER
ping -n 1 -w 1000 %PXE_SERVER% >nul && goto :map
set/an+=1 >nul
goto :wait

:NOSERVER
echo.网络可能连接不正常或服务器有防火墙,准备强制进行连接,有可能会发生错误......
echo.%TIME%  网络映射失败: net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%
goto :LINK

:map
net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER% >NUL 2>NUL || net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%@%COMPUTERNAME% >NUL 2>NUL || (pause>nul|ECHO.%TIME%       网络映射失败: net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%)
pecmd wait 2000
if not exist z:\nul goto :map
endlocal&&echo.已映射网络共享\\%PXE_SERVER%\%SHARE_NAME%为Z:盘

:LINK
START PECMD.EXE LOAD %TP%\LOADST.IC_
START PECMD.EXE LOAD %WINDIR%\SYSTEM32\PETOOLS.INI
PECMD FIND Explorer.EXE,KILL EXPLORER.EXE

:end
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /va /f >nul 2>nul
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce /va /f >nul 2>nul
:EOF
EXIT

[ 本帖最后由 zhaohj 于 2010-7-30 10:36 编辑 ]

zhaohj · 发表于 2010-7-29 18:25:07

特别是域环境下，原来的用GUEST账号连接不了，需要前面加域名如 abc.com/guest

这样修改后就不用输域名了。

coolg · 发表于 2010-7-29 20:12:02

据老大测试，是不是应当改成：
set SHARE_USER=abc.com/Guest

其中abc.com是域名

coolg · 发表于 2010-7-29 20:21:31

原帖由 zhaohj 于 2010-7-29 18:21 发表
客户端网络支持.cmd ，我修改了一下，我发觉你的有错误，你再看一下

@echo off
PECMD TEXT 正在加载网卡驱动. 请稍候 ......L189 T180 $24
SET Var0=%0
::IF '^%Var0:~0,1%'=='^"' SET Var0=%Var0:~1,-1% ...

这个P处理，我只是在XP\WIN2003里测试，开启服务，客户端能映射成功。其它的就不太了解，呵呵

现在我正在研究老大的处理方法。想把它们全部改成PECMD命令。

zhaohj · 发表于 2010-7-29 22:32:07

afd这个服务很重要，如果这个服务没开启或不正常，会引起其他服务不正常。

我发觉你以前的版本都没有开启这个服务或注册表值有问题。

coolg · 发表于 2010-7-29 22:37:24

老大，这个服务的全称是什么，注册表应修改哪里？

zhaohj · 发表于 2010-7-29 22:46:17

这个服务，是很底层的，也是驱动服务，所以无法用NET START开启。
reg add "HKLM\SYSTEM\CurrentControlSet\Services\afd" /v ImagePath /t REG_EXPAND_SZ /D "%windir%\System32\DRIVERS\afd.sys" /f >nul

你在注册表查一下看看以前的是否正确。
如果不正确，要么改注册表，要么用P处理补上。
afd.sys要确保存在。

[ 本帖最后由 zhaohj 于 2010-7-30 10:37 编辑 ]

dvd008 · 发表于 2010-7-30 09:25:41

这个在网络组件包里面提供的,
正常启动网络支持后服务应该启动的,
如果没有启动,可以使用
PETOOLS\系统维护\PE下安装srs启动sys服务.CMD
手工或者命令行方式启动,用记事本打开,可以看见使用方法.

做个BAT就行了

zhaohj · 发表于 2010-7-30 09:25:42

还是建议把一些固定的东西放在内核，如网络组件，至少基本网络组件放在内核，并在桌面之前释放它。
目前启动网络，时间偏长。

zhaohj · 发表于 2010-7-30 10:55:02

我查看了你的注册表，AFD服务是好的，问题不在这里，可能与注册DLL及下面蓝色服务有关。重新贴一下CMD：
@echo off
PECMD TEXT 正在加载网卡驱动. 请稍候 ......L189 T180 $24
SET Var0=%0
::IF '^%Var0:~0,1%'=='^"' SET Var0=%Var0:~1,-1%
FOR /f "delims=" %%I in ("%Var0%") do Set TP=%%~dpI
SET TP=%TP:~0,-1%
CD /D %TP%
7z.exe x NET_PART.7z -y -aos -o"%WinDir%"
7z.exe x system32.7z -y -aos -o"%WinDir%\system32"
IF EXIST A:\NET.CAB PECMD.EXE DEVI A:\NET.CAB
FOR /F %%i IN ('Dir /B /A-D ^"%TP%\DRIVERS_NET*.CAB^"') DO PECMD.EXE DEVI "%TP%\%%i"
START /Wait %TP%\InfCacheBuild.exe %SystemRoot%
PECMD.EXE UPNP -pnp
NET START EVENTLOG
PECMD.EXE UPNP -pnp -cn WinPE%RANDOM% -wg WORKGROUP
REGSVR32 /S RSAENH.DLL
REGSVR32 /S NETCFGX.DLL
REGSVR32 /S NETSHELL.DLL
REGSVR32 /S NETMAN.DLL
REGSVR32 /S HNETCFG.DLL
PECMD.EXE UPNP -c p -i MS_TCPIP
PECMD.EXE UPNP -c c -i MS_MSCLIENT
PECMD.EXE UPNP -c s -i MS_SERVER
NET START DHCP
::NET START TCPIP
NET START NLA
NET START LMHOSTS
NET START RpcLocator
SET K=HKLM\SYSTEM\CurrentControlSet\Services&&SET W=AutoShareServer&&SET S=AutoShareWks
REG ADD %K%\Lanmanserver\parameters /v %S% /t REG_DWORD /d 0 /f
REG ADD %K%\Lanmanserver\parameters /v %W% /t REG_DWORD /d 0 /f
REG ADD %K%\lanmanworkstation\parameters /v %S% /t REG_DWORD /d 0 /f
REG ADD %K%\lanmanworkstation\parameters /v %W% /t REG_DWORD /d 0 /f
NET START SERVER
DEL /Q %SystemRoot%\INF\*.PNF %SystemRoot%\INF\INFCACHE.1
::reg add "HKLM\SYSTEM\CurrentControlSet\Services\afd" /v ImagePath /t REG_EXPAND_SZ /D "%windir%\System32\DRIVERS\afd.sys" /f >nul
PECMD.EXE EXEC @REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /va /f
PECMD.EXE EXEC @REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce /va /f
FOR /F %%i IN ('@reg query "HKLM\SYSTEM\CurrentControlSet\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}" /s^|find /i "\Connection"') DO >nul REG ADD %%i /v ShowIcon /t REG_DWORD /d 1 /f
PECMD.EXE LINK %USERPROFILE%\桌面\PENETCFG网络设置,%SystemRoot%\System32\PENETCFG.exe
::START PENETCFG.EXE
::PECMD.EXE HOME www.baidu.com
net user guest /active:yes
IF EXIST A:\SERV_SET.bat call A:\SERV_SET.bat
IF NOT "%PXE_SERVER%"=="WINPE" GOTO :GETSER
ECHO.|NET USE t: \\WINPE\PEROOT0 /user:guest /persistent:no
GOTO :LINK
:GETSER
echo.
NBTSTAT -N >nul || GOTO :网卡错误
call :映射网络磁盘
goto :END
:获取DHCP服务器IP
wntipcfg /all /batch %temp%\ser_ip.txt
for /f "usebackq tokens=2 delims=:" %%i in (`find /i "DHCP Server" %TEMP%\ser_ip.txt`) do set PXE_SERVER=%%i
set PXE_SERVER=%PXE_SERVER:~1%
goto :EOF

:网卡错误
echo.
ECHO.启动网络时出现一个错误!
echo.
echo.       网卡不能正常初始化,请确认网卡驱动安装正常......
echo.
echo.请安装好网卡驱动后再次运行本程序:       [%~nx0]       ]
echo.
pause
goto :END

:映射网络磁盘
setlocal
IF EXIST A:\SERV_SET.bat call A:\SERV_SET.bat
if not defined PXE_SERVER call :获取DHCP服务器IP
if not defined SHARE_NAME set SHARE_NAME=tftp
if not defined SHARE_USER set SHARE_USER=Guest
if not defined SHARE_PASS set SHARE_PASS=""
::等待网络运行正常.
echo.%time%  等待网络连接并映射网络共享\\%PXE_SERVER%\%SHARE_NAME%为Z:
:wait
if "%n%"=="10" goto :NOSERVER
ping -n 1 -w 1000 %PXE_SERVER% >nul && goto :map
set/an+=1 >nul
goto :wait

:NOSERVER
echo.网络可能连接不正常或服务器有防火墙,准备强制进行连接,有可能会发生错误......
echo.%TIME%  网络映射失败: net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%
goto :LINK

:map
net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER% >NUL 2>NUL || net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%@%COMPUTERNAME% >NUL 2>NUL || (pause>nul|ECHO.%TIME%       网络映射失败: net use Z: \\%PXE_SERVER%\%SHARE_NAME% %SHARE_PASS% /user:%SHARE_USER%)
pecmd wait 2000
if not exist z:\nul goto :map
endlocal&&echo.已映射网络共享\\%PXE_SERVER%\%SHARE_NAME%为Z:盘

:LINK
START PECMD.EXE LOAD %TP%\LOADST.IC_
START PECMD.EXE LOAD %WINDIR%\SYSTEM32\PETOOLS.INI
PECMD FIND Explorer.EXE,KILL EXPLORER.EXE

:end
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /va /f >nul 2>nul
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce /va /f >nul 2>nul
:EOF
EXIT

[ 本帖最后由 zhaohj 于 2010-7-30 10:57 编辑 ]

coolg · 发表于 2010-7-30 13:21:21

注册表afd服务存在，启动时间长，主要是解压网络组件费时间，
如果把网络组件释放到内核里，内核又比较大，难以接受。
我再试这个CMD......

zhaohj · 发表于 2010-7-30 14:09:28

内核做成FAT32格式的IMG，再WDSYS无盘天使驱动，把setupldr.bin及ntdecete.com加进去，做成可引导的分区映像，这就是以前说的，然后用GZ压缩，这样比较小，FAT格式的修改也比较容易。不过，NTFS省内存。

这就是以前说的可直接启动的IMG，我测试了一下，GZ压缩大概25M

map --mem=0xb000 /BOOT/WINPE03.GZ (rd)
write 0x82a4 0
map (rd)+1 (hd0)
map --hook
chainloader (hd0,0)/SETUPLDR.BIN
rootnoverify (hd0,0)

[ 本帖最后由 zhaohj 于 2010-7-30 15:39 编辑 ]

canmao · 发表于 2010-7-30 15:03:05

不知WIM核心，开 FBWF 前能否在 X盘挂载Wim包？
如果可以的话，wim格式的网络组件包应该是较理想的选择。

coolg · 发表于 2010-7-30 15:52:13

wim核心PE,就不一样了，网络组件可以直接解开放到内核里，直接打包，特别方便。
一般80~90M的内核，打包后只有30多M。
不用CMD，直接用PECMD加载网络支持。几十秒钟就完成

[ 本帖最后由 coolg 于 2010-7-30 15:55 编辑 ]

zhaohj · 发表于 2010-7-30 16:42:02

to coolg:

帮我测试一下我的FTP中COOLG，为什么加载网络出现两次？

coolg · 发表于 2010-7-30 16:44:12

好的，马上下载测试。。

zhaohj · 发表于 2010-7-30 17:12:51

IMG内核，也可以把网络部分做成WIM，如NET.WIM，具体看一下CHENALL的CSPE的ext.zip的bat内容。

现在既然用到A盘了，网络部分放在A盘NET.WIM，直接挂载到WXPE\NET速度应该会很快。

[ 本帖最后由 zhaohj 于 2010-7-30 17:29 编辑 ]

[2010.11.11]内核仅168M的支持无线网络及影音版WIN7PE(测试)

回复 #2316 iwany 的帖子

回复 #2320 zhaohj 的帖子

		自动登录	找回密码
密码			注册