|
|
这样都不行
// 建议将本文保存为Unicode或UTF-8编码格式。
FIND $%&BX64%=0,TEAM ENVI B=X86|ENVI WIN=WIN2003PE!FIND $%&BX64%=3,TEAM ENVI WIN=X64_WIN8|ENVI B=X64
FIND $%B%=X86,IFEX X:\WINDOWS,ENVI WIN=X86_WIN8
FIND EXPLORER.EXE,ENVI BF=AFTER!ENVI BF=BEFOR
CALL %WIN%_%BF%
CALL %BF%
EXIT FILE
// 以下“U:\”特指安装了USBOS V2的U盘的可见区根目录，请根据自实际情况对号入座。
//*******************************************
_SUB X64_WIN8_AFTER
// 在 _SUB X64_WIN8_AFTER与 _END之间添加用于U盘操作系统X64 WIN8 RAMOS启动时,需要进桌面时加载的命令。
// 由于USBOS的X64 RAMOS维护版没有TCPIP.SYS，因此通过“IFEX %WINDIR%\SYSTEM32\DRIVERS\TCPIP.SYS”能简易地区分维护版与全功能版。
//以下示范了创建FIREFOX的安装快捷方式的过程。
FIND MEM>3071,
{
IFEX %DESKTOP%\Mozilla Firefox.LNK,!
{
FORX \PETOOLS\FIREFOX\FIREFOX.7Z,FF,1,
{
FDIR DR=%FF%
ENVI I=0
LOOP #%I%<20,
{
REGI $HKCU\SOFTWARE\7-ZIP\PATH,Z7
FIND $%Z7%=,TEAM CALC I=#%I%+1|WAIT 2000!EXIT LOOP
}
FIND #%I%=20,EXIT _SUB
ENVI P=%WINDIR%\SYSTEM32\FIREFOX.INI
LINK %DESKTOP%\Mozilla Firefox,%WINDIR%\SYSTEM32\PECMD.EXE,LOAD %P%,%DR%\FIREFOX.ICO,安装火狐浏览器
FILE %P%
WRIT %P%,$+0,TIPS 正在安装火狐浏览器,请稍侯......,5000,1,%DR%\FIREFOX.ICO
WRIT %P%,$+0,EXEC =!%Z7%\7Z.EXE x "%FF%" -y -aos -oX:\
WRIT %P%,+0,LOAD X:\MAIN.INI
WRIT %P%,$+0,FILE %P%
TEAM ENVI FF=|ENVI P=|ENVI DR=
}
}
}
// 以下还可追加其它命令
_END
//*******************************************
_SUB X86_WIN8_BEFOR
// 在 _SUB X86_WIN8_BEFOR与 _END之间添加用于U盘操作系统X86 WIN8 PE启动时,需要在SHEL命令前加载的命令。
FORX %CURDIR%\DRIVERS\X86\SCSIAdapter*.CAB,KV,0,TEAM DEVI $%KV%,,%TEMP%|TEMP @DELETE
// 以下还可追加其它命令
_END
//*******************************************
_SUB X86_WIN8_AFTER
// 在 _SUB X86_WIN8_AFTER与 _END之间添加用于U盘操作系统 X86 WIN8 PE启动时,需要在SHEL命令后加载的命令。
_END
//*******************************************
_SUB WIN2003PE_BEFOR
// 在 _SUB WIN2003PE_BEFOR与 _END之间添加用于U盘操作系统Win2003 PE启动时,需要在SHEL命令前加载的命令。
// 自20160423起 USBOSV2.1 的2003PE的PECMD.INI中已省略对PETOOLS目录下WIM格式外置程序包的全自动挂载请求机会，转到本文来处理该过程。
// 以下FORX语句示例了如何在03PE登录桌面前，全自动挂载本文所在目录（含子目录）下任意名字的WIM格式的外置程序包的过程：
FORX /S %CURDIR%\*.WIM,W,0,
{
NAME I=%W%
ENVI I2=%I%
TEXT 正在加载%I%.WIM .......#0x000000 L28 T28 $20
ENVI L=T
LOOP $%L%=T,CALL LOOPX
MOUN %W%,Y:\%I2%\
IFEX Y:\%I2%\MAIN.INI,LOAD Y:\%I2%\MAIN.INI!LOAD Y:\%I2%\%I%.INI
}
// 以下还可追加其它命令
_END
_SUB LOOPX
IFEX Y:\%I2%,ENVI I2=%I2%2!ENVI L=
_END
//*******************************************
_SUB WIN2003PE_AFTER
// 在 _SUB WIN2003PE_AFTER与 _END之间添加用于U盘操作系统Win2003 PE启动时,需要在SHEL命令后加载的命令。
_END
//*******************************************
_SUB AFTER
// 在 _SUB AFTER与 _END之间添加用于U盘操作系统 X64 WIN8.1 RAMOS或 X86 WIN8 PE及Win2003 PE启动时,需要在SHEL命令后加载的命令。
// USBOS具备自动创建PETOOLS下（含子目录）.EXE .TXT .CMD .INI.BAT快捷方式的能力，以下例子只是示范如何把快捷方式创建到指定位置。
// 下一句示例为本文目录下的“UD_DPT_备份还原.EXE”在“开始菜单-->备份还原”下创建一个快捷方式。
LINK %Programs%\备份还原\UD_DPT备份还原(通用),UD_DPT_备份还原.EXE
LINK %desktop%\DiskGenius,DiskGenius\DiskGenius.exe
LINK %desktop%\Qemu启动测试器,Qemu启动测试器\Qemu启动测试器.exe
// 以下还可追加其它命令
_END
|
|
[复制链接]
IP卡
狗仔卡
发表于 2016-5-2 22:41:51
显身卡
楼主