有可以在PE下查看原系统IP的工具么?

dogduxin · 发表于 2022-4-16 21:47:20

问下
有可以在PE下查看原wiondows系统IP的工具么?

nttwqz · 发表于 2022-4-16 22:04:21

本坛好多年前就有人写出来了，你找找

yfwang0798 · 发表于 2022-4-16 22:06:30

以前写过一个批处理放在pe的 windows\sustem32 文件夹下，运行批处理，输入windows西戎所在的盘符

@echo on
echo 本程序用于获取windows系统的机器名和 ip地址
@echo 注意：本程序认为系统安装到windows文件夹并且
@echo off
set keyname=HKLM\TempHive
@echo ================================================
if exist "%temp%\diskpart.txt" del "%temp%\diskpart.txt" /f /q
echo list vol>"%temp%\diskpart.txt"
echo exit>>"%temp%\diskpart.txt"
diskpart /s "%temp%\diskpart.txt"
echo ================================================

set choice1=
set strdrv=
set /p choice1= 请输入硬盘上 windows所在盘符，例如输入 c
If Not "%Choice1%"=="" Set strdrv=%choice1:~0,1%
echo 原来 windows所在盘为 %strdrv%

reg load %keyname%  "%strdrv%:\WINDOWS\SYSTEM32\CONFIG\SYSTEM"

echo 原来系统的 ip地址如下：
reg QUERY %keyname%\ControlSet001\Services\Tcpip\Parameters\Interfaces /s
echo ____________________________________
echo ____________________________________
echo
echo 原来计算机名字如下  ：
reg QUERY %keyname%\ControlSet001\Control\ComputerName\ComputerName  /v ComputerName
echo 请安任意键继续
reg unload  %keyname%
pause>nul

邪恶海盗 · 发表于 2022-4-16 22:14:45

NirSoft有这种工具,撸主找一下,而且0PE里有个批处理也行,只是不确定在其它PE中是否好使,你自行测试:

@echo off 2>nul 3>nul
setlocal enabledelayedexpansion
set /p Input=输入要查询的系统安装盘符[例如D]：
if /i "%Input%:" neq "%systemDrive%" (
for %%a in (software system) do (
if not exist "%Input%:\Windows\System32\config\%%a" echo,输错啦&pause & exit/b
)
reg load HKLM\Temp_HIV1 %Input%:\Windows\System32\config\software >nul
reg load HKLM\Temp_HIV2 %Input%:\Windows\System32\config\system >nul
call :GetIPInfo Temp_HIV1 Temp_HIV2
reg unload HKLM\Temp_HIV1 >nul
reg unload HKLM\Temp_HIV2 >nul
) else call :GetIPInfo SOFTWARE SYSTEM
start "" "%TEMP%\IPInfo.txt" & exit/b
:GetIPInfo
for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\select"') do (
if /i "%%a" == "Default" set /a x=%%c
)
set "v1=Microsoft\Windows NT\CurrentVersion\NetworkCards"
set "v2=ControlSet00%x%\Control\Network"
set "v3=ControlSet00%x%\services\Tcpip\Parameters"
set "s=EnableDHCP NameServer IPAddress SubnetMask DefaultGateway"
set "s=%s% DHCPNameServer DHCPIPAddress DHCPSubnetMask DHCPDefaultGateway"
for /f "delims=" %%a in ('reg query "HKLM\%1\%v1%"') do (
set "v=%%a"
if "!v:%v1%\=!" neq "!v!" (
set /a n+=1
for /f "tokens=1,2*" %%b in ('reg query "%%a"') do (
if /i "%%b" == "ServiceName" (
set "Guid!n!=%%d"
) else if /i "%%b" == "Description" set "NetCard!n!=%%d"
)
)
)
if not defined n echo,找不到网卡&pause & exit
(for /f "tokens=1,2*" %%a in ('reg query "HKLM\%2\%v3%"') do (
if /i "%%a" == "Domain" (
if "%%c" neq "" (echo,域名名称：%%c)else echo,域名名称：^<nul^>
) else if /i "%%a" == "HostName" echo,主机名称：%%c
))>"%TEMP%\IPInfo.txt"
for %%a in (%s%) do set "_%%a=1"
(for /l %%a in (1 1 %n%) do (
echo,&echo,网卡名称：!NetCard%%a!
for %%b in (%s%) do set "%%b="
for /f "delims=" %%b in ('reg query "HKLM\%2\%v2%" /s') do (
if defined flag (
for /f "tokens=1,2*" %%c in ("%%b") do (
if /i "%%c" == "Name" echo,连接名称：%%e& set "flag="
)
) else (
set "v=%%b"
for %%c in ("\!Guid%%a!") do if "!v:%%~c=!" neq "!v!" set flag=1
)
)
for /f "tokens=1,2*" %%b in ('reg query "HKLM\%2\%v3%\Interfaces\!Guid%%a!"') do (
if defined _%%b if "%%d" neq "" set "v=%%d" & set "%%b=!v:\0=!"
)
if /i "!EnableDHCP!" == "0x1" (
echo,IP 地址：!DHCPIPAddress!
echo,子网掩码：!DHCPSubnetMask!
echo,默认网关：!DHCPDefaultGateway!
echo,DNS 地址：!DHCPNameServer!
) else (
echo,IP 地址：!IPAddress!
echo,子网掩码：!SubnetMask!
echo,默认网关：!DefaultGateway!
echo,DNS 地址：!NameServer!
)
))>>"%TEMP%\IPInfo.txt"

