无忧启动论坛

 找回密码
 注册
搜索
系统gho:最纯净好用系统下载站广告联系 微信:wuyouceo QQ:184822951
查看: 55297|回复: 93

应部分网友要求,贴上老九WinPE老毛桃修改版内安装工具批处理代码

[复制链接]
发表于 2007-3-31 13:33:26 | 显示全部楼层 |阅读模式
安装.EXE v1.6.0.0330

文件描述:老毛桃制作的WinPE专用安装工具,仅仅适用于将老毛桃修改的老九WinPE从光盘(或硬盘、U 盘)安装到本地硬盘的系统分区。


  1. @Echo Off
  2. COLOR 2F
  3. Set Prog=老毛桃制作的 WinPE 专用安装工具
  4. Set L1=      ╭══════════════════╮
  5. Set L2=      ║                  ║
  6. Set L3=   ╭══┤ %Prog%  ├══╮
  7. Set L4=   ║  ║                  ║  ║
  8. Set L5=   ║  ╰══════════════════╯  ║
  9. Set L6=   ║                        ║
  10. Set L7=   ╟════════════════════════╢
  11. Set L8=   ║ 版权所有:老毛桃  仅供网友们交流 翻版不究 ║
  12. Set L9=   ╰────────────────────────╯
  13. Title %Prog%
  14. Set PEFile=WinPE.IS_
  15. Set PEIni=外置程序\WinPE.INI
  16. Set LogFile=PEInstall.log
  17. Set AddATTR=ATTRIB +S +H +R
  18. Set DelATTR=ATTRIB -S -H -R
  19. :Start
  20. CLS
  21. Title %Prog%——安装
  22. Echo.
  23. Echo %L1%
  24. Echo %L2%
  25. Echo %L3%
  26. Echo %L4%
  27. Echo %L5%
  28. Echo %L6%
  29. Echo    ║  请选择安装方式:               ║
  30. Echo %L6%
  31. Echo    ║  [1] 普通安装/启动 (硬盘安装)        ║
  32. Echo    ║  [2] Grub安装/启动 (硬盘安装,支持 MD5 密码) ║
  33. Echo    ║  [3] Aero安装/启动 (硬盘安装,支持密码)   ║
  34. Echo    ║  [4] Grub安装/启动 (U 盘安装,支持 MD5 密码) ║
  35. Echo    ║  [Q] 退出安装                ║
  36. Echo %L6%
  37. Echo %L7%
  38. Echo    ║ 注意: Aero 安装项只适合系统分区在(HD0,0)分区  ║
  39. Echo %L7%
  40. Echo %L8%
  41. Echo %L9%
  42. Echo.
  43. Set Choice=
  44. Set /P Choice=   请选择要进行的操作 (1/2/3/4/Q) ,然后按回车:
  45. If "%Choice%"=="" Goto Start
  46. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
  47. If /I "%Choice%"=="1" Goto HD
  48. If /I "%Choice%"=="2" Goto HD
  49. If /I "%Choice%"=="3" Goto HD
  50. If /I "%Choice%"=="4" Goto UD
  51. If /I "%Choice%"=="Q" Exit
  52. Goto Start
  53. :HD
  54. For %%I In (Z Y X W V U T S R Q P O N M L K J I H G F E D C) Do If Exist %%I:\BOOT.INI Set RP=%%I:
  55. If "%RP%"=="" Goto NoSys
  56. Set PEDIR=%RP%\MAOTAO
  57. Set TargetP=硬盘&&Set TxtSp=
  58. If Exist %PEDIR% Goto Err1
  59. FIND /I "C:\MAOTAO" %RP%\BOOT.INI>NUL 2>NUL
  60. If "%Errorlevel%"=="0" Goto Err1
  61. If /I "%Choice%"=="1" Goto Install
  62. If /I "%Choice%"=="2" Goto GInstall
  63. If /I "%Choice%"=="3" Goto AInstall
  64. Goto HD
  65. :UD
  66. CLS
  67. Title %Prog%——U 盘安装
  68. If "%NoUD%"=="Yes" Echo 错误:您设定的 U 盘分区不存在或写保护,请按任意键重新设定。&&Echo.
  69. Set /P RP=请选择您的 U 盘盘符(不需要冒号,例如 F):
  70. Echo.&&Echo.
  71. If "%RP%"=="" Goto UD
  72. If Not "%RP%"=="" Set RP=%RP:~0,1%:
  73. Set TestFile=%RP%\MaotaoTest_%RANDOM%.MT
  74. Cd.>%TestFile%
  75. If Not Exist %TestFile% Set NoUD=Yes&&Goto UD
  76. Del %TestFile% /Q>NUL 2>NUL
  77. Set U=U&&Set PEDIR=%RP%\MAOTAO&&Set OP=%RP%&&Set TargetP= U 盘
  78. If Exist %PEDIR% Goto Err1
  79. CLS
  80. Echo 您选择的 U 盘分区为 %RP%,下面将对您的 U 盘进行格式化并写入引导
  81. Echo.
  82. Echo 请严格按照相关工具软件界面中的提示操作,以防出错。请按任意键开始。。。
  83. PAUSE>NUL
  84. Start /Wait Grub2U\HPUSBFW.EXE
  85. Start /Wait Grub2U\GRUBGUI.EXE
  86. Echo.
  87. Echo 您的 U 盘已经成功格式化并写入了 Grub 引导,请按任意键继续。。。
  88. PAUSE>NUL
  89. Goto GInstall
  90. :Err1
  91. CLS
  92. Title %Prog%——卸载
  93. Echo.
  94. Echo %L1%
  95. Echo %L2%
  96. Echo %L3%
  97. Echo %L4%
  98. Echo %L5%
  99. Echo %L6%
  100. Echo    ║ 您的%TargetP%中好像已经安装了 WinPE,您想怎么办?%TxtSp% ║
  101. Echo %L6%
  102. Echo    ║  [1] 卸载原有的 WinPE,并且重新安装。    ║
  103. Echo    ║  [2] 卸载原有的 WinPE,并且不再安装。    ║
  104. Echo    ║  [B] 返回首页,重新选择安装选项。      ║
  105. Echo    ║  [Q] 退出安装                ║
  106. Echo %L6%
  107. Echo %L7%
  108. Echo %L8%
  109. Echo %L9%
  110. Echo.
  111. Set Choice=
  112. Set /P Choice=   请选择要进行的操作 (1/2/B/Q) ,然后按回车:
  113. If "%Choice%"=="" Goto Err1
  114. If Not "%Choice%"=="" Set Choice=%Choice:~0,1%
  115. If /I "%Choice%"=="1" Set Choi=1&&Goto UnInstall
  116. If /I "%Choice%"=="2" Goto UnInstall
  117. If /I "%Choice%"=="B" Goto Start
  118. If /I "%Choice%"=="Q" Exit
  119. Goto Err1
  120. Exit
  121. :UnInstall
  122. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE&&Del %RP%\LDRXPE /Q>NUL 2>NUL
  123. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE&&Del %RP%\WINNT.XPE /Q>NUL 2>NUL
  124. If Exist %RP%\MTLDR.PE %DelATTR% %RP%\MTLDR.PE&&Del %RP%\MTLDR.PE /Q>NUL 2>NUL
  125. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR&&Del %RP%\MTLDR /Q>NUL 2>NUL
  126. If Exist %RP%\%LogFile% For /F "eol=; tokens=2 delims=^=" %%i In ('find /I ^"WinPE外挂位置^" %RP%\%LogFile%') do SET OPU=%%i
  127. If Not "%U%"=="" Set OPU=%OP%
  128. If Exist %OPU%\外置程序 RD %OPU%\外置程序 /S /Q>NUL 2>NUL
  129. If Exist %RP%\%LogFile% %DelATTR% %RP%\%LogFile%&&Del %RP%\%LogFile% /Q>NUL 2>NUL
  130. If Exist %RP%\MAOTAO RD %RP%\MAOTAO /S /Q>NUL 2>NUL
  131. %DelATTR% %RP%\BOOT.INI>NUL 2>NUL
  132. If Exist %RP%\BOOT.BAK (
  133. %DelATTR% %RP%\BOOT.BAK
  134. TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
  135. ) Else (
  136. If Exist %RP%\BOOT.INI Copy %RP%\BOOT.INI %RP%\BOOT.BAK /Y>NUL 2>NUL
  137. If Exist %RP%\BOOT.BAK TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
  138. )
  139. If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK&&Del %RP%\BOOT.BAK>NUL 2>NUL
  140. If Exist %RP%\BOOT.INI %AddATTR% %RP%\BOOT.INI
  141. Title %Prog%——卸载完成
  142. If "%Choi%"=="1" (Echo.&&Echo.&&Echo    卸载完成,请按任意键准备安装 。。。&&PAUSE>NUL 2>NUL&&Goto Start)
  143. Echo.&&Echo.&&Echo    卸载完成,请按任意键退出 。。。
  144. PAUSE>NUL 2>NUL
  145. Exit
  146. :Install
  147. Title %Prog%——普通安装
  148. If "%OP%"=="" Call :SetOP
  149. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
  150. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
  151. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
  152. Echo 正在复制文件,请稍候 。。。
  153. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MAOTAO.BIN -r -y>NUL 2>NUL
  154. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
  155. Call :CopyAndSetFiles
  156. Goto SUCCESS
  157. :GInstall
  158. If "%U%"=="" Title %Prog%——Grub安装
  159. CLS
  160. Set DefItem=0&&Set LDRP=MAOTAO\
  161. If "%U%"=="" Set DefItem=1&&If "%OP%"=="" Call :SetOP
  162. Echo 请输入您要设定的密码
  163. Echo 注意:密码中不许有空格、""、引号等特殊字符
  164. Echo.
  165. Set /P Pass1=请输入:
  166. If "%Pass1%"=="" Goto GInstall
  167. Echo.&&Echo.
  168. Echo 请再一次输入您的密码
  169. Echo.
  170. Set /P Pass2=请再次输入:
  171. If "%Pass2%"=="" Goto GInstall
  172. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致,请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto GInstall
  173. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
  174. >%PEDIR%\MD5P.TMP <nul Set/p=%Pass2%
  175. MD5.EXE %PEDIR%\MD5P.TMP %PEDIR%\MD5R.TXT>NUL 2>NUL
  176. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% MTLDR -r -y>NUL 2>NUL
  177. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% MTLDR%U%.BIN -r -y>NUL 2>NUL
  178. >>%RP%\MTLDR Echo default %DefItem%
  179. >>%RP%\MTLDR Echo timeout 5
  180. >>%RP%\MTLDR Echo.
  181. For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
  182. Echo fontfile /maotao/muifont.gz>>%RP%\MTLDR
  183. Echo splashimage /maotao/bj2008.xpm.gz>>%RP%\MTLDR
  184. >>%RP%\MTLDR Echo.
  185. Echo title WinPE  By: Maotao>>%RP%\MTLDR
  186. For /f %%i In ('type %PEDIR%\md5r.txt') do echo password --md5 %%i>>%RP%\MTLDR
  187. Copy /b %RP%\MTLDR+%PEDIR%\MTLDR%U%.bin %RP%\MTLDR>NUL 2>NUL
  188. Del %PEDIR%\MD5?.* /Q>NUL 2>NUL
  189. Del %PEDIR%\MTLDR%U%.bin /Q>NUL 2>NUL
  190. Echo.
  191. Echo 密码设置完成,请牢记您的密码,并按任意键继续 。。。
  192. PAUSE>NUL 2>NUL
  193. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
  194. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
  195. If Exist %RP%\MTLDR %DelATTR% %RP%\MTLDR
  196. Echo.
  197. Echo 正在复制文件,请稍候 。。。
  198. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% BJ2008.XPM.GZ -r -y>NUL 2>NUL
  199. MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% muifont.gz -r -y>NUL 2>NUL
  200. If "%U%"=="" MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR%\ maotaog.bin -r -y>NUL 2>NUL
  201. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
  202. If "%U%"=="" Ren %PEDIR%\maotaog.bin maotao.bin
  203. Call :CopyAndSetFiles
  204. Goto SUCCESS
  205. :AInstall
  206. Title %Prog%——Aero安装
  207. CLS
  208. If "%OP%"=="" Call :SetOP
  209. Echo 请输入您要设定的密码
  210. Echo 注意:密码中不许有空格、""、引号等特殊字符
  211. Echo.
  212. Set /P Pass1=请输入:
  213. If "%Pass1%"=="" Goto AInstall
  214. Echo.&&Echo.
  215. Echo 请再一次输入您的密码
  216. Echo.
  217. Set /P Pass2=请再次输入:
  218. If "%Pass2%"=="" Goto AInstall
  219. If Not "%Pass2%"=="%Pass1%" Echo.&&Echo 您两次输入的密码不一致,请重新输入&&Echo 请按任意键重新开始设置密码&&PAUSE>NUL 2>NUL&&Goto AInstall
  220. If Not Exist %PEDIR% MD %PEDIR%>NUL 2>NUL
  221. For /f %%i In (MyIns\Aero.sys) Do MyIns\MyIns.exe e MyIns\MyIns.dll -o%PEDIR% %%i -r -y>NUL 2>NUL
  222. Ren %PEDIR%\maotao.bin avldr.xpe
  223. Ren %PEDIR%\maotaoa.bin maotao.bin
  224. >%PEDIR%\airL.gz <nul Set/p=%Pass2%
  225. Copy /B %PEDIR%\airT.gz+%PEDIR%\airL.gz+%PEDIR%\airW.gz %PEDIR%\airmenu.ini>NUL 2>NUL&&Del %PEDIR%\air?.gz /Q>NUL 2>NUL>NUL 2>NUL
  226. MyIns\MyIns.exe a -tGZip %PEDIR%\airmenu.gz %PEDIR%\airmenu.ini -w%PEDIR%>NUL 2>NUL&&Del %PEDIR%\airmenu.ini /Q>NUL 2>NUL&&Ren %PEDIR%\airmenu.gz airmenu.ini>NUL 2>NUL
  227. Echo.
  228. Echo 密码设置完成,请牢记您的密码,并按任意键继续 。。。
  229. PAUSE>NUL 2>NUL
  230. If Exist %RP%\LDRXPE %DelATTR% %RP%\LDRXPE
  231. If Exist %RP%\WINNT.XPE %DelATTR% %RP%\WINNT.XPE
  232. Echo.
  233. Echo 正在复制文件,请稍候 。。。
  234. MOVE %PEDIR%\MTLDR.PE %RP%\>NUL 2>NUL
  235. MOVE %PEDIR%\WINNT.XPE %RP%\>NUL 2>NUL
  236. Call :CopyAndSetFiles
  237. Goto SUCCESS
  238. :NoSys
  239. CLS
  240. Echo 好像您的机器中没有安装操作系统哦,请确认后再执行本安装程序。
  241. Echo.
  242. Echo 请按任意键退出 。。。
  243. PAUSE>NUL 2>NUL
  244. Exit
  245. :CopyAndSetFiles
  246. MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\%LDRP% LDRXPE -r -y>NUL 2>NUL
  247. If Not Exist %RP%\NTDETECT.COM MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP% NTDETECT.COM -r -y>NUL 2>NUL
  248. Copy ..\%PEFile% %PEDIR% /Y>NUL 2>NUL
  249. If "%U%"=="" %DelATTR% %RP%\BOOT.INI
  250. If "%U%"=="" If Exist %RP%\BOOT.BAK %DelATTR% %RP%\BOOT.BAK
  251. If "%U%"=="" Copy %RP%\BOOT.INI %RP%\BOOT.BAK>NUL 2>NUL
  252. If "%U%"=="" TYPE %RP%\BOOT.BAK|FIND /I /V "C:\MAOTAO">%RP%\BOOT.INI
  253. If "%U%"=="" Echo C:\MAOTAO\MAOTAO.BIN="WinPE  By: 老毛桃">>%RP%\BOOT.INI
  254. XCOPY ..\外置程序 /E %OP%\外置程序\ /Y /H /R>NUL 2>NUL
  255. If Exist %OP%\%PEIni% %DelATTR% %OP%\%PEIni%
  256. TYPE ..\%PEIni%|FIND /I /V "安装.EXE">%OP%\%PEIni%
  257. >>%RP%\WINNT.XPE <nul Set/p=/rdexportascd /rdpath=MAOTAO\%PEFile%"
  258. %AddATTR% %RP%\%LDRP%LDRXPE
  259. %AddATTR% %RP%\NTDETECT.COM
  260. %AddATTR% %RP%\WINNT.XPE
  261. If "%U%"=="" %AddATTR% %RP%\BOOT.INI
  262. %AddATTR% %RP%\MAOTAO /S /D
  263. %AddATTR% %RP%\MAOTAO\*.* /S /D
  264. %AddATTR% %OP%\外置程序 /S /D
  265. %AddATTR% %OP%\外置程序\*.* /S /D
  266. If Exist %RP%\MTLDR.PE %AddATTR% %RP%\MTLDR.PE
  267. If Exist %RP%\MTLDR %AddATTR% %RP%\MTLDR
  268. If "%U%"=="" Call :AddLog
  269. Goto :EOF
  270. :AddLog
  271. >%RP%\%LogFile% Cd.
  272. >>%RP%\%LogFile% Echo ;此文件为 WinPE 的安装日志文件,请不要随意删除
  273. >>%RP%\%LogFile% Echo ;否则可能会造成 WinPE 的卸载不够彻底!!!
  274. >>%RP%\%LogFile% Echo.
  275. >>%RP%\%LogFile% Echo WinPE镜像文件=%PEFile%
  276. >>%RP%\%LogFile% Echo WinPE外挂位置=%OP%
  277. >>%RP%\%LogFile% Echo WinPE安装日期=%Date% %Time%
  278. %AddATTR% %RP%\%LogFile%
  279. Goto :EOF
  280. :SetOP
  281. CLS
  282. If "%NoOP%"=="Yes" Echo 错误:您设定的分区不存在或写保护,请按任意键重新设定。&&Echo.
  283. Set /P OP=请设定 外置程序 存放的分区符(不需要冒号,例如 D):
  284. Echo.&&Echo.
  285. If "%OP%"=="" Goto SetOP
  286. If Not "%OP%"=="" Set OP=%OP:~0,1%:
  287. Set TestFile=%OP%\MaotaoTest.MT
  288. Cd.>%TestFile%
  289. If Not Exist %TestFile% Set NoOP=Yes&&Goto SetOP
  290. Del %TestFile% /Q>NUL 2>NUL
  291. Goto :EOF
  292. :SUCCESS
  293. Title %Prog%——安装完成
  294. CLS
  295. Echo 已经成功将镜像 %PEFile% 安装到您的 %RP% 盘。
  296. If "%U%"=="" (
  297. Echo 外置程序 文件夹按照您的设置,复制到了 %OP% 盘。
  298. Echo.
  299. Echo 系统分区中的 BOOT.INI 备份为 BOOT.BAK。
  300. )
  301. Echo.&&Echo.
  302. Echo 如果您需要将 WinPE 卸载,请重新运行本安装程序。
  303. Echo.
  304. Echo 请按任意键退出 。。。
  305. PAUSE>NUL 2>NUL
  306. Exit
