无忧启动论坛

标题: 分享创建12k bcd 方法 [打印本页]

作者: xuexiang 时间: 2009-11-23 12:00
标题: 分享创建12k bcd 方法

bcdedit.rar (75.43 KB, 下载次数: 156)
创建空白启动文件默认 8K

在c盘创建 bcd文件

bcdedit /createstore c:\bcd
bcdedit /store c:\bcd /create    {bootmgr} /d "bootmgr"
bcdedit /store c:\bcd /set       {bootmgr} device boot
bcdedit /store c:\bcd /set       {bootmgr} locale zh-CN

创建 Ramdisk 选项

bcdedit /store c:\bcd /create    {ramdiskoptions} /d "Ramdisk options"
bcdedit /store c:\bcd /set       {ramdiskoptions} ramdisksdidevice       boot
bcdedit /store c:\bcd /set       {ramdiskoptions} ramdisksdipath       \boot\boot.sdi

创建启动项

bcdedit /store c:\bcd /create    /D "Win7 PE 3.0" /application osloader                【“”菜单描述】

查看bcd【内新建的启动项ID】

bcdedit /store c:\bcd /enum all
                                          {          复制ID 粘贴到下面 {} 内          }
bcdedit /store c:\bcd /default {18533e40-d797-11de-a274-00247ef7f6e2}          【这里是新建的ID】
bcdedit /store c:\bcd /displayorder          {default}
bcdedit /store c:\bcd /set {default} device ramdisk=[boot]\boot\boot.wim,{ramdiskoptions}
bcdedit /store c:\bcd /set {default} path                   \windows\system32\boot\winload.exe
bcdedit /store c:\bcd /set {default} osdevice ramdisk=[boot]\boot\boot.wim,{ramdiskoptions}
bcdedit /store c:\bcd /set {default} locale zh-CN
bcdedit /store c:\bcd /set {default} systemroot             \windows
bcdedit /store c:\bcd /set {default} detecthal             Yes
bcdedit /store c:\bcd /set {default} winpe                Yes

OK
bcd创建成功  【12K】

查看bcd

bcdedit /store c:\bcd /enum all

[ 本帖最后由 xuexiang 于 2009-11-23 12:11 编辑 ]

作者: xhdz 时间: 2012-8-22 00:07
标题: 补充一下
补充一下，要在Win7或Win7PE下执行。
今天在xp折腾了快2小时，真悲剧。

作者: xhdz 时间: 2012-8-22 00:12
附上我的批处理

bcdedit /createstore bcd
bcdedit /store bcd /create {bootmgr} /d "bootmgr"
bcdedit /store bcd /set {bootmgr} device boot
bcdedit /store bcd /create {ramdiskoptions} /d "Ramdisk options"
bcdedit /store bcd /set {ramdiskoptions} ramdisksdidevice boot
bcdedit /store bcd /set {ramdiskoptions} ramdisksdipath \w77e\boot.sdi
for /F "tokens=[color=Red]3[/color]" %%i in ('bcdedit /store bcd /create /d "PE.wim" /application osloader') do set uuid=%%i
::（有些bcdedit.mui影响可能是2）
echo %uuid%
bcdedit /store bcd /default %uuid%
bcdedit /store bcd /displayorder {default}
bcdedit /store bcd /set {default} device ramdisk=[boot]\w77e\boot.wim,{ramdiskoptions}
bcdedit /store bcd /set {default} osdevice ramdisk=[boot]\w77e\boot.wim,{ramdiskoptions}
bcdedit /store bcd /set {default} systemroot \windows
bcdedit /store bcd /set {default} winpe yes
bcdedit /store bcd /set {default} detecthal yes
Bcdedit /store bcd /set {bootmgr} nointegritychecks yes
::破解的bootmgr
bcdedit /store bcd /enum all
pause

复制代码

[ 本帖最后由 xhdz 于 2012-8-22 00:14 编辑 ]

作者: foxfirefox 时间: 2013-11-8 16:04
本帖最后由 foxfirefox 于 2013-11-12 17:30 编辑

修正上面的代码:

_________________________________________________________________________________
@Echo off
rem *创建bcd文件
bcdedit /createstore bcd

rem  *选择设备类型为 Ramdisk
bcdedit /store bcd /create {bootmgr} /d "bootmgr"
bcdedit /store bcd /set {bootmgr} device boot

rem 设置启动界面语言
rem bcdedit /store bcd /set {bootmgr} locale zh-CN

rem *设置BCD合盘启动时的菜单标题,默认为 "Ramdisk options".Bootice 专业编辑模式下Device Objects 的参数Description
bcdedit /store bcd /create {ramdiskoptions} /d "Win8.1PE"

rem *设置启动磁盘为 Boot(WIM)/LOCATE(VHD)
bcdedit /store bcd /set {ramdiskoptions} ramdisksdidevice boot

rem *设置 SDI文件为 \boot\boot.sdi
bcdedit /store bcd /set {ramdiskoptions} ramdisksdipath  \boot\boot.sdi

rem *设置菜单标题为 Win8.1PE
bcdedit /store bcd /create /d "Win8.1PE" /application osloader

rem *获取GUID
bcdedit /store bcd /enum all >a.txt
@echo off&setlocal enabledelayedexpansion
for /f "tokens=2" %%a in (a.txt) do set /a n+=1&set "_!n!=%%a"&set  ".%%a=!n!"
set /a .boot-=5
bcdedit /store bcd /default !_%.boot%!
del /q a.txt
bcdedit /store bcd /displayorder {default}

rem *设置设备文件为 \boot\boot.wim
bcdedit /store bcd /set {default} device ramdisk=[boot]\boot\boot.wim,{ramdiskoptions}
bcdedit /store bcd /set {default} osdevice ramdisk=[boot]\boot\boot.wim,{ramdiskoptions}

rem 设置启动文件
rem bcdedit /store bcd /set {default} path  \windows\system32\boot\winload.exe

rem 设置系统语言
rem bcdedit /store bcd /set {default} locale zh-CN

rem *设置系统路径为 \windows
bcdedit /store bcd /set {default} systemroot \windows

rem *设置启动到winpe 有效
bcdedit /store bcd /set {default} winpe yes

rem 设置检测硬件抽象层  有效
rem bcdedit /store bcd /set {default} detecthal yes

rem 设置禁用数字签名验证有效
rem Bcdedit /store bcd /set {bootmgr} nointegritychecks yes

rem 设置超时时间为 3 秒
rem bcdedit /timeout 3 /store bcd

rem 显示bcd文件全部内容
bcdedit /store bcd /enum all
del /Q /a:h bcd*
pause
____________________________________
说明：1.此批处理制作12K BCD的最少参数版本,此时生成的批处理，bootice是不能直接编辑的
2.如需bootice编辑必须设置启动文件的路径为 \windows\system32\boot\winload.exe  。

3.如果需要增加参数，请将上述 rem bcdedit 替换成bcdedit即可。

欢迎光临无忧启动论坛 (http://bbs.wuyou.net/)

Powered by Discuz! X3.3