复制代码

dogduxin · 发表于 2022-4-16 22:32:09

邪恶海盗发表于 2022-4-16 22:14
NirSoft有这种工具,撸主找一下,而且0PE里有个批处理也行,只是不确定在其它PE中是否好使,你自行测试:

0PE在哪里下载？官方网址是？

saiz · 发表于 2022-4-16 22:48:26

http://bbs.wuyou.net/forum.php?mod=viewthread&tid=335152
推薦!

江南一根葱 · 发表于 2022-4-17 00:30:01

我的newbeepe里有，乱抄的，支持离线系统xp-win11

2010sya · 发表于 2022-4-17 08:11:45

本帖最后由 2010sya 于 2022-4-17 08:18 编辑

PE下查看离线系统IP工具，在微PE下测试通过。。。

深深的沼泽 · 发表于 2022-4-17 11:31:03

以前就是从其他PE里提取里一个，测试在XP里提取成功，如果能提取MAC地址就好了

ghjghjghj · 发表于 2022-4-17 11:46:02

谢谢分享，收藏一个

23456 · 发表于 2022-4-17 17:43:58

这功能好像不错我觉得可以添加下

aichong168 · 发表于 2022-4-17 18:03:42

pe系统查看ip地址 - CSDN https://www.csdn.net/tags/NtzaYg5sNDYyMDMtYmxvZwO0O0OO0O0O.html

2010techon · 发表于 2022-4-18 11:50:33

PE下直接运行 3楼或4楼的批处理

因为原系统IP地址保存在注册表HIVE文件里，挂载后查询即可

782159442 · 发表于 2022-10-20 10:46:09

支持

wanghh · 发表于 2022-10-20 14:17:02

这个很好用。

holley2008 · 发表于 2022-10-20 14:52:16

要这个？

@echo off
set tempsys=%1
if %1*==* SET TEMPSYS=C:\windows\system32\config\SYSTEM
REG LOAD HKLM\TEMPSYS %tempsys%
set regx=HKLM\TEMPSYS\ControlSet001
echo 计算机名称 >%temp%\temp.txt
for /f "tokens=3" %%c in ('reg query %regx%\Control\ComputerName\ComputerName ^| find /i "computername"') do echo %%c >>%temp%\temp.txt
echo.>>%temp%\temp.txt
echo IP地址>>%temp%\temp.txt
for /f %%c in ('reg query %regx%\Services\Tcpip\Parameters\Interfaces') do (
for /f "tokens=3" %%d in ('reg query %%c /v ipaddress^|find /i "ipaddress"') do if not %%d*==0.0.0.0\0\0* echo %%d>>%temp%\temp.txt
)
echo.>>%temp%\temp.txt
echo 子网掩码>>%temp%\temp.txt
for /f %%c in ('reg query %regx%\Services\Tcpip\Parameters\Interfaces') do (
for /f "tokens=3" %%d in ('reg query %%c /v subnetmask^|find /i "subnetmask"') do if not %%d*==0.0.0.0\0\0* echo %%d>>%temp%\temp.txt
)
echo.>>%temp%\temp.txt
echo 默认网关>>%temp%\temp.txt
for /f %%c in ('reg query %regx%\Services\Tcpip\Parameters\Interfaces') do (
for /f "tokens=3" %%d in ('reg query %%c /v defaultgateway^|find /i "defaultgateway"') do if not %%d*==\0* echo %%d>>%temp%\temp.txt
)
echo DNS 服务器>>%temp%\temp.txt
for /f %%c in ('reg query %regx%\Services\Tcpip\Parameters\Interfaces') do (
for /f "tokens=3" %%d in ('reg query %%c /v nameserver^|find /i "nameserver"') do echo %%d>>%temp%\temp.txt
)
echo.>>%temp%\temp.txt
REG UNLOAD HKLM\TEMPSYS
cls
type %temp%\temp.txt
echo.
pause

复制代码

		自动登录	找回密码
密码			注册

有可以在PE下查看原系统IP的工具么?

点评

点评

评分