复制代码
发表于 2007-3-31 13:53:03 | 显示全部楼层
对新手作用还是挺大的
回复

使用道具 举报

发表于 2007-3-31 13:57:02 | 显示全部楼层
呵呵,拷贝了。比原来看到的功能更强了。
回复

使用道具 举报

发表于 2007-3-31 18:01:17 | 显示全部楼层
顶一个!非常佩服毛桃兄的耐心,要我可写不了这么长的东西。^_^
回复

使用道具 举报

发表于 2007-3-31 20:10:56 | 显示全部楼层
辛苦了,赞一个。
回复

使用道具 举报

发表于 2007-4-1 19:50:50 | 显示全部楼层
就是不换行不好.东西真是好东西.
回复

使用道具 举报

发表于 2007-4-3 23:30:23 | 显示全部楼层
现在出现新的GRUB了,内置菜单在GRLDR最后的可以支持4k的大菜单了,修改菜单的工具今天也发布了,不知道斑竹更新不更新安装程序里的GRUBGUI.EXE。
好像GRUBGUI.EXE就是斑竹开发出来的吧,新的安装里根本就没单独的GRUB了,没了这个东西都不知道怎么安装新的版本了:'( :'( :'( :'(
回复

使用道具 举报

发表于 2007-4-4 19:57:37 | 显示全部楼层
认真学习,真是高手!!!
回复

使用道具 举报

 楼主| 发表于 2007-4-5 00:05:01 | 显示全部楼层
原帖由 maomao11000 于 2007-4-3 23:30 发表
现在出现新的GRUB了,内置菜单在GRLDR最后的可以支持4k的大菜单了,修改菜单的工具今天也发布了,不知道斑竹更新不更新安装程序里的GRUBGUI.EXE。
好像GRUBGUI.EXE就是斑竹开发出来的吧,新的安装里根本就没单 ...

呵呵,抱歉。GrubGui 并不是我做的。我只不过针对我的安装 Grub 到 U 盘的需求,对其进行了一点修改。
回复

使用道具 举报

发表于 2007-4-5 07:42:23 | 显示全部楼层
收下,偶学习学习
回复

使用道具 举报

发表于 2007-4-5 09:14:47 | 显示全部楼层
:victory:
回复

使用道具 举报

发表于 2007-4-5 16:19:30 | 显示全部楼层
回9楼,知道了,那您会继续维护PE吗?什么时候再出安装程序呢?
回复

使用道具 举报

发表于 2007-4-6 16:39:40 | 显示全部楼层
MAOTAO兄可以解说一下那MD5密码写入到MTLDR和把MTLDR,MTLDR.BIN合并那部分的原理吗?为什么这样就可以内置密码了?
回复

使用道具 举报

 楼主| 发表于 2007-4-10 11:04:54 | 显示全部楼层
原帖由 113651031 于 2007-4-6 16:39 发表
MAOTAO兄可以解说一下那MD5密码写入到MTLDR和把MTLDR,MTLDR.BIN合并那部分的原理吗?为什么这样就可以内置密码了?

就是使用 Copy 命令合并啊。将密码写入 Grub 的内置菜单
回复

使用道具 举报

发表于 2007-4-10 13:56:04 | 显示全部楼层
好好学习 准时完成作业:lol
回复

使用道具 举报

发表于 2007-4-11 10:53:08 | 显示全部楼层
下一版能不能加一个FTP个传下载软件,如flashfxp,我想自己加你能告诉我如何操作吗?
回复

使用道具 举报

发表于 2007-4-11 19:34:32 | 显示全部楼层
要想看懂这些首先得学习什么?
回复

使用道具 举报

发表于 2007-4-12 14:42:04 | 显示全部楼层
学习学习:victory:
回复

使用道具 举报

发表于 2007-4-15 08:28:01 | 显示全部楼层
下一版能不能加一个FTP个传下载软件,如flashfxp,我想自己加你能告诉我如何操作吗?

                         没有人教我,我很容易学会的。

[ 本帖最后由 13642639815 于 2007-4-15 08:29 AM 编辑 ]
回复

使用道具 举报

发表于 2007-4-15 15:00:17 | 显示全部楼层

请问老毛桃兄

请问mtldr是不是grub4dos 的grldr+menu.lst
回复

使用道具 举报

发表于 2007-4-15 22:47:02 | 显示全部楼层
看不看懂,先收藏起来再说
回复

使用道具 举报

发表于 2007-4-16 08:33:12 | 显示全部楼层
这个学习当中。

不如本人习惯就看不实践。哈
回复

使用道具 举报

发表于 2007-4-16 21:17:48 | 显示全部楼层
多谢贴出代码,不过我想问下那个"安装.EXE"是用什么生成的?
回复

使用道具 举报

发表于 2007-4-18 16:43:24 | 显示全部楼层
很多的实例,学习中,感谢分享
回复

使用道具 举报

发表于 2007-4-18 20:50:41 | 显示全部楼层
厉害啊,看的眼睛都花了:(
回复

使用道具 举报

 楼主| 发表于 2007-4-19 11:10:50 | 显示全部楼层
原帖由 woyaoxiangpian 于 2007-4-15 15:00 发表
请问mtldr是不是grub4dos 的grldr+menu.lst

grldr 本身就有内置菜单
回复

使用道具 举报

发表于 2007-4-21 15:58:11 | 显示全部楼层
原帖由 season 于 2007-4-16 09:17 PM 发表
多谢贴出代码,不过我想问下那个"安装.EXE"是用什么生成的?

同问,哪位高手解答一下,谢谢
回复

使用道具 举报

发表于 2007-4-22 15:08:56 | 显示全部楼层
回楼上:估计是bat文件,用exescript生成的吧.

请问毛老大或哪位兄弟知道myins.exe的作用是什么,为什么我用winnt.sif替换下面一行中的winnt.xpe就会出错?(无法复制到c盘)

MyIns\MyIns.exe e MyIns\MyIns.dll -o%RP%\ WINNT.XPE -r -y>NUL 2>NUL
回复

使用道具 举报

发表于 2007-4-22 22:10:31 | 显示全部楼层
:lol 真佩服老毛桃 ,版权所有,翻版不究.

开源对一个程序员来说胸襟多么广阔啊!!!偶像:hug:
回复

使用道具 举报

发表于 2007-4-23 22:47:15 | 显示全部楼层
收藏起来 虽然现在看不懂  但以后可以慢慢研究
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|捐助支持|无忧启动 ( 闽ICP备05002490号-1 )

闽公网安备 35020302032614号

GMT+8, 2024-3-29 22:53

Powered by Discuz! X3.3

